movect.F90

Go to the documentation of this file.

 
 
 SUBROUTINE movect(FLAT,FLON,TLAT,TLON,CROT,SROT)
 IMPLICIT NONE
!
 INTEGER,         PARAMETER     :: KD=selected_real_kind(15,45)
!
 REAL,            INTENT(IN   ) :: FLAT, FLON
 REAL,            INTENT(IN   ) :: TLAT, TLON
 REAL,            INTENT(  OUT) :: CROT, SROT
!
 REAL(KIND=kd),   PARAMETER     :: crdlim=0.9999999
 REAL(KIND=kd),   PARAMETER     :: pi=3.14159265358979
 REAL(KIND=kd),   PARAMETER     :: dpr=180./pi
!
 REAL(KIND=kd)                  :: ctlat,stlat,cflat,sflat
 REAL(KIND=kd)                  :: cdlon,sdlon,crd
 REAL(KIND=kd)                  :: srd2rn,str,ctr,sfr,cfr
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!  COMPUTE COSINE OF THE RADIAL DISTANCE BETWEEN THE POINTS.
 ctlat=cos(tlat/dpr)
 stlat=sin(tlat/dpr)
 cflat=cos(flat/dpr)
 sflat=sin(flat/dpr)
 cdlon=cos((flon-tlon)/dpr)
 sdlon=sin((flon-tlon)/dpr)
 crd=stlat*sflat+ctlat*cflat*cdlon
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!  COMPUTE ROTATIONS AT BOTH POINTS WITH RESPECT TO THE GREAT CIRCLE
!  AND COMBINE THEM TO GIVE THE TOTAL VECTOR ROTATION PARAMETERS.
 IF(abs(crd).LE.crdlim) THEN
   srd2rn=-1/(1-crd**2)
   str=cflat*sdlon
   ctr=cflat*stlat*cdlon-sflat*ctlat
   sfr=ctlat*sdlon
   cfr=ctlat*sflat*cdlon-stlat*cflat
   crot=real(srd2rn*(ctr*cfr-str*sfr))
   srot=real(srd2rn*(ctr*sfr+str*cfr))
!  USE A DIFFERENT APPROXIMATION FOR NEARLY COINCIDENT POINTS.
!  MOVING VECTORS TO ANTIPODAL POINTS IS AMBIGUOUS ANYWAY.
 ELSE
   crot=real(cdlon)
   srot=real(sdlon*stlat)
 ENDIF
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
 END SUBROUTINE movect