nvnwin.f

Go to the documentation of this file.

C> @file
C> @author WOOLLEN @date 1994-01-06
      
C> THIS FUNCTION LOOKS FOR AND RETURNS ALL OCCURRENCES OF A
C>   SPECIFIED NODE WITHIN THE PORTION OF THE CURRENT SUBSET BUFFER
C>   BOUNDED BY THE INDICES INV1 AND INV2.  THE RESULTING LIST IS A
C>   STACK OF "EVENT" INDICES FOR THE REQUESTED NODE. 
C>
C> PROGRAM HISTORY LOG:
C> 1994-01-06  J. WOOLLEN -- ORIGINAL AUTHOR
C> 1998-07-08  J. WOOLLEN -- REPLACED CALL TO CRAY LIBRARY ROUTINE
C>                           "ABORT" WITH CALL TO NEW INTERNAL BUFRLIB
C>                           ROUTINE "BORT"
C> 1999-11-18  J. WOOLLEN -- THE NUMBER OF BUFR FILES WHICH CAN BE
C>                           OPENED AT ONE TIME INCREASED FROM 10 TO 32
C>                           (NECESSARY IN ORDER TO PROCESS MULTIPLE
C>                           BUFR FILES UNDER THE MPI)
C> 2003-11-04  S. BENDER  -- ADDED REMARKS/BUFRLIB ROUTINE
C>                           INTERDEPENDENCIES
C> 2003-11-04  D. KEYSER  -- MAXJL (MAXIMUM NUMBER OF JUMP/LINK ENTRIES)
C>                           INCREASED FROM 15000 TO 16000 (WAS IN
C>                           VERIFICATION VERSION); UNIFIED/PORTABLE FOR
C>                           WRF; ADDED DOCUMENTATION (INCLUDING
C>                           HISTORY); OUTPUTS MORE COMPLETE DIAGNOSTIC
C>                           INFO WHEN ROUTINE TERMINATES ABNORMALLY OR
C>                           UNUSUAL THINGS HAPPEN
C> 2009-03-23  J. ATOR    -- USE 1E9 TO PREVENT OVERFLOW WHEN
C>                           INITIALIZING INVN; USE ERRWRT
C> 2009-03-31  J. WOOLLEN -- ADDED DOCUMENTATION
C> 2014-12-10  J. ATOR    -- USE MODULES INSTEAD OF COMMON BLOCKS
C>
C> USAGE:    NVNWIN (NODE, LUN, INV1, INV2, INVN, NMAX)
C>   INPUT ARGUMENT LIST:
C>     NODE     - INTEGER: JUMP/LINK TABLE INDEX TO LOOK FOR
C>     LUN      - INTEGER: I/O STREAM INDEX INTO INTERNAL MEMORY ARRAYS
C>     INV1     - INTEGER: STARTING INDEX OF THE PORTION OF THE SUBSET
C>                BUFFER IN WHICH TO LOOK
C>     INV2     - INTEGER: ENDING INDEX OF THE PORTION OF THE SUBSET
C>                BUFFER IN WHICH TO LOOK
C>     NMAX     - INTEGER: DIMENSIONED SIZE OF INVN; USED BY THE
C>                FUNCTION TO ENSURE THAT IT DOES NOT OVERFLOW THE
C>                INVN ARRAY
C>
C>   OUTPUT ARGUMENT LIST:
C>     INVN     - INTEGER: ARRAY OF STACK "EVENT" INDICES FOR NODE
C>     NVNWIN   - INTEGER: NUMBER OF INDICES RETURNED WITHIN INVN
C>
C> REMARKS:
C>    THIS ROUTINE CALLS:        BORT     ERRWRT
C>    THIS ROUTINE IS CALLED BY: UFBEVN
C>                               Normally not called by any application
C>                               programs.
C>
      FUNCTION nvnwin(NODE,LUN,INV1,INV2,INVN,NMAX)

      USE moda_usrint

      COMMON /quiet / iprt

      CHARACTER*128 bort_str
      dimension     invn(nmax)

C----------------------------------------------------------------------
C----------------------------------------------------------------------

      nvnwin = 0

      IF(node.EQ.0) THEN
         IF(iprt.GE.1) THEN
      CALL errwrt('+++++++++++++++++++++WARNING+++++++++++++++++++++++')
      CALL errwrt('BUFRLIB: NVNWIN - NODE=0, IMMEDIATE RETURN')
      CALL errwrt('+++++++++++++++++++++WARNING+++++++++++++++++++++++')
      CALL errwrt(' ')
         ENDIF
         goto 100
      ENDIF

      DO i=1,nmax
         invn(i) = 1e9
      ENDDO

C  SEARCH BETWEEN INV1 AND INV2
C  ----------------------------

      DO n=inv1,inv2
         IF(inv(n,lun).EQ.node) THEN
            IF(nvnwin+1.GT.nmax) goto 900
            nvnwin = nvnwin+1
            invn(nvnwin) = n
         ENDIF
      ENDDO

C  EXITS
C  -----

100   RETURN
900   WRITE(bort_str,'("BUFRLIB: NVNWIN - THE NUMBER OF EVENTS, '//
     . 'NVNWIN (",I5,") EXCEEDS THE LIMIT, NMAX (",I5,")")') nvnwin,nmax
      CALL bort(bort_str)
      END