getlens.f

Go to the documentation of this file.

C> @file
C> @brief Read the section lengths of a BUFR message.

C> This subroutine reads the lengths of all of the individual
C> sections of a given BUFR message, up to a specified point in
C> the message.
C>
C> <p>This subroutine will work on any BUFR message encoded using
C> BUFR edition 2, 3, or 4
C>
C> @author J. Ator
C> @date 2005-11-29
C>
C> @param[in]  MBAY -- integer(*): BUFR message
C> @param[in]   LL  -- integer: Number of last section for
C>                     which the length is to be read.
C>                     In other words, setting LL = N means to
C>                     read and return the lengths of Sections 0
C>                     through N (i.e. LEN0, LEN1,...,LENN).
C>                     Any section lengths that are not specified
C>                     to be read are returned with a default
C>                     placeholder value of -1.
C> @param[out]  LEN0 -- integer: Length (in bytes) of Section 0
C> @param[out]  LEN1 -- integer: Length (in bytes) of Section 1
C> @param[out]  LEN2 -- integer: Length (in bytes) of Section 2
C> @param[out]  LEN3 -- integer: Length (in bytes) of Section 3
C> @param[out]  LEN4 -- integer: Length (in bytes) of Section 4
C> @param[out]  LEN5 -- integer: Length (in bytes) of Section 5
C>
C> @remarks
C> - The start of the BUFR message (i.e. the string 'BUFR') must be
C>   aligned on the first 4 bytes of MBAY.
C>
C> <b>Program history log:</b>
C> | Date | Programmer | Comments |
C> | -----|------------|----------|
C> | 2005-11-29 | J. Ator | Original author |
C>
    SUBROUTINE getlens(MBAY,LL,LEN0,LEN1,LEN2,LEN3,LEN4,LEN5)

    dimension   mbay(*)

C-----------------------------------------------------------------------
C-----------------------------------------------------------------------

    len0 = -1
    len1 = -1
    len2 = -1
    len3 = -1
    len4 = -1
    len5 = -1

    IF(ll.LT.0) RETURN
    len0 = iupbs01(mbay,'LEN0') 

    IF(ll.LT.1) RETURN
    len1 = iupbs01(mbay,'LEN1') 

    IF(ll.LT.2) RETURN
    iad2 = len0 + len1
    len2 = iupb(mbay,iad2+1,24) * iupbs01(mbay,'ISC2')

    IF(ll.LT.3) RETURN
    iad3 = iad2 + len2
    len3 = iupb(mbay,iad3+1,24)

    IF(ll.LT.4) RETURN
    iad4 = iad3 + len3
    len4 = iupb(mbay,iad4+1,24)

    IF(ll.LT.5) RETURN
    len5 = 4

    RETURN
    END