w3tagb.f

       SUBROUTINE w3tagb(PROG,KYR,JD,LF,ORG)
c$$$   subprogram documentation block
c
c subprogram: w3tagb        operational job identifier
c   prgmmr: farley          org: np11          date: 1998-03-17
c
c abstract: prints identifying information for operational
c   codes. called at the beginning of a code, w3tagb prints
c   the program name, the year and julian day of its
c   compilation, and the responsible organization. on a 2nd
c   line it prints the starting date-time. called at the
c   END OF A JOB, entry routine, W3TAGE PRINTS A LINE WITH the
c   ending date-time and a 2nd line stating the program name 
c   and that it has ended.
c
c PROGRAM history log:
c   85-10-29  j.newell
c   89-10-20  r.e.jones   convert to cray cft77 fortran
c   91-03-01  r.e.jones   add machine name to ending line
c   92-12-02  r.e.jones   add start-ending time-date
c   93-11-16  r.e.jones   add day of year, day of week, and julian day
c                         number. 
c   97-12-24  m.farley    print statements modified for 4-digit yr 
c   98-03-17  m.farley    replaced datimx with calls to w3locdat/w3doxdat 
c   99-01-29  b. vuong    converted to ibm rs/6000 sp
c
c   99-06-17  a. spruill  adjusted the SIZE of PROGRAM name to accommodate
c                         the 20 CHARACTER NAME CONVENTION ON THE IBM SP.
c 1999-08-24  gilbert     added call to start() in w3tagb and a call
c                         to summary() in w3tage to print out a 
c                         resource summary list for the program using
c                         w3tags.
c 2012-10-18  vuong       remove print statement 604
c 2013-02-06  vuong       modified print statement 604
c
c usage:  CALL w3tagb(prog, kyr, jd, lf, org)
c         CALL w3tage(prog)
c
c   input variables:
c     names  INTERFACE description of variables and types
c     ------ --------- -----------------------------------------------
c     prog   arg list  PROGRAM name   character*1
c     kyr    arg list  year of compilation   integer
c     jd     arg list  julian day of compilation   integer
c     lf     arg list  hundreths of julian day of compilation
c                      integer(range is 0 to 99 inclusive)
c     org    arg list  organization code(such as wd42)
c                      character*1
c
c   output variables:
c     names  INTERFACE description of variables and types
c     ----------------------------------------------------------------
c     ddate  print     year and julian day(nearest hundreth)
c            file      of compilation  real
c
c   subprograms called: clock, date
c
c   remarks: full word used in order to have at least
c            seven decimal digits accuracy for VALUE of ddate.
c            subprogram clock and date may differ for each TYPE
c            computer. you may have to change them for another
c            TYPE of computer.
c
c attributes:
c   language: fortran 90
c
c$$$
c
         CHARACTER *(*) PROG,ORG
         CHARACTER * 3 JMON(12)
         CHARACTER * 3 DAYW(7)
c
         INTEGER       IDAT(8), JDOW, JDOY, JDAY
c
         SAVE
c
         DATA  dayw/'SUN','MON','TUE','WEN','THU','FRI','SAT'/
         DATA  jmon  /'JAN','FEB','MAR','APR','MAY','JUN',
     &                'JUL','AUG','SEP','OCT','NOV','DEC'/
c 
         CALL start()
 
         dyr   = kyr
         dyr   = 1.0e+03 * dyr
         djd   = jd
         dlf   = lf
         dlf   = 1.0e-02 * dlf
         ddate = dyr + djd + dlf
         print 600
  600    FORMAT(//,10('* . * . '))
         print 601, prog, ddate, org
  601    FORMAT(5x,'PROGRAM ',a,' HAS BEGUN. COMPILED ',f10.2,
     &   5x, 'ORG: ',a)
c
         CALL w3locdat(idat)
         CALL w3doxdat(idat,jdow,jdoy,jday)
         print 602, jmon(idat(2)),idat(3),idat(1),idat(5),idat(6),
     &   idat(7),idat(8),jdoy,dayw(jdow),jday
  602    FORMAT(5x,'STARTING DATE-TIME  ',a3,1x,i2.2,',',
     &   i4.4,2x,2(i2.2,':'),i2.2,'.',i3.3,2x,i3,2x,a3,2x,i8,//)
         RETURN
c
         entry w3tage(prog)
c
         CALL w3locdat(idat)
         CALL w3doxdat(idat,jdow,jdoy,jday)
         print 603, jmon(idat(2)),idat(3),idat(1),idat(5),idat(6),
     &   idat(7),idat(8),jdoy,dayw(jdow),jday
  603    FORMAT(//,5x,'ENDING DATE-TIME    ',a3,1x,i2.2,',',
     &   i4.4,2x,2(i2.2,':'),i2.2,'.',i3.3,2x,i3,2x,a3,2x,i8)
         print 604, prog
  604    FORMAT(5x,'PROGRAM ',a,' HAS ENDED.')
c 604    FORMAT(5x,'PROGRAM ',a,' HAS ENDED.  CRAY J916/2048')
c 604    FORMAT(5x,'PROGRAM ',a,' HAS ENDED.  CRAY Y-MP EL2/256')
         print 605
  605    FORMAT(10('* . * . '))
 
         CALL summary()
c
         RETURN
         END