iokoper.f

Go to the documentation of this file.

C> @file
C> @brief Check whether a mnemonic is a Table C operator.

C> This function determines whether a specified mnemonic is a
C> Table C operator supported by the BUFRLIB software.
C>
C> @author J. Ator
C> @date 2015-03-06
C>
C> @param[in] NEMO   - character*(*): Mnemonic
C> @returns iokoper  - integer: Flag indicating whether NEMO is a
C>                     Table C operator supported by the BUFRLIB
C>                     software
C>                        - 0 = No
C>                        - 1 = Yes
C>
C> <b>Program history log:</b>
C> - 2015-03-06  J. Ator    -- Original author
C> - 2016-05-04  J. Ator    -- Use imrkopr() and allow additional
C>                             operators
C>
      INTEGER FUNCTION iokoper(NEMO)

      CHARACTER*(*)  nemo

C-----------------------------------------------------------------------
C-----------------------------------------------------------------------

      IF (len(nemo).LT.6) THEN
        iokoper = 0
      ELSE IF ( lge(nemo(1:3),'201') .AND. lle(nemo(1:3),'208') ) THEN
        iokoper = 1
      ELSE IF ( nemo(1:3).EQ.'221') THEN
        iokoper = 1
      ELSE IF ( ( ( nemo(4:6).EQ.'000' ) .OR. ( nemo(4:6).EQ.'255' ) )
     +          .AND.
     +         ( ( nemo(1:3).EQ.'237' ) .OR. ( nemo(1:3).EQ.'241' ) .OR.
     +           ( nemo(1:3).EQ.'242' ) .OR. ( nemo(1:3).EQ.'243' ) ) )
     +          THEN
        iokoper = 1
      ELSE IF ( ( nemo(4:6).EQ.'000' ) 
     +          .AND.
     +         ( ( nemo(1:3).EQ.'222' ) .OR. ( nemo(1:3).EQ.'223' ) .OR.
     +           ( nemo(1:3).EQ.'224' ) .OR. ( nemo(1:3).EQ.'225' ) .OR.
     +           ( nemo(1:3).EQ.'232' ) .OR. ( nemo(1:3).EQ.'235' ) .OR.
     +           ( nemo(1:3).EQ.'236' ) ) )
     +          THEN
        iokoper = 1
      ELSE
        iokoper = imrkopr(nemo)
      ENDIF

      RETURN
      END