sptgptsd.f

Go to the documentation of this file.

C> @file
C> @brief Transform spectral scalar to station points.
C> @author Iredell @date 96-02-29
C>
C> ### Program History Log
C> Date | Programmer | Comments
C> -----|------------|---------
C> 96-02-29 | Iredell | Initial.
C> 1998-12-15 | Iredell | Openmp directives inserted.
C> 1999-08-18 | Iredell | Openmp directive typo fixed.
C>
C> @author Iredell @date 96-02-29
 
C> This subprogram performs a spherical transform
C> from spectral coefficients of scalar quantities
C> to specified sets of station point values
C> and their gradients on the globe.
C>
C> The wave-space can be either triangular or rhomboidal.
C>
C> The wave and point fields may have general indexing,
C> but each wave field is in sequential 'IBM order',
C> i.e. with zonal wavenumber as the slower index.
C>
C> The transforms are all multiprocessed over stations.
C>
C> Transform several fields at a time to improve vectorization.
C>
C> Subprogram can be called from a multiprocessing environment.
C>
C> @param IROMB spectral domain shape
C> (0 for triangular, 1 for rhomboidal)
C> @param MAXWV spectral truncation
C> @param KMAX number of fields to transform.
C> @param NMAX number of station points to return
C> @param KWSKIP skip number between wave fields
C> (defaults to (MAXWV+1)*((IROMB+1)*MAXWV+2) if KWSKIP=0)
C> @param KGSKIP skip number between station point sets
C> (defaults to NMAX if KGSKIP=0)
C> @param NRSKIP skip number between station lats and lons
C> (defaults to 1 if NRSKIP=0)
C> @param NGSKIP skip number between station points
C> (defaults to 1 if NGSKIP=0)
C> @param RLAT station latitudes in degrees
C> @param RLON station longitudes in degrees
C> @param WAVE wave fields
C> @param GP station point sets
C> @param XP station point x-gradient sets
C> @param YP station point y-gradient sets
C>
C> @author Iredell @date 96-02-29
      SUBROUTINE sptgptsd(IROMB,MAXWV,KMAX,NMAX,
     &                    KWSKIP,KGSKIP,NRSKIP,NGSKIP,
     &                    RLAT,RLON,WAVE,GP,XP,YP)
 
      REAL RLAT(*),RLON(*),WAVE(*)
      REAL GP(*),XP(*),YP(*)
      REAL EPS((MAXWV+1)*((IROMB+1)*MAXWV+2)/2),EPSTOP(MAXWV+1)
      REAL ENN1((MAXWV+1)*((IROMB+1)*MAXWV+2)/2)
      REAL ELONN1((MAXWV+1)*((IROMB+1)*MAXWV+2)/2)
      REAL EON((MAXWV+1)*((IROMB+1)*MAXWV+2)/2),EONTOP(MAXWV+1)
      INTEGER MP(2*KMAX)
      REAL W((MAXWV+1)*((IROMB+1)*MAXWV+2)/2*2,2*KMAX)
      REAL WTOP(2*(MAXWV+1),2*KMAX)
      REAL PLN((MAXWV+1)*((IROMB+1)*MAXWV+2)/2),PLNTOP(MAXWV+1)
      REAL F(2*MAXWV+2,2,3*KMAX),G(3*KMAX)
      parameter(pi=3.14159265358979)
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
C  CALCULATE PRELIMINARY CONSTANTS
      CALL spwget(iromb,maxwv,eps,epstop,enn1,elonn1,eon,eontop)
      mx=(maxwv+1)*((iromb+1)*maxwv+2)/2
      mxtop=maxwv+1
      mdim=2*mx
      idim=2*maxwv+2
      kw=kwskip
      kg=kgskip
      nr=nrskip
      ng=ngskip
      IF(kw.EQ.0) kw=2*mx
      IF(kg.EQ.0) kg=nmax
      IF(nr.EQ.0) nr=1
      IF(ng.EQ.0) ng=1
      mp(1:kmax)=10
      mp(kmax+1:2*kmax)=1
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
C  CALCULATE SPECTRAL WINDS
C$OMP PARALLEL DO PRIVATE(KWS,KS,KY)
      DO k=1,kmax
        kws=(k-1)*kw
        ks=0*kmax+k
        ky=1*kmax+k
        DO i=1,2*mx
          w(i,ks)=wave(kws+i)
        ENDDO
        DO i=1,2*mxtop
          wtop(i,ks)=0
        ENDDO
        CALL spgrady(iromb,maxwv,enn1,eon,eontop,
     &               wave(kws+1),w(1,ky),wtop(1,ky))
      ENDDO
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
C  CALCULATE STATION FIELDS
C$OMP PARALLEL DO PRIVATE(KS,KY,KX,SLAT1,CLAT1)
C$OMP&            PRIVATE(PLN,PLNTOP,F,G,NK)
      DO n=1,nmax
        IF(abs(rlat((n-1)*nr+1)).GE.89.9995) THEN
          slat1=sign(1.,rlat((n-1)*nr+1))
          clat1=0.
        ELSE
          slat1=sin(pi/180*rlat((n-1)*nr+1))
          clat1=cos(pi/180*rlat((n-1)*nr+1))
        ENDIF
        CALL splegend(iromb,maxwv,slat1,clat1,eps,epstop,
     &                pln,plntop)
        CALL spsynth(iromb,maxwv,2*maxwv,idim,mdim,2*mxtop,2*kmax,
     &               clat1,pln,plntop,mp,w,wtop,f)
        CALL spgradx(maxwv,idim,kmax,mp,clat1,f(1,1,1),f(1,1,2*kmax+1))
        CALL spfftpt(maxwv,1,idim,1,3*kmax,rlon((n-1)*nr+1),f,g)
        DO k=1,kmax
          ks=0*kmax+k
          ky=1*kmax+k
          kx=2*kmax+k
          nk=(n-1)*ng+(k-1)*kg+1
          gp(nk)=g(ks)
          xp(nk)=g(kx)
          yp(nk)=g(ky)
        ENDDO
      ENDDO
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      END