spffte.f

Go to the documentation of this file.

C> @file
C> @brief Perform multiple fast Fourier transforms.
C>
C> ### Program History Log
C> Date | Programmer | Comments
C> -----|------------|---------
C> 1998-12-18 | Iredell | Initial.
C> 2012-11-12 | Mirvis | fixing hard-wired types problem on Intel/Linux.
C>
C> @author Iredell @date 96-02-20
 
C> This subprogram performs multiple fast Fourier transforms
C> between complex amplitudes in Fourier space and real values
C> in cyclic physical space.
C>
C> This subprogram must be invoked first with IDIR=0
C> to initialize trigonemetric data. Use subprogram spfft1()
C> to perform an FFT without previous initialization.
C>
C> This version invokes the IBM ESSL FFT.
C>
C> @note The restrictions on IMAX are that it must be a multiple
C> of 1 to 25 factors of two, up to 2 factors of three,
C> and up to 1 factor of five, seven and eleven.
C>
C> If IDIR=0, then W and G need not contain any valid data.
C> The other parameters must be supplied and cannot change
C> in succeeding calls until the next time it is called with IDIR=0.
C>
C> This subprogram is thread-safe.
C>      
C> @param IMAX number of values in the cyclic physical space
C> (see limitations on imax in remarks below.)
C> @param INCW first dimension of the complex amplitude array
C> (INCW >= IMAX/2+1)
C> @param INCG first dimension of the real value array
C> (INCG >= IMAX)
C> @param KMAX number of transforms to perform
C> @param[out] W complex amplitudes if IDIR>0
C> @param[out] G real values if IDIR<0
C> @param IDIR  direction flag
C> - IDIR=0 to initialize trigonometric data
C> - IDIR>0 to transform from Fourier to physical space
C> - IDIR<0 to transform from physical to Fourier space
C> @param[out] AFFT auxiliary array if IDIR<>0
C>
C> @author Iredell @date 96-02-20
      SUBROUTINE spffte(IMAX,INCW,INCG,KMAX,W,G,IDIR,AFFT)
        IMPLICIT NONE
        INTEGER,INTENT(IN):: IMAX,INCW,INCG,KMAX,IDIR
        REAL,INTENT(INOUT):: W(2*INCW,KMAX)
        REAL,INTENT(INOUT):: G(INCG,KMAX)
        REAL(8),INTENT(INOUT):: AFFT(50000+4*IMAX)
        REAL:: AFFTR(50000+4*IMAX)
        INTEGER:: INIT,INC2X,INC2Y,N,M,ISIGN,NAUX1,NAUX2,NAUX3
C ==EM==       ^(4)
        REAL:: SCALE
        REAL :: AUX2(20000+2*IMAX),AUX3
        INTEGER:: IACR,IARC
 
        naux1=25000+2*imax
        naux2=20000+2*imax
        naux3=1
        iacr=1
        iarc=1+naux1
        afftr=real(afft)
 
C  INITIALIZATION.
C  FILL AUXILIARY ARRAYS WITH TRIGONOMETRIC DATA
        SELECT CASE(idir)
          CASE(0)
            init=1
            inc2x=incw
            inc2y=incg
            n=imax
            m=kmax
            isign=-1
            scale=1.
            IF(digits(1.).LT.digits(1._8)) THEN
              CALL scrft(init,w,inc2x,g,inc2y,n,m,isign,scale,
     &                   afftr(iacr),naux1,aux2,naux2,aux3,naux3)
            ELSE
              CALL dcrft(init,w,inc2x,g,inc2y,n,m,isign,scale,
     &                   afftr(iacr),naux1,aux2,naux2)
            ENDIF
            init=1
            inc2x=incg
            inc2y=incw
            n=imax
            m=kmax
            isign=+1
            scale=1./imax
            IF(digits(1.).LT.digits(1._8)) THEN
              CALL srcft(init,g,inc2x,w,inc2y,n,m,isign,scale,
     &                   afftr(iarc),naux1,aux2,naux2,aux3,naux3)
            ELSE
              CALL drcft(init,g,inc2x,w,inc2y,n,m,isign,scale,
     &                   afftr(iarc),naux1,aux2,naux2)
            ENDIF
 
C  FOURIER TO PHYSICAL TRANSFORM.
          CASE(1:)
            init=0
            inc2x=incw
            inc2y=incg
            n=imax
            m=kmax
            isign=-1
            scale=1.
            IF(digits(1.).LT.digits(1._8)) THEN
              CALL scrft(init,w,inc2x,g,inc2y,n,m,isign,scale,
     &                   afftr(iacr),naux1,aux2,naux2,aux3,naux3)
            ELSE
              CALL dcrft(init,w,inc2x,g,inc2y,n,m,isign,scale,
     &                   afftr(iacr),naux1,aux2,naux2)
            ENDIF
 
C  PHYSICAL TO FOURIER TRANSFORM.
          CASE(:-1)
            init=0
            inc2x=incg
            inc2y=incw
            n=imax
            m=kmax
            isign=+1
            scale=1./imax
            IF(digits(1.).LT.digits(1._8)) THEN
              CALL srcft(init,g,inc2x,w,inc2y,n,m,isign,scale,
     &                   afftr(iarc),naux1,aux2,naux2,aux3,naux3)
            ELSE
              CALL drcft(init,g,inc2x,w,inc2y,n,m,isign,scale,
     &                   afftr(iarc),naux1,aux2,naux2)
            ENDIF
        END SELECT
        afft=real(afftr,kind=8)
      END SUBROUTINE