GETGBANDSCATTER.f

      subroutine getgbandscatter(me,iunit,im,jm,im_jm,jsta,jsta_2l        &
      ,jend_2u,mpi_comm_comp,icnt,idsp,spval,varname,jpds,jgds,kpds,buf)
!      
      implicit none
      include "mpif.h"
!
      character(len=20),intent(in) :: varname
      real,intent(in)       :: spval
      integer,intent(in)    :: me,iunit,im,jm,im_jm,jsta_2l,jend_2u,jsta, &
                               mpi_comm_comp
      integer,intent(in)    :: icnt(0:1023), idsp(0:1023)
      integer,intent(in)    :: jpds(200),jgds(200)
      integer,intent(inout) :: kpds(200)
      real,intent(out)      :: buf(im,jsta_2l:jend_2u)
      integer               :: kf,k,iret,i,j
      integer kgds(200) 
      LOGICAL*1 lb(im,jm)
      real dummy(im,jm)
      
      if(me == 0) then
        call getgb(iunit,0,im_jm,0,jpds,jgds,kf &
                  ,k,kpds,kgds,lb,dummy,iret)
        if (iret /= 0) then
          print*,varname," not found in file-Assigned missing values"
!$omp parallel do private(i,j)
          do j=1,jm
            do i=1,im
              dummy(i,j) = spval
            end do
          end do
        else
!$omp parallel do private(i,j)
          do j=1,jm
            do i=1,im    
              if(.not.lb(i,j)) dummy(i,j) = spval
            end do
          end do 
        end if
      end if
                                                                                          
      call mpi_scatterv(dummy(1,1),icnt,idsp,mpi_real                     &
                       ,buf(1,jsta),icnt(me),mpi_real,0,mpi_comm_comp,iret)
      
       RETURN
       END