pktdd.f

Go to the documentation of this file.

C> @file
C> @author WOOLLEN @date 1994-01-06
      
C> THIS SUBROUTINE STORES INFORMATION ABOUT A "CHILD"
C>   MNEMONIC WITHIN THE INTERNAL BUFR TABLE D ENTRY (IN MODULE
C>   TABABD) FOR A TABLE D SEQUENCE ("PARENT") MNEMONIC WHEN THE
C>   "CHILD" MNEMONIC IS CONTAINED WITHIN THE SEQUENCE REPRESENTED BY
C>   THE "PARENT" MNEMONIC (AS DETERMINED WITHIN BUFR ARCHIVE LIBRARY
C>   SUBROUTINE SEQSDX).
C>
C> PROGRAM HISTORY LOG:
C> 1994-01-06  J. WOOLLEN -- ORIGINAL AUTHOR
C> 1995-06-28  J. WOOLLEN -- INCREASED THE SIZE OF INTERNAL BUFR TABLE
C>                           ARRAYS IN ORDER TO HANDLE BIGGER FILES
C> 1999-11-18  J. WOOLLEN -- THE NUMBER OF BUFR FILES WHICH CAN BE
C>                           OPENED AT ONE TIME INCREASED FROM 10 TO 32
C>                           (NECESSARY IN ORDER TO PROCESS MULTIPLE
C>                           BUFR FILES UNDER THE MPI)
C> 2003-11-04  J. ATOR    -- ADDED DOCUMENTATION
C> 2003-11-04  S. BENDER  -- ADDED REMARKS/BUFRLIB ROUTINE
C>                           INTERDEPENDENCIES
C> 2003-11-04  D. KEYSER  -- UNIFIED/PORTABLE FOR WRF; ADDED HISTORY
C>                           DOCUMENTATION; ADDED MORE COMPLETE
C>                           DIAGNOSTIC INFO WHEN UNUSUAL THINGS HAPPEN
C> 2009-04-21  J. ATOR    -- USE ERRWRT
C> 2014-12-10  J. ATOR    -- USE MODULES INSTEAD OF COMMON BLOCKS
C>
C> USAGE:    CALL PKTDD (ID, LUN, IDN, IRET)
C>   INPUT ARGUMENT LIST:
C>     ID       - INTEGER: POSITIONAL INDEX OF PARENT MNEMONIC WITHIN
C>                INTERNAL BUFR TABLE D ARRAY TABD(*,*)
C>     LUN      - INTEGER: I/O STREAM INDEX INTO INTERNAL MEMORY ARRAYS
C>     IDN      - INTEGER: BIT-WISE REPRESENTATION OF FXY VALUE
C>                CORRESPONDING TO CHILD MNEMONIC
C>                       0 = delete all information about all child
C>                           mnemonics from within TABD(ID,LUN)
C>
C>   OUTPUT ARGUMENT LIST:
C>     IRET     - INTEGER: TOTAL NUMBER OF CHILD MNEMONICS STORED THUS
C>                FAR (INCLUDING IDN) FOR THE PARENT MNEMONIC GIVEN BY
C>                TABD(ID,LUN)
C>                       0 = information was cleared from TABD(ID,LUN)
C>                           because input IDN value was 0
C>                      -1 = bad counter value or maximum number of
C>                           child mnemonics already stored for this
C>                           parent mnemonic
C>
C> REMARKS:
C>    THIS ROUTINE CALLS:        ERRWRT   IPKM     IUPM
C>    THIS ROUTINE IS CALLED BY: DXINIT   SEQSDX   STBFDX   STSEQ
C>                               Normally not called by any application
C>                               programs.
C>
      SUBROUTINE pktdd(ID,LUN,IDN,IRET)

      USE modv_maxcd
      USE moda_tababd

      COMMON /dxtab / maxdx,idxv,nxstr(10),ldxa(10),ldxb(10),ldxd(10),
     .                ld30(10),dxstr(10)
      COMMON /quiet / iprt

      CHARACTER*128 errstr
      CHARACTER*56  dxstr

C-----------------------------------------------------------------------
C-----------------------------------------------------------------------

      ldd = ldxd(idxv+1)+1

C     LDD points to the byte within TABD(ID,LUN) which contains (in
C     packed integer format) a count of the number of child mnemonics
C     stored thus far for this parent mnemonic.

C  ZERO THE COUNTER IF IDN IS ZERO
C  -------------------------------

      IF(idn.EQ.0) THEN
         CALL ipkm(tabd(id,lun)(ldd:ldd),1,0)
         iret = 0
         goto 100
      ENDIF

C  UPDATE THE STORED DESCRIPTOR COUNT FOR THIS TABLE D ENTRY
C  ---------------------------------------------------------

      nd = iupm(tabd(id,lun)(ldd:ldd),8)

C     ND is the (unpacked) count of the number of child mnemonics
C     stored thus far for this parent mnemonic.

      IF(nd.LT.0 .OR. nd.EQ.maxcd) THEN
      IF(iprt.GE.0) THEN
      CALL errwrt('+++++++++++++++++++++WARNING+++++++++++++++++++++++')
         IF(nd.LT.0) THEN
            WRITE ( unit=errstr, fmt='(A,I4,A)' )
     .        'BUFRLIB: PKTDD - BAD COUNTER VALUE (=', nd,
     .        ') - RETURN WITH IRET = -1'
         ELSE
            WRITE ( unit=errstr, fmt='(A,I4,A,A)' )
     .        'BUFRLIB: PKTDD - MAXIMUM NUMBER OF CHILD MNEMONICS (=',
     .        maxcd, ') ALREADY STORED FOR THIS PARENT - RETURN WITH ',
     .        'IRET = -1'
         ENDIF
      CALL errwrt(errstr)
      CALL errwrt('+++++++++++++++++++++WARNING+++++++++++++++++++++++')
      CALL errwrt(' ')
      ENDIF
         iret = -1
         goto 100
      ELSE
         nd = nd+1
         CALL ipkm(tabd(id,lun)(ldd:ldd),1,nd)
         iret = nd
      ENDIF

C  PACK AND STORE THE DESCRIPTOR
C  -----------------------------

      idm = ldd+1 + (nd-1)*2

C     IDM points to the starting byte within TABD(ID,LUN) at which
C     the IDN value for this child mnemonic will be stored (as a
C     packed integer of width = 2 bytes).

      CALL ipkm(tabd(id,lun)(idm:idm),2,idn)

C  EXIT
C  ----

100   RETURN
      END