isetprm.f

Go to the documentation of this file.

C> @file
C> @brief Define a customized parameter value for dynamic allocation.
C>
C> @author J. Ator @date 2014-12-04
 
C> Define a customized parameter value for dynamic allocation.
C>
C> This function sets a specified parameter to a specified value for
C> use in dynamically allocating one or more internal arrays within
C> the BUFRLIB software.
C>
C> A separate call to this
C> function must be made for each parameter that is to be set to a
C> customized value, and all such calls must be made prior to the
C> first call to subroutine openbf() from within an application
C> program, because that is when all internal arrays are dynamically
C> allocated based on the parameter values in effect at the time.
C> Otherwise, if this function is never called for a particular
C> parameter, then an internal default value for that parameter is
C> used instead.
C>
C> @param[in] CPRMNM - character*(*): Parameter to be changed from its
C> internal default value:
C> - 'MXMSGL' = Maximum length (in bytes) of a BUFR message.
C> - 'MAXSS'  = Maximum number of data values in an uncompressed BUFR
C> subset.
C> - 'MXCDV'  = Maximum number of data values that can be written into a
C> compressed BUFR subset.
C> - 'MXLCC'  = Maximum length (in bytes) of a character string that can
C> be written into a compressed BUFR subset.
C> - 'MXCSB'  = Maximum number of subsets that can be written into a
C> compressed BUFR message.
C> - 'NFILES' = Maximum number of BUFR files that can be accessed for
C> reading or writing at any one time.
C> - 'MAXTBA' = Maximum number of entries in internal BUFR Table A per
C> BUFR file.
C> - 'MAXTBB' = Maximum number of entries in internal BUFR Table B per
C> BUFR file.
C> - 'MAXTBD' = Maximum number of entries in internal BUFR Table D per
C> BUFR file.
C> - 'MAXMEM' = Maximum number of bytes that can be used to store BUFR
C> messages in internal memory.
C> - 'MAXMSG' = Maximum number of BUFR messages that can be stored in
C> internal memory.
C> - 'MXDXTS' = Maximum number of dictionary tables that can be stored
C> for use with BUFR messages in internal memory.
C> - 'MXMTBB' = Maximum number of master Table B entries.
C> - 'MXMTBD' = Maximum number of master Table D entries.
C> - 'MXMTBF' = Maximum number of master Code/Flag entries.
C> - 'MAXCD'  = Maximum number of child descriptors in a Table D
C> descriptor sequence definition.
C> - 'MAXJL'  = Maximum number of entries in the internal jump/link table.
C> - 'MXS01V' = Maximum number of default Section 0 or Section 1 values
C> that can be overwritten within an output BUFR message.
C> - 'MXBTM'  = Maximum number of bitmaps that can be stored internally
C> for a BUFR subset.
C> - 'MXBTMSE' = Maximum number of entries that can be set within a bitmap.
C> - 'MXTAMC' = Maximum number of Table A mnemonics in the internal
C> jump/link table which contain at least one Table C operator with
C> XX >= 21 in their subset definition.
C> - 'MXTCO'  = Maximum number of Table C operators with XX >= 21 in the
C> subset definition of a Table A mnemonic.
C> - 'MXNRV'  = Maximum number of 2-03 reference values in the internal
C> jump/link table.
C> - 'MXRST'  = Maximum number of long character strings that can be
C> read from a compressed subset.
C> - 'MXH4WLC' = Maximum number of long character strings that can be
C> stored internally.
C> @param[in] IPVAL - integer: Value to be set for CPRMNM
C> @returns  isetprm - integer:
C> -  0 = normal return
C> - -1 = Unknown CPRMNM
C>
C> @author J. Ator @date 2014-12-04
        RECURSIVE FUNCTION isetprm ( CPRMNM, IPVAL ) RESULT ( IRET )
 
        USE modv_maxss
        USE modv_nfiles
        USE modv_mxmsgl
        USE modv_mxdxts
        USE modv_maxmsg
        USE modv_maxmem
        USE modv_maxtba
        USE modv_maxtbb
        USE modv_maxtbd
        USE modv_maxjl
        USE modv_mxcdv
        USE modv_mxlcc
        USE modv_mxcsb
        USE modv_mxmtbb
        USE modv_mxmtbd
        USE modv_mxmtbf
        USE modv_maxcd
        USE modv_mxs01v
        USE modv_mxbtm
        USE modv_mxbtmse
        USE modv_mxtamc
        USE modv_mxtco
        USE modv_mxnrv
        USE modv_mxrst
        USE modv_im8b
        USE modv_mxh4wlc
 
        CHARACTER*(*)   cprmnm
        CHARACTER*128   errstr
 
