ufbcpy.f

Go to the documentation of this file.

C> @file
C> @author WOOLLEN @date 1994-01-06
      
C> THIS SUBROUTINE COPIES A COMPLETE SUBSET BUFFER, UNPACKED
C>   INTO INTERNAL MEMORY FROM LOGICAL UNIT LUBIN BY A PREVIOUS CALL
C>   TO BUFR ARCHIVE LIBRARY SUBROUTINE READSB OR READNS, TO
C>   LOGICAL UNIT LUBOT.  BUFR ARCHIVE LIBRARY SUBROUTINE OPENMG OR
C>   OPENMB MUST HAVE BEEN PREVIOUSLY CALLED TO OPEN AND INITIALIZE A
C>   BUFR MESSAGE WITHIN MEMORY FOR LOGICAL UNIT LUBOT.  BOTH FILES MUST
C>   HAVE BEEN OPENED TO THE INTERFACE (VIA A CALL TO BUFR ARCHIVE
C>   LIBRARY SUBROUTINE OPENBF) WITH IDENTICAL BUFR TABLES.
C>
C> PROGRAM HISTORY LOG:
C> 1994-01-06  J. WOOLLEN -- ORIGINAL AUTHOR
C> 1998-07-08  J. WOOLLEN -- REPLACED CALL TO CRAY LIBRARY ROUTINE
C>                           "ABORT" WITH CALL TO NEW INTERNAL BUFRLIB
C>                           ROUTINE "BORT"
C> 1999-11-18  J. WOOLLEN -- THE NUMBER OF BUFR FILES WHICH CAN BE
C>                           OPENED AT ONE TIME INCREASED FROM 10 TO 32
C>                           (NECESSARY IN ORDER TO PROCESS MULTIPLE
C>                           BUFR FILES UNDER THE MPI)
C> 2003-11-04  S. BENDER  -- ADDED REMARKS/BUFRLIB ROUTINE
C>                           INTERDEPENDENCIES
C> 2003-11-04  D. KEYSER  -- MAXJL (MAXIMUM NUMBER OF JUMP/LINK ENTRIES)
C>                           INCREASED FROM 15000 TO 16000 (WAS IN
C>                           VERIFICATION VERSION); UNIFIED/PORTABLE FOR
C>                           WRF; ADDED DOCUMENTATION (INCLUDING
C>                           HISTORY); OUTPUTS MORE COMPLETE DIAGNOSTIC
C>                           INFO WHEN ROUTINE TERMINATES ABNORMALLY
C> 2009-06-26  J. ATOR    -- USE IOK2CPY
C> 2009-08-11  J. WOOLLEN -- ADD COMMON UFBCPL TO REMEMBER WHICH UNIT 
C>                           IS COPIED TO WHAT SUBSET BUFFER IN ORDER TO
C>                           TRANSFER LONG STRINGS VIA UFBCPY AND WRTREE
C> 2014-12-10  J. ATOR    -- USE MODULES INSTEAD OF COMMON BLOCKS
C>
C> USAGE:    CALL UFBCPY (LUBIN, LUBOT)
C>   INPUT ARGUMENT LIST:
C>     LUBIT    - INTEGER: FORTRAN LOGICAL UNIT NUMBER FOR INPUT BUFR
C>                FILE
C>     LUBOT    - INTEGER: FORTRAN LOGICAL UNIT NUMBER FOR OUTPUT BUFR
C>                FILE
C>
C> REMARKS:
C>    THIS ROUTINE CALLS:        BORT     IOK2CPY  STATUS
C>    THIS ROUTINE IS CALLED BY: COPYSB
C>                               Also called by application programs.
C>
      SUBROUTINE ufbcpy(LUBIN,LUBOT)

      USE moda_usrint
      USE moda_msgcwd
      USE moda_ufbcpl
      USE moda_tables

C----------------------------------------------------------------------
C----------------------------------------------------------------------

C  CHECK THE FILE STATUSES AND I-NODE
C  ----------------------------------

      CALL status(lubin,lui,il,im)
      IF(il.EQ.0) goto 900
      IF(il.GT.0) goto 901
      IF(im.EQ.0) goto 902
      IF(inode(lui).NE.inv(1,lui)) goto 903

      CALL status(lubot,luo,il,im)
      IF(il.EQ.0) goto 904
      IF(il.LT.0) goto 905
      IF(im.EQ.0) goto 906

      IF(inode(lui).NE.inode(luo)) THEN
        IF( (tag(inode(lui)).NE.tag(inode(luo))) .OR.
     .     (iok2cpy(lui,luo).NE.1) ) goto 907
      ENDIF

C  EVERYTHING OKAY COPY USER ARRAY FROM LUI TO LUO
C  -----------------------------------------------

      nval(luo) = nval(lui)

      DO n=1,nval(lui)
      inv(n,luo) = inv(n,lui)
      nrfelm(n,luo) = nrfelm(n,lui)
      val(n,luo) = val(n,lui)
      ENDDO

      luncpy(luo)=lubin

C  EXITS
C  -----

      RETURN
900   CALL bort('BUFRLIB: UFBCPY - INPUT BUFR FILE IS CLOSED, IT MUST'//
     . ' BE OPEN FOR INPUT')
901   CALL bort('BUFRLIB: UFBCPY - INPUT BUFR FILE IS OPEN FOR '//
     . 'OUTPUT, IT MUST BE OPEN FOR INPUT')
902   CALL bort('BUFRLIB: UFBCPY - A MESSAGE MUST BE OPEN IN INPUT '//
     . 'BUFR FILE, NONE ARE')
903   CALL bort('BUFRLIB: UFBCPY - LOCATION OF INTERNAL TABLE FOR '//
     . 'INPUT BUFR FILE DOES NOT AGREE WITH EXPECTED LOCATION IN '//
     . 'INTERNAL SUBSET ARRAY')
904   CALL bort('BUFRLIB: UFBCPY - OUTPUT BUFR FILE IS CLOSED, IT '//
     . 'MUST BE OPEN FOR OUTPUT')
905   CALL bort('BUFRLIB: UFBCPY - OUTPUT BUFR FILE IS OPEN FOR '//
     . 'INPUT, IT MUST BE OPEN FOR OUTPUT')
906   CALL bort('BUFRLIB: UFBCPY - A MESSAGE MUST BE OPEN IN OUTPUT '//
     . 'BUFR FILE, NONE ARE')
907   CALL bort('BUFRLIB: UFBCPY - INPUT AND OUTPUT BUFR FILES MUST '//
     . 'HAVE THE SAME INTERNAL TABLES, THEY ARE DIFFERENT HERE')
      END