mtfnam.f

Go to the documentation of this file.

C> @file
C> @author ATOR @date 2017-10-16
    
C> BASED ON THE INPUT ARGUMENTS, THIS SUBROUTINE DETERMINES
C>   THE NAMES OF THE CORRESPONDING STANDARD AND LOCAL MASTER TABLE
C>   FILES.  IT THEN CONFIRMS THE EXISTENCE OF THESE FILES ON THE
C>   FILESYSTEM, USING ADDITIONAL INFORMATION OBTAINED FROM THE MOST
C>   RECENT CALL TO SUBROUTINE MTINFO, OR ELSE AS DEFINED WITHIN
C>   SUBROUTINE BFRINI IF SUBROUTINE MTINFO WAS NEVER CALLED.
C>
C> PROGRAM HISTORY LOG:
C> 2017-10-16  J. ATOR    -- ORIGINAL AUTHOR
C>
C> USAGE:    CALL MTFNAM ( IMT, IMTV, IOGCE, IMTVL, TBLTYP,
C>                         STDFIL, LOCFIL )
C>   INPUT ARGUMENT LIST:
C>     IMT      - INTEGER: MASTER TABLE NUMBER
C>     IMTV     - INTEGER: MASTER TABLE VERSION NUMBER
C>     IOGCE    - INTEGER: ORIGINATING CENTER
C>     IMTVL    - INTEGER: LOCAL TABLE VERSION NUMBER
C>     TBLTYP   - CHARACTER*(*): TABLE TYPE:
C>                  'TableB'   = Table B
C>                  'TableD'   = Table D
C>                  'CodeFlag' = Code and Flag Tables 
C>
C>   OUTPUT ARGUMENT LIST:
C>     STDFIL   - CHARACTER*(*): STANDARD MASTER TABLE PATH/FILENAME
C>     LOCFIL   - CHARACTER*(*): LOCAL MASTER TABLE PATH/FILENAME
C>
C> REMARKS:
C>    THIS ROUTINE CALLS:        BORT2    ERRWRT   ISIZE   STRSUC
C>    THIS ROUTINE IS CALLED BY: IREADMT
C>                               Normally not called by any application
C>                               programs.
C>
    SUBROUTINE mtfnam ( IMT, IMTV, IOGCE, IMTVL, TBLTYP,
     .                      stdfil, locfil )

    COMMON /quiet/  iprt
    COMMON /mstinf/ lun1, lun2, lmtd, mtdir

    character*(*)   stdfil, locfil, tbltyp

    character*16    tbltyp2
    character*20    fmtf
    character*100   mtdir
    character*128   bort_str
    logical     found

C-----------------------------------------------------------------------
C-----------------------------------------------------------------------

    CALL strsuc( tbltyp, tbltyp2, ltbt )

C*  Determine the standard master table path/filename.

    IF ( ( imt .EQ. 0 ) .AND. ( imtv .LE. 13 ) ) THEN

C*    For master table 0, version 13 is a superset of all earlier
C*    versions.

      stdfil = mtdir(1:lmtd) // '/bufrtab.' // tbltyp2(1:ltbt) //
     .         '_STD_0_13'
    ELSE
      WRITE ( fmtf, '(A,I1,A,I1,A)' )
     .       '(4A,I', isize(imt), ',A,I', isize(imtv), ')'
      WRITE ( stdfil, fmtf ) mtdir(1:lmtd), '/bufrtab.',
     .       tbltyp2(1:ltbt), '_STD_', imt, '_', imtv
    ENDIF
    IF ( iprt .GE. 2 ) THEN
      CALL errwrt('Standard ' // tbltyp2(1:ltbt) // ':')
      CALL errwrt(stdfil)
    ENDIF
    INQUIRE ( file = stdfil, exist = found )
    IF ( .NOT. found ) goto 900

C*  Now determine the local master table path/filename.

C*  Use the local table corresponding to the originating center
C*  and local table version number, if such a table exists.
C*  Otherwise use the local table from NCEP.

    WRITE ( fmtf, '(A,I1,A,I1,A,I1,A)' )
     .     '(4A,I', isize(imt), ',A,I', isize(iogce),
     .     ',A,I',  isize(imtvl), ')'
    WRITE ( locfil, fmtf ) mtdir(1:lmtd), '/bufrtab.',
     .       tbltyp2(1:ltbt), '_LOC_', imt, '_', iogce, '_', imtvl
    IF ( iprt .GE. 2 ) THEN
      CALL errwrt('Local ' // tbltyp2(1:ltbt) // ':')
      CALL errwrt(locfil)
    ENDIF
    INQUIRE ( file = locfil, exist = found )
    IF ( .NOT. found ) THEN

C*    Use the local table from NCEP.

      locfil = mtdir(1:lmtd) // '/bufrtab.' // tbltyp2(1:ltbt) //
     .         '_LOC_0_7_1'
      IF ( iprt .GE. 2 ) THEN
        CALL errwrt('Local ' // tbltyp2(1:ltbt) //
     .          'not found, so using:')
        CALL errwrt(locfil)
      ENDIF
      INQUIRE ( file = locfil, exist = found )
      IF ( .NOT. found ) goto 901
    ENDIF

    RETURN
900 bort_str = 'BUFRLIB: MTFNAM - COULD NOT FIND STANDARD FILE:'
    CALL bort2(bort_str,stdfil)
901 bort_str = 'BUFRLIB: MTFNAM - COULD NOT FIND LOCAL FILE:'
    CALL bort2(bort_str,locfil)
    END