CALWXT_DOMINANT.f

       SUBROUTINE calwxt_dominant_post(PREC,RAIN,FREEZR,SLEET,SNOW,     &
     &                                 DOMR,DOMZR,DOMIP,DOMS)
!
!     WRITTEN: 24 AUGUST 2005, G MANIKIN
! 
!     PROGRAM HISTORY LOG:
!     21-10-31  JESSE MENG - 2D DECOMPOSITION
!      
!     THIS ROUTINE TAKES THE PRECIP TYPE SOLUTIONS FROM DIFFERENT
!       ALGORITHMS AND SUMS THEM UP TO GIVE A DOMINANT TYPE
!
!     use params_mod
      use ctlblk_mod, only: jsta, jend, pthresh, im, jsta_2l, jend_2u, &
                            ista, iend, ista_2l, iend_2u
!     use ctlblk_mod
!- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      implicit none
!
      integer,PARAMETER :: NALG=5
!    INPUT:
      REAL PREC(ista_2l:iend_2u,jsta_2l:jend_2u)
      real,DIMENSION(ista:iend,jsta:jend),     intent(inout) ::  DOMS,DOMR,DOMZR,DOMIP
      real,DIMENSION(ista:iend,jsta:jend,NALG),intent(in)    ::  RAIN,SNOW,SLEET,FREEZR
      integer I,J,L
      real TOTSN,TOTIP,TOTR,TOTZR
!--------------------------------------------------------------------------
!$omp  parallel do  private(i,j)
      DO j=jsta,jend
        DO i=ista,iend
          domr(i,j)  = 0.
          doms(i,j)  = 0.
          domzr(i,j) = 0.
          domip(i,j) = 0.
        ENDDO
      ENDDO
!
!$omp  parallel do private(i,j,totsn,totip,totr,totzr)
      DO j=jsta,jend
        DO i=ista,iend
!   SKIP THIS POINT IF NO PRECIP THIS TIME STEP
          IF (prec(i,j) <= pthresh) cycle
          totsn = 0
          totip = 0
          totr  = 0
          totzr = 0 
!   LOOP OVER THE NUMBER OF DIFFERENT ALGORITHMS THAT ARE USED
          DO l = 1, nalg
            IF (rain(i,j,l) >  0) THEN
              totr = totr + 1
              cycle
            ENDIF
 
            IF (snow(i,j,l) >  0) THEN
              totsn = totsn + 1
              cycle
            ENDIF
 
            IF (sleet(i,j,l) >  0) THEN
              totip = totip + 1
              cycle
            ENDIF
 
            IF (freezr(i,j,l) >  0) THEN
              totzr = totzr + 1
            ENDIF
          enddo
 
!   TIES ARE BROKEN TO FAVOR THE MOST DANGEROUS FORM OF PRECIP
!     FREEZING RAIN > SNOW > SLEET > RAIN 
          IF (totsn > totip) THEN
            IF (totsn > totzr) THEN
              IF (totsn  >=  totr) THEN
                doms(i,j) = 1
              ELSE
                domr(i,j) = 1 
              ENDIF
            ELSE IF (totzr  >=  totr) THEN
              domzr(i,j) = 1
            ELSE
              domr(i,j) = 1
            ENDIF 
          ELSE IF (totip  >  totzr) THEN
            IF (totip  >= totr) THEN
              domip(i,j) = 1
            ELSE
              domr(i,j) = 1
            ENDIF
          ELSE IF (totzr >= totr) THEN
            domzr(i,j) = 1
          ELSE
            domr(i,j) = 1
          ENDIF
        enddo
      enddo
!
      RETURN
      END