strnum.f

Go to the documentation of this file.

C> @file
C> @brief Decode an integer from a character string
 
C> This subroutine decodes an integer from a character string.  The
C> string should contain only digits and (optional) trailing blanks.
C> It should not contain any sign ('+' or '-') character nor any
C> leading blanks nor embedded blanks.
C>
C> @author J. Woollen
C> @date 1994-01-06
C>
C> @param[in]  STR -- character*(*): String
C> @param[out] NUM -- integer: Value decoded from STR
C>                    - -1 = decode was unsuccessful
C>
C> <b>Program History Log:</b>
C> | Date | Programmer | Comments |
C> | -----|------------|----------|
C> | 1994-01-06 | J. Woollen | Original author |
C> | 2003-11-04 | J. Ator    | Added documentation |
C> | 2009-04-21 | J. Ator    | Use errwrt() |
C>
      SUBROUTINE strnum(STR,NUM)
 
      CHARACTER*(*) STR
      CHARACTER*20  STR2
 
      COMMON /quiet / iprt
 
C-----------------------------------------------------------------------
C-----------------------------------------------------------------------
 
      num = 0
      k = 0
 
C     Note that, in the following call to subroutine STRSUC, the output
C     string STR2 is not used anywhere else in this routine.  In fact,
C     the only reason that subroutine STRSUC is being called here is to
C     determine NUM, which, owing to the fact that the input string STR
C     cannot contain any leading blanks, is equal to the number of
C     digits to be decoded from the beginning of STR.
 
      CALL strsuc(str,str2,num)
      IF(num.EQ.-1) GOTO 100
 
      DO i=1,num
      READ(str(i:i),'(I1)',err=99) j
      IF(j.EQ.0 .AND. str(i:i).NE.'0') GOTO 99
      k = k*10+j
      ENDDO
 
      num = k
      GOTO 100
 
C     Note that NUM = -1 unambiguously indicates a bad decode since
C     the input string cannot contain sign characters; thus, NUM is
C     always positive if the decode is successful.
 
99    num = -1
      IF(iprt.GE.0) THEN
      CALL errwrt('++++++++++++++BUFR ARCHIVE LIBRARY+++++++++++++++++')
      CALL errwrt('BUFRLIB: STRNUM - BAD DECODE; RETURN WITH NUM = -1')
      CALL errwrt('++++++++++++++BUFR ARCHIVE LIBRARY+++++++++++++++++')
      CALL errwrt(' ')
      ENDIF
 
C  EXIT
C  ----
 
100   RETURN
      END