sptgpt.f

Go to the documentation of this file.

C> @file
C> @brief Transform spectral scalar to station points.
C>
C> ### Program History Log
C> Date | Programmer | Comments
C> -----|------------|---------
C> 96-02-29 | Iredell | Initial.
C> 1998-12-15 | Iredell | Openmp directives inserted.
C> 2003-06-30 | Iredell | Use spfftpt().
C>
C> @author Iredell @date 96-02-29
 
C> This subprogram performs a spherical transform
c> from spectral coefficients of scalar quantities
c> to specified sets of station points on the globe.
C>
C> The wave-space can be either triangular or rhomboidal.
C>
C> The wave and point fields may have general indexing,
c> but each wave field is in sequential 'IBM order',
c> i.e. with zonal wavenumber as the slower index.
C>
C> The transforms are all multiprocessed over stations.
C>
C> Transform several fields at a time to improve vectorization.
C>
C> Subprogram can be called from a multiprocessing environment.
C>
C> @param IROMB spectral domain shape
C> (0 for triangular, 1 for rhomboidal)
C> @param MAXWV spectral truncation
C> @param KMAX number of fields to transform.
C> @param NMAX number of station points to return
C> @param KWSKIP skip number between wave fields
C> (defaults to (MAXWV+1)*((IROMB+1)*MAXWV+2) if KWSKIP=0)
C> @param KGSKIP skip number between station point sets
C> (defaults to NMAX if KGSKIP=0)
C> @param NRSKIP skip number between station lats and lons
C> (defaults to 1 if NRSKIP=0)
C> @param NGSKIP skip number between station points
C> (defaults to 1 if NGSKIP=0)
C> @param RLAT station latitudes in degrees
C> @param RLON station longitudes in degrees
C> @param WAVE wave fields
C> @param GP station point sets
C>
C> @author Iredell @date 96-02-29
      SUBROUTINE sptgpt(IROMB,MAXWV,KMAX,NMAX,
     &                  KWSKIP,KGSKIP,NRSKIP,NGSKIP,
     &                  RLAT,RLON,WAVE,GP)
 
      REAL RLAT(*),RLON(*),WAVE(*),GP(*)
      REAL EPS((MAXWV+1)*((IROMB+1)*MAXWV+2)/2),EPSTOP(MAXWV+1)
      REAL ENN1((MAXWV+1)*((IROMB+1)*MAXWV+2)/2)
      REAL ELONN1((MAXWV+1)*((IROMB+1)*MAXWV+2)/2)
      REAL EON((MAXWV+1)*((IROMB+1)*MAXWV+2)/2),EONTOP(MAXWV+1)
      INTEGER MP(KMAX)
      REAL WTOP(2*(MAXWV+1),KMAX)
      REAL PLN((MAXWV+1)*((IROMB+1)*MAXWV+2)/2),PLNTOP(MAXWV+1)
      REAL F(2*MAXWV+3,2,KMAX)
      parameter(pi=3.14159265358979)
 
C  CALCULATE PRELIMINARY CONSTANTS
      CALL spwget(iromb,maxwv,eps,epstop,enn1,elonn1,eon,eontop)
      mx=(maxwv+1)*((iromb+1)*maxwv+2)/2
      mxtop=maxwv+1
      idim=2*maxwv+3
      kw=kwskip
      kg=kgskip
      nr=nrskip
      ng=ngskip
      IF(kw.EQ.0) kw=2*mx
      IF(kg.EQ.0) kg=nmax
      IF(nr.EQ.0) nr=1
      IF(ng.EQ.0) ng=1
      mp=0
C$OMP PARALLEL DO
      DO k=1,kmax
        wtop(1:2*mxtop,k)=0
      ENDDO
 
C  CALCULATE STATION FIELDS
C$OMP PARALLEL DO PRIVATE(RADLAT,SLAT1,CLAT1)
C$OMP&            PRIVATE(PLN,PLNTOP,F,NK)
      DO n=1,nmax
        radlat=pi/180*rlat((n-1)*nr+1)
        IF(rlat((n-1)*nr+1).GE.89.9995) THEN
          slat1=1.
          clat1=0.
        ELSEIF(rlat((n-1)*nr+1).LE.-89.9995) THEN
          slat1=-1.
          clat1=0.
        ELSE
          slat1=sin(radlat)
          clat1=cos(radlat)
        ENDIF
        CALL splegend(iromb,maxwv,slat1,clat1,eps,epstop,
     &                pln,plntop)
        CALL spsynth(iromb,maxwv,2*maxwv,idim,kw,2*mxtop,kmax,
     &               clat1,pln,plntop,mp,wave,wtop,f)
        CALL spfftpt(maxwv,1,2*maxwv+3,kg,kmax,rlon((n-1)*nr+1),
     &               f,gp((n-1)*ng+1))
      ENDDO
      END