adn30.f

Go to the documentation of this file.

C> @file
C> @brief Convert an FXY value from its bit-wise (integer)
C> representation to its five or six character representation

C> This function converts an FXY value from its bit-wise
C> (integer) representation to its 5 or 6 character
C> representation.
C>
C> @author J. Woollen
C> @date 1994-01-06
C>
C> @param[in] IDN -- integer: Bit-wise representation of FXY value
C> @param[in] L30 -- integer: Length of string to be returned; can be
C>                either 5 or 6 characters
C> @returns adn30 -- character*(*): FXY value
C>
C> @remarks
C> - This function is the logical inverse of function idn30().
C>
C> <b>Program History Log:</b>
C> | Date | Programmer | Comments |
C> | -----|------------|----------|
C> | 1994-01-06 | J. Woollen | Original author |
C> | 1998-07-08 | J. Woollen | Replaced call to CRAY library routine "ABORT" with call to new internal BUFRLIB routine bort() |
C> | 2003-11-04 | S. Bender  | Added remarks and routine interdependencies |
C> | 2003-11-04 | D. Keyser  | Unified/portable for WRF; added history documentation |
      
      FUNCTION adn30(IDN,L30)

      COMMON /hrdwrd/ nbytw,nbitw,iord(8)

      CHARACTER*(*) adn30
      CHARACTER*128 bort_str

C----------------------------------------------------------------------
C----------------------------------------------------------------------

      IF(len(adn30).LT.l30         ) goto 900
      IF(idn.LT.0 .OR. idn.GT.65535) goto 901
      IF(l30.EQ.5) THEN
         WRITE(adn30,'(I5)') idn
      ELSEIF(l30.EQ.6) THEN
         idf = ishft(idn,-14)
         idx = ishft(ishft(idn,nbitw-14),-(nbitw-6))
         idy = ishft(ishft(idn,nbitw- 8),-(nbitw-8))
         WRITE(adn30,'(I1,I2,I3)') idf,idx,idy
      ELSE
         goto 902
      ENDIF

      DO i=1,l30
      IF(adn30(i:i).EQ.' ') adn30(i:i) = '0'
      ENDDO

C  EXITS
C  -----

      RETURN
900   CALL bort('BUFRLIB: ADN30 - FUNCTION RETURN STRING TOO SHORT')
901   CALL bort('BUFRLIB: ADN30 - INTEGER REPRESENTATION OF '//
     . 'DESCRIPTOR OUT OF 16-BIT RANGE')
902   WRITE(bort_str,'("BUFRLIB: ADN30 - CHARACTER LENGTH (",I4,") '//
     . 'MUST BE EITHER 5 OR 6")') l30
      CALL bort(bort_str)
      END