rdmtbb.f

Go to the documentation of this file.

C> @file
C> @brief Read master Table B information from local file system

C> This subroutine reads master Table B information from two separate
C> ASCII files (one standard and one local) and then merges the
C> output into a single set of arrays.
C>
C> <p>Each of the two ASCII files must already be individually sorted
C> in ascending order with respect to the FXY numbers.
C>
C> @author J. Ator
C> @date 2007-01-19
C>
C> @param[in] LUNSTB -- integer: Fortran logical unit number for
C>                      ASCII file containing standard Table B
C>                      information
C> @param[in] LUNLTB -- integer: Fortran logical unit number for
C>                      ASCII file containing local Table B
C>                      information
C> @param[in] MXMTBB -- integer: Dimensioned size (in integers) of
C>                      merged output arrays; used by the subroutine
C>                      to ensure that it doesn't overflow these
C>                      arrays
C> @param[out] IMT   -- integer: Master table
C>                      - This value is read from both ASCII
C>                        files and must be identical between them.
C> @param[out] IMTV  -- integer: Version number of master table
C>                      - This value is read from the standard ASCII
C>                        file.
C> @param[out] IOGCE -- integer: Originating center
C>                      - This value is read from the local ASCII
C>                        file.
C> @param[out] ILTV  -- integer: Version number of local table
C>                      - This value is read from the local ASCII
C>                        file.
C> @param[out] NMTBB -- integer: Number of entries in merged output
C>                      arrays
C> @param[out] IMFXYN -- integer(*): Merged array containing bit-wise
C>                       representations of FXY numbers
C> @param[out] CMSCL -- character*4(*): Merged array containing
C>                      scale factors
C> @param[out] CMSREF -- character*12(*): Merged array containing
C>                       reference values
C> @param[out] CMBW  -- character*4(*): Merged array containing
C>                      bit widths
C> @param[out] CMUNIT -- character*24(*): Merged array containing units
C> @param[out] CMMNEM -- character*8(*): Merged array containing
C>                      mnemonics
C> @param[out] CMDSC -- character*4(*): Merged array containing
C>                      descriptor codes
C> @param[out] CMELEM -- character*120(*): Merged array containing
C>                       element names
C>
C> <b>Program history log:</b>
C> | Date | Programmer | Comments |
C> | -----|------------|----------|
C> | 2007-01-19 | J. Ator | Original author |
C> | 2021-01-08 | J. Ator | Modified mstabs array declarations for GNUv10 portability |
C> | 2021-05-17 | J. Ator | Allow up to 24 characters in cmunit |
C>
    SUBROUTINE rdmtbb ( LUNSTB, LUNLTB, MXMTBB,
     .              imt, imtv, iogce, iltv,
     .              nmtbb, imfxyn, cmscl, cmsref, cmbw,
     .              cmunit, cmmnem, cmdsc, cmelem )

    character*200   stline, ltline
    character*128   bort_str
    character*6 cmatch, adn30
    character*4 cmdsc(*)
    character   cmelem(120,*)
    character   cmunit(24,*)
    character   cmsref(12,*)
    character   cmmnem(8,*)
    character   cmscl(4,*), cmbw(4,*)

    integer     imfxyn(*)

C-----------------------------------------------------------------------
C-----------------------------------------------------------------------

C   Call WRDLEN to initialize some important information about the
C   local machine, just in case it hasn't already been called.

    CALL wrdlen

C   Read and parse the header lines of both files.

    CALL gettbh( lunstb, lunltb, 'B', imt, imtv, iogce, iltv )
    
C   Read through the remainder of both files, merging the
C   contents into a unified set of master Table B arrays.

    nmtbb = 0
    CALL getntbe( lunstb, isfxyn, stline, iers )
    CALL getntbe( lunltb, ilfxyn, ltline, ierl )
    DO WHILE ( ( iers .EQ. 0 ) .OR. ( ierl .EQ. 0 ) )
      IF ( ( iers .EQ. 0 ) .AND. ( ierl .EQ. 0 ) ) THEN
        IF ( isfxyn .EQ. ilfxyn ) THEN
          cmatch = adn30( isfxyn, 6 )
          goto 900
        ELSE IF ( isfxyn .LT. ilfxyn ) THEN
          CALL sntbbe( isfxyn, stline, mxmtbb,
     .              nmtbb, imfxyn, cmscl, cmsref, cmbw,
     .              cmunit, cmmnem, cmdsc, cmelem )
          CALL getntbe( lunstb, isfxyn, stline, iers )
        ELSE
          CALL sntbbe( ilfxyn, ltline, mxmtbb,
     .              nmtbb, imfxyn, cmscl, cmsref, cmbw,
     .              cmunit, cmmnem, cmdsc, cmelem )
          CALL getntbe( lunltb, ilfxyn, ltline, ierl )
        ENDIF
      ELSE IF ( iers .EQ. 0 ) THEN
        CALL sntbbe( isfxyn, stline, mxmtbb,
     .            nmtbb, imfxyn, cmscl, cmsref, cmbw,
     .            cmunit, cmmnem, cmdsc, cmelem )
        CALL getntbe( lunstb, isfxyn, stline, iers )
      ELSE IF ( ierl .EQ. 0 ) THEN
        CALL sntbbe( ilfxyn, ltline, mxmtbb,
     .            nmtbb, imfxyn, cmscl, cmsref, cmbw,
     .            cmunit, cmmnem, cmdsc, cmelem )
        CALL getntbe( lunltb, ilfxyn, ltline, ierl )
      ENDIF
    ENDDO

    RETURN
 900    WRITE(bort_str,'("BUFRLIB: RDMTBB - STANDARD AND LOCAL'//
     . ' TABLE B FILES BOTH CONTAIN SAME FXY NUMBER: ",5A)')
     .   cmatch(1:1), '-', cmatch(2:3), '-', cmatch(4:6)    
    CALL bort(bort_str)
    END