ufbcup.f

Go to the documentation of this file.

C> @file
C> @author WOOLLEN @date 1994-01-06
      
C> THIS SUBROUTINE MAKES ONE COPY OF EACH UNIQUE ELEMENT IN AN
C>   INPUT SUBSET BUFFER INTO THE IDENTICAL MNEMONIC SLOT IN THE OUTPUT
C>   SUBSET BUFFER.
C>
C> PROGRAM HISTORY LOG:
C> 1994-01-06  J. WOOLLEN -- ORIGINAL AUTHOR
C> 1998-07-08  J. WOOLLEN -- REPLACED CALL TO CRAY LIBRARY ROUTINE
C>                           "ABORT" WITH CALL TO NEW INTERNAL BUFRLIB
C>                           ROUTINE "BORT"
C> 1999-11-18  J. WOOLLEN -- THE NUMBER OF BUFR FILES WHICH CAN BE
C>                           OPENED AT ONE TIME INCREASED FROM 10 TO 32
C>                           (NECESSARY IN ORDER TO PROCESS MULTIPLE
C>                           BUFR FILES UNDER THE MPI)
C> 2003-11-04  S. BENDER  -- ADDED REMARKS/BUFRLIB ROUTINE
C>                           INTERDEPENDENCIES
C> 2003-11-04  D. KEYSER  -- MAXJL (MAXIMUM NUMBER OF JUMP/LINK ENTRIES)
C>                           INCREASED FROM 15000 TO 16000 (WAS IN
C>                           VERIFICATION VERSION); UNIFIED/PORTABLE FOR
C>                           WRF; ADDED DOCUMENTATION (INCLUDING
C>                           HISTORY); OUTPUTS MORE COMPLETE DIAGNOSTIC
C>                           INFO WHEN ROUTINE TERMINATES ABNORMALLY
C> 2014-12-10  J. ATOR    -- USE MODULES INSTEAD OF COMMON BLOCKS
C>
C> USAGE:    CALL UFBCUP (LUBIN, LUBOT)
C>   INPUT ARGUMENT LIST:
C>     LUBIN    - INTEGER: FORTRAN LOGICAL UNIT NUMBER FOR INPUT BUFR 
C>                FILE
C>     LUBOT    - INTEGER: FORTRAN LOGICAL UNIT NUMBER FOR OUTPUT BUFR 
C>                FILE
C>
C> REMARKS:
C>    THIS ROUTINE CALLS:        BORT     STATUS
C>    THIS ROUTINE IS CALLED BY: None
C>                               Normally called only by application
C>                               programs.
C>
      SUBROUTINE ufbcup(LUBIN,LUBOT)
 
      USE moda_usrint
      USE moda_msgcwd
      USE moda_tables
      USE moda_ivttmp
 
      CHARACTER*10 TAGO
 
C----------------------------------------------------------------------
C----------------------------------------------------------------------
 
C  CHECK THE FILE STATUSES AND I-NODE
C  ----------------------------------
 
      CALL status(lubin,lui,il,im)
      IF(il.EQ.0) GOTO 900
      IF(il.GT.0) GOTO 901
      IF(im.EQ.0) GOTO 902
      IF(inode(lui).NE.inv(1,lui)) GOTO 903
 
      CALL status(lubot,luo,il,im)
      IF(il.EQ.0) GOTO 904
      IF(il.LT.0) GOTO 905
      IF(im.EQ.0) GOTO 906
 
C  MAKE A LIST OF UNIQUE TAGS IN INPUT BUFFER
C  ------------------------------------------
 
      ntag = 0
 
      DO 5 ni=1,nval(lui)
      nin = inv(ni,lui)
      IF(itp(nin).GE.2) THEN
         DO nv=1,ntag
         IF(ttmp(nv).EQ.tag(nin)) GOTO 5
         ENDDO
         ntag = ntag+1
         itmp(ntag) = ni
         ttmp(ntag) = tag(nin)
      ENDIF
5     ENDDO
 
      IF(ntag.EQ.0) GOTO 907
 
C  GIVEN A LIST MAKE ONE COPY OF COMMON ELEMENTS TO OUTPUT BUFFER
C  --------------------------------------------------------------
 
      DO 10 nv=1,ntag
      ni = itmp(nv)
      DO no=1,nval(luo)
      tago = tag(inv(no,luo))
      IF(ttmp(nv).EQ.tago) THEN
         val(no,luo) = val(ni,lui)
         GOTO 10
      ENDIF
      ENDDO
10    ENDDO
 
C  EXITS
C  -----
 
      RETURN
900   CALL bort('BUFRLIB: UFBCUP - INPUT BUFR FILE IS CLOSED, IT '//
     . 'MUST BE OPEN FOR INPUT')
901   CALL bort('BUFRLIB: UFBCUP - INPUT BUFR FILE IS OPEN FOR '//
     . 'OUTPUT, IT MUST BE OPEN FOR INPUT')
902   CALL bort('BUFRLIB: UFBCUP - A MESSAGE MUST BE OPEN IN INPUT '//
     . 'BUFR FILE, NONE ARE')
903   CALL bort('BUFRLIB: UFBCUP - LOCATION OF INTERNAL TABLE FOR '//
     . 'INPUT BUFR FILE DOES NOT AGREE WITH EXPECTED LOCATION IN '//
     . 'INTERNAL SUBSET ARRAY')
904   CALL bort('BUFRLIB: UFBCUP - OUTPUT BUFR FILE IS CLOSED, IT '//
     . 'MUST BE OPEN FOR OUTPUT')
905   CALL bort('BUFRLIB: UFBCUP - OUTPUT BUFR FILE IS OPEN FOR '//
     . 'INPUT, IT MUST BE OPEN FOR OUTPUT')
906   CALL bort('BUFRLIB: UFBCUP - A MESSAGE MUST BE OPEN IN OUTPUT '//
     . 'BUFR FILE, NONE ARE')
907   CALL bort('BUFRLIB: UFBCUP - THERE ARE NO ELEMENTS (TAGS) IN '//
     . 'INPUT SUBSET BUFFER')
      END