skgb.f

Go to the documentation of this file.

C>    @file
C>    @brief This subroutine generates an index record for each field in
C>    a grib2 message.
C>    @author Mark Iredell @date 1995-10-31
C>
 
C>    This subroutine searches a file for the next grib 1 message. A grib 
C>    1 message is identified by its indicator section, i.e. an 8-byte
C>    sequence with 'grib' in bytes 1-4 and 1 in byte 8. If found, the
C>    length of the message is decoded from bytes 5-7. The search is
C>    done over a given section of the file. The search is terminated if
C>    an eof or i/o error is encountered.
C>    PROGRAM HISTORY LOG:
C>    - 1993-11-22 Mark Iredell
C>    - 1995-10-31 Mark Iredell add call to baread.
C>    - 1997-03-14 Mark Iredell check for '7777'.
C>    - 2001-12-05 Stephen Gilbert modified to also look for grib2
C>    messages.
C>    - 2009-12-14 Boi Vuong modified to increase length of seek (512).
C>    
C>    @param[in] LUGB integer unit of the unblocked grib file.
C>    @param[in] ISEEK integer number of bytes to skip before search.
C>    @param[in] MSEEK integer maximum number of bytes to search.
C>    @param[out] LSKIP integer number of bytes to skip before message.
C>    @param[out] LGRIB integer number of bytes in message (0 if not
C>    found)
C>    
C>    @author Mark Iredell @date 1995-10-31
C>    
 
C-----------------------------------------------------------------------
      SUBROUTINE skgb(LUGB,ISEEK,MSEEK,LSKIP,LGRIB)
 
      parameter(lseek=512)
      CHARACTER Z(LSEEK)
      CHARACTER Z4(4)
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      lgrib=0
      ks=iseek
      kn=min(lseek,mseek)
      kz=lseek
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
C  LOOP UNTIL GRIB MESSAGE IS FOUND
      dowhile(lgrib.EQ.0.AND.kn.GE.8.AND.kz.EQ.lseek)
C  READ PARTIAL SECTION
        CALL baread(lugb,ks,kn,kz,z)
        km=kz-8+1
        k=0
C  LOOK FOR 'GRIB...1' IN PARTIAL SECTION
        dowhile(lgrib.EQ.0.AND.k.LT.km)
          CALL g2_gbytec(z,i4,(k+0)*8,4*8)
          CALL g2_gbytec(z,i1,(k+7)*8,1*8)
          IF(i4.EQ.1196575042.AND.(i1.EQ.1.OR.i1.EQ.2)) THEN
C  LOOK FOR '7777' AT END OF GRIB MESSAGE
            IF (i1.EQ.1) CALL g2_gbytec(z,kg,(k+4)*8,3*8)
            IF (i1.EQ.2) CALL g2_gbytec(z,kg,(k+12)*8,4*8)
            CALL baread(lugb,ks+k+kg-4,4,k4,z4)
            IF(k4.EQ.4) THEN
              CALL g2_gbytec(z4,i4,0,4*8)
              IF(i4.EQ.926365495) THEN
C  GRIB MESSAGE FOUND
                lskip=ks+k
                lgrib=kg
              ENDIF
            ENDIF
          ENDIF
          k=k+1
        ENDDO
        ks=ks+km
        kn=min(lseek,iseek+mseek-ks)
      ENDDO
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      RETURN
      END