nmsub.f

Go to the documentation of this file.

C> @file
C> @brief Get the number of data subsets from a BUFR message.
C>
C> @author J. Woollen @date 1994-01-06
 
C> This function returns the total number of data subsets available
C> within the BUFR message that was most recently opened for reading
C> via a call to one of the other
C> [message-reading subroutines](@ref hierarchy)
C> for a specified Fortran logical unit.
C>
C> The data subsets themselves do not need to have already been
C> read via previous calls to any of the
C> [subset-reading subroutines](@ref hierarchy).
C>
C> @param[in] LUNIT -- integer: Fortran logical unit number for
C>                     BUFR file
C> @returns nmsub   -- integer: Number of data subsets
C>
C> @author J. Woollen @date 1994-01-06
      RECURSIVE FUNCTION nmsub(LUNIT) RESULT(IRET)
 
      USE modv_im8b
 
      USE moda_msgcwd
 
C-----------------------------------------------------------------------
C-----------------------------------------------------------------------
 
C  CHECK FOR I8 INTEGERS
C  ---------------------
 
      IF(im8b) THEN
         im8b=.false.
 
         CALL x84(lunit,my_lunit,1)
         iret=nmsub(my_lunit)
 
         im8b=.true.
         RETURN
      ENDIF
 
      iret = 0
 
C  CHECK THE FILE STATUS
C  ---------------------
 
      CALL status(lunit,lun,il,im)
      IF(il.EQ.0) GOTO 900
      IF(il.GT.0) GOTO 901
      IF(im.EQ.0) GOTO 902
 
      iret = msub(lun)
 
C  EXITS
C  -----
 
      RETURN
900   CALL bort('BUFRLIB: NMSUB - INPUT BUFR FILE IS CLOSED, IT MUST '//
     . 'BE OPEN FOR INPUT')
901   CALL bort('BUFRLIB: NMSUB - INPUT BUFR FILE IS OPEN FOR OUTPUT,'//
     . ' IT MUST BE OPEN FOR INPUT')
902   CALL bort('BUFRLIB: NMSUB - A MESSAGE MUST BE OPEN IN INPUT '//
     . 'BUFR FILE, NONE ARE')
      END