MICROINIT.F

      SUBROUTINE microinit(imp_physics)
!
!-- ABSTRACT:
!     Initializes arrays for new cloud microphysics
!
!-- Program History Log:
!     02-02-08  B. Ferrier
!     04-11-19 H CHUANG - WRF VERSION
!
!-- Input argument list:
!     None
!
!-- Output argument list:
!     None
!
!-- Subprograms called:
!     Function FPVS
!
!-- Common blocks:
!     CMASSI
!     RMASS_TABLES
!     MAPOT
!     CRHgrd
!
!-- Attributes:
!     Language: FORTRAN 90
!     Machine : IBM SP
!
!- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      use params_mod, only: tfrz, pi
      use cmassi_mod, only: dmrmax, t_ice, nlimax, flarge2, xmrmax, &
                            mdrmax, mdrmin, trad_ice, massi, &
                            rqr_drmin, n0r0, rqr_drmax, cn0r0, &
                            cn0r_dmrmin, cn0r_dmrmax, dmrmin
      use gridspec_mod,only : gridtype
      use rhgrd_mod, only: rhgrd
      use ctlblk_mod, only: me
!- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      implicit none
!
      REAL, PARAMETER :: RHOL=1000.
      real ax,C_N0r0
      integer i
      integer, intent(in):: imp_physics
      real, allocatable:: MASSR(:)
      character filename*80
!
!------------------------ START EXECUTION ------------------------
!
!---  READ IN MASSI FROM LOOKUP TABLES 
!
      if(imp_physics==5 .or. imp_physics==15)then
!-- Changes associated with the Ferrier-Aligo microphysics in NMMB:
!   NLImax is now defined internally and FLARGE2 is no longer used.
         rhgrd=0.98
         dmrmax=1.e-3
      else if(imp_physics==85)then
         rhgrd=1.         !-- Approximation, as it varies in HWRF for different grids
         nlimax=20.e3
         flarge2=0.2
         dmrmax=.45e-3
      else if(imp_physics==95)then
         rhgrd=1.
         nlimax=5.e3
         if(gridtype=="B") then
            flarge2=0.03
            dmrmax=.45e-3
         else
            flarge2=0.2
            dmrmax=1.e-3
         endif
      endif 
 
#if defined(COMMCODE)
    ! If community code, check DMRmax to determine which file to link
      if (dmrmax<=0.45e-3) then
         filename = "nam_micro_lookup.dat"
      else
         filename = "hires_micro_lookup.dat"
      endif 
#else 
    ! Else operational code and use this file
         filename = "eta_micro_lookup.dat"
#endif
 
      t_ice=-40.     !-- Now used in all versions.
      xmrmax=1.e6*dmrmax 
      mdrmax=xmrmax
      allocate(massr(mdrmin:mdrmax))
      trad_ice=0.5*t_ice+tfrz
      
      OPEN (unit=1,file=filename,convert='big_endian',form="UNFORMATTED")
      DO i=1,3
        READ(1)
      ENDDO
      READ(1) massr
      DO i=1,5
        READ(1)
      ENDDO
      READ(1) massi
      CLOSE(1)
      rqr_drmin=n0r0*massr(mdrmin)    ! Rain content for mean drop diameter of .05 mm
      rqr_drmax=n0r0*massr(mdrmax)    ! Rain content for mean drop diameter of .45 mm
!      PI=ACOS(-1.) ! defined in params now
      c_n0r0=pi*rhol*n0r0
      cn0r0=1.e6/sqrt(sqrt(c_n0r0))
      cn0r_dmrmin=1./(pi*rhol*dmrmin*dmrmin*dmrmin*dmrmin)
      cn0r_dmrmax=1./(pi*rhol*dmrmax*dmrmax*dmrmax*dmrmax)
      if(me==0)print *,'MICROINIT: MDRmin, MASSR(MDRmin)=',mdrmin,massr(mdrmin)
      if(me==0)print *,'MICROINIT: MDRmax, MASSR(MDRmax)=',mdrmax,massr(mdrmax)
!      print *,  'ETA2P:MASSI(50)= ', MASSI(50)
!      print *,  'ETA2P:MASSI(450)= ', MASSI(450)
!      print *,  'ETA2P:MASSI(1000)= ', MASSI(1000)
!
!--- Initialize saturation vapor pressure lookup tables (functions FPVS, FPVS0)
!
      CALL gpvs
!
!--- Initialize RHgrd, grid-scale RH for onset of condensation. 
!    See GSMCONST in Eta model for algorithm with grid-size dependence.
!
!      AX=111.*(DPHD**2+DLMD**2)**.5
!      AX=111.*(DYVAL/1000.**2+DXVAL/1000.**2)**.5
!      AX=MIN(100., MAX(5., AX) )
!      RHgrd=0.90+.08*((100.-AX)/95.)**.5
      deallocate(massr)
!--- 
      RETURN
      END