C-----------------------------------------------------------------------
C-----------------------------------------------------------------------
 
C       Check for I8 integers.
 
        IF ( im8b ) THEN
            im8b = .false.
 
            CALL x84 ( ipval, my_ipval, 1 )
            iret = isetprm( cprmnm, my_ipval )
 
            im8b = .true.
            RETURN
        ENDIF
 
        iret = 0
        IF ( cprmnm .EQ. 'MAXSS' ) THEN
            maxss = ipval
        ELSE IF ( cprmnm .EQ. 'NFILES' ) THEN
            nfiles = ipval
        ELSE IF ( cprmnm .EQ. 'MXMSGL' ) THEN
            mxmsgl = ipval
        ELSE IF ( cprmnm .EQ. 'MXDXTS' ) THEN
            mxdxts = ipval
        ELSE IF ( cprmnm .EQ. 'MAXMSG' ) THEN
            maxmsg = ipval
        ELSE IF ( cprmnm .EQ. 'MAXMEM' ) THEN
            maxmem = ipval
        ELSE IF ( cprmnm .EQ. 'MAXTBA' ) THEN
            maxtba = ipval
        ELSE IF ( cprmnm .EQ. 'MAXTBB' ) THEN
            maxtbb = ipval
        ELSE IF ( cprmnm .EQ. 'MAXTBD' ) THEN
            maxtbd = ipval
        ELSE IF ( cprmnm .EQ. 'MAXJL' ) THEN
            maxjl = ipval
        ELSE IF ( cprmnm .EQ. 'MXCDV' ) THEN
            mxcdv = ipval
        ELSE IF ( cprmnm .EQ. 'MXLCC' ) THEN
            mxlcc = ipval
        ELSE IF ( cprmnm .EQ. 'MXCSB' ) THEN
            mxcsb = ipval
        ELSE IF ( cprmnm .EQ. 'MXMTBB' ) THEN
            mxmtbb = ipval
        ELSE IF ( cprmnm .EQ. 'MXMTBD' ) THEN
            mxmtbd = ipval
        ELSE IF ( cprmnm .EQ. 'MXMTBF' ) THEN
            mxmtbf = ipval
        ELSE IF ( cprmnm .EQ. 'MAXCD' ) THEN
            maxcd = ipval
        ELSE IF ( cprmnm .EQ. 'MXS01V' ) THEN
            mxs01v = ipval
        ELSE IF ( cprmnm .EQ. 'MXBTM' ) THEN
            mxbtm = ipval
        ELSE IF ( cprmnm .EQ. 'MXBTMSE' ) THEN
            mxbtmse = ipval
        ELSE IF ( cprmnm .EQ. 'MXTAMC' ) THEN
            mxtamc = ipval
        ELSE IF ( cprmnm .EQ. 'MXTCO' ) THEN
            mxtco = ipval
        ELSE IF ( cprmnm .EQ. 'MXNRV' ) THEN
            mxnrv = ipval
        ELSE IF ( cprmnm .EQ. 'MXRST' ) THEN
            mxrst = ipval
        ELSE IF ( cprmnm .EQ. 'MXH4WLC' ) THEN
            mxh4wlc = ipval
        ELSE
            iret = -1
            CALL errwrt('++++++++++++++++++WARNING+++++++++++++++++++')
            errstr = 'BUFRLIB: ISETPRM - UNKNOWN INPUT PARAMETER '//
     .          cprmnm // ' -- NO ACTION WAS TAKEN'
            CALL errwrt(errstr)
            CALL errwrt('++++++++++++++++++WARNING+++++++++++++++++++')
        ENDIF
 
        RETURN
        END