rdmtbf.f

Go to the documentation of this file.

C> @file
C> @brief Read master Code/Flag table information from local file system

C> This subroutine reads master Code/Flag table information from two
C> separate ASCII files (one standard and one local) and then merges the
C> output into a single set of arrays.
C>
C> <p>Each of the two ASCII files must already be individually sorted
C> in ascending order with respect to the FXY numbers.
C>
C> @author J. Ator
C> @date 2017-10-17
C>
C> @param[in] LUNSTF -- integer: Fortran logical unit number for
C>                      ASCII file containing standard Code/Flag table
C>                      information
C> @param[in] LUNLTF -- integer: Fortran logical unit number for
C>                      ASCII file containing local Code/Flag table
C>                      information
C>
C> <b>Program history log:</b>
C> | Date | Programmer | Comments |
C> | -----|------------|----------|
C> | 2017-10-17 | J. Ator | Original author |
C>
    SUBROUTINE rdmtbf ( LUNSTF, LUNLTF )

    character*160   stline, ltline
    character*128   bort_str
    character*6 cmatch, adn30

C-----------------------------------------------------------------------
C-----------------------------------------------------------------------

C   Call WRDLEN to initialize some important information about the
C   local machine, just in case it hasn't already been called.

    CALL wrdlen

C   Initialize the internal memory structure, including allocating
C   space for it in case this hasn't already been done.

    CALL inittbf

C   Read and parse the header lines of both files.

    CALL gettbh( lunstf, lunltf, 'F', imt, imtv, iogce, iltv )
    
C   Read through the remainder of both files, merging the
C   contents into a unified internal memory structure.

    CALL getntbe( lunstf, isfxyn, stline, iers )
    CALL getntbe( lunltf, ilfxyn, ltline, ierl )
    DO WHILE ( ( iers .EQ. 0 ) .OR. ( ierl .EQ. 0 ) )
      IF ( ( iers .EQ. 0 ) .AND. ( ierl .EQ. 0 ) ) THEN
        IF ( isfxyn .EQ. ilfxyn ) THEN
          cmatch = adn30( isfxyn, 6 )
          goto 900
        ELSE IF ( isfxyn .LT. ilfxyn ) THEN
          CALL sntbfe( lunstf, isfxyn, stline )
          CALL getntbe( lunstf, isfxyn, stline, iers )
        ELSE
          CALL sntbfe( lunltf, ilfxyn, ltline )
          CALL getntbe( lunltf, ilfxyn, ltline, ierl )
        ENDIF
      ELSE IF ( iers .EQ. 0 ) THEN
        CALL sntbfe( lunstf, isfxyn, stline )
        CALL getntbe( lunstf, isfxyn, stline, iers )
      ELSE IF ( ierl .EQ. 0 ) THEN
        CALL sntbfe( lunltf, ilfxyn, ltline )
        CALL getntbe( lunltf, ilfxyn, ltline, ierl )
      ENDIF
    ENDDO

C   Sort the contents of the internal memory structure.

    CALL sorttbf

    RETURN
 900    WRITE(bort_str,'("BUFRLIB: RDMTBF - STANDARD AND LOCAL'//
     . ' CODE/FLAG TABLE FILES BOTH CONTAIN SAME FXY NUMBER: ",5A)')
     .   cmatch(1:1), '-', cmatch(2:3), '-', cmatch(4:6)    
    CALL bort(bort_str)
    END