sptranv.f

Go to the documentation of this file.

C> @file
C> @brief Perform a vector spherical transform.
C>
C> ### Program History Log
C> Date | Programmer | Comments
C> -----|------------|---------
C> 96-02-29 | IREDELL | Initial.
C> 1998-12-15 | IREDELL | Generic fft used, openmp directives inserted
C>
C> @author IREDELL @date 96-02-29
 
C> This subprogram performs a spherical transform
C> between spectral coefficients of divergences and curls
C> and vector fields on a global cylindrical grid.
C>
C> The wave-space can be either triangular or rhomboidal.
C>
C> The grid-space can be either an equally-spaced grid
C> (with or without pole points) or a Gaussian grid.
C> the wave and grid fields may have general indexing,
C> but each wave field is in sequential 'ibm order',
C> i.e. with zonal wavenumber as the slower index.
C>
C> Transforms are done in latitude pairs for efficiency;
C> thus grid arrays for each hemisphere must be passed.
C> If so requested, just a subset of the latitude pairs
C> may be transformed in each invocation of the subprogram.
C>
C> The transforms are all multiprocessed over latitude except
C> the transform from fourier to spectral is multiprocessed
C> over zonal wavenumber to ensure reproducibility.
C>
C> Transform several fields at a time to improve vectorization.
C> Subprogram can be called from a multiprocessing environment.
C>
C> Minimum grid dimensions for unaliased transforms to spectral:
C> DIMENSION                    |LINEAR              |QUADRATIC
C> -----------------------      |---------           |-------------
C> IMAX                         |2*MAXWV+2           |3*MAXWV/2*2+2
C> JMAX (IDRT=4,IROMB=0)        |1*MAXWV+1           |3*MAXWV/2+1
C> JMAX (IDRT=4,IROMB=1)        |2*MAXWV+1           |5*MAXWV/2+1
C> JMAX (IDRT=0,IROMB=0)        |2*MAXWV+3           |3*MAXWV/2*2+3
C> JMAX (IDRT=0,IROMB=1)        |4*MAXWV+3           |5*MAXWV/2*2+3
C> JMAX (IDRT=256,IROMB=0)      |2*MAXWV+1           |3*MAXWV/2*2+1
C> JMAX (IDRT=256,IROMB=1)      |4*MAXWV+1           |5*MAXWV/2*2+1
C>
C> @param IROMB SPECTRAL DOMAIN SHAPE
C> (0 FOR TRIANGULAR, 1 FOR RHOMBOIDAL)
C> @param MAXWV SPECTRAL TRUNCATION
C> @param IDRT  GRID IDENTIFIER
C> - IDRT=4 FOR GAUSSIAN GRID,
C> - IDRT=0 FOR EQUALLY-SPACED GRID INCLUDING POLES,
C> - IDRT=256 FOR EQUALLY-SPACED GRID EXCLUDING POLES
C> @param IMAX EVEN NUMBER OF LONGITUDES.
C> @param JMAX NUMBER OF LATITUDES.
C> @param KMAX NUMBER OF FIELDS TO TRANSFORM.
C> @param IPRIME LONGITUDE INDEX FOR THE PRIME MERIDIAN.
C> (DEFAULTS TO 1 IF IPRIME=0)
C> @param ISKIP SKIP NUMBER BETWEEN LONGITUDES
C> (DEFAULTS TO 1 IF ISKIP=0)
C> @param JNSKIP SKIP NUMBER BETWEEN N.H. LATITUDES FROM NORTH
C> (DEFAULTS TO IMAX IF JNSKIP=0)
C> @param JSSKIP SKIP NUMBER BETWEEN S.H. LATITUDES FROM SOUTH
C> (DEFAULTS TO -IMAX IF JSSKIP=0)
C> @param KWSKIP SKIP NUMBER BETWEEN WAVE FIELDS
C> (DEFAULTS TO (MAXWV+1)*((IROMB+1)*MAXWV+2) IF KWSKIP=0)
C> @param KGSKIP SKIP NUMBER BETWEEN GRID FIELDS
C> (DEFAULTS TO IMAX*JMAX IF KGSKIP=0)
C> @param JBEG LATITUDE INDEX (FROM POLE) TO BEGIN TRANSFORM
C> - DEFAULTS TO 1 IF JBEG=0
C> - IF JBEG=0 AND IDIR<0, WAVE IS ZEROED BEFORE TRANSFORM
C> @param JEND LATITUDE INDEX (FROM POLE) TO END TRANSFORM
C> (DEFAULTS TO (JMAX+1)/2 IF JEND=0)
C> @param JCPU NUMBER OF CPUS OVER WHICH TO MULTIPROCESS
C> @param[out] WAVED (*) WAVE DIVERGENCE FIELDS IF IDIR>0
C> [WAVED=(D(GRIDU)/DLAM+D(CLAT*GRIDV)/DPHI)/(CLAT*RERTH)]
C> @param[out] WAVEZ (*) WAVE VORTICITY FIELDS IF IDIR>0
C> [WAVEZ=(D(GRIDV)/DLAM-D(CLAT*GRIDU)/DPHI)/(CLAT*RERTH)]
C> @param[out] GRIDUN N.H. GRID U-WINDS (STARTING AT JBEG) IF IDIR<0
C> @param[out] GRIDUS S.H. GRID U-WINDS (STARTING AT JBEG) IF IDIR<0
C> @param[out] GRIDVN N.H. GRID V-WINDS (STARTING AT JBEG) IF IDIR<0
C> @param[out] GRIDVS S.H. GRID V-WINDS (STARTING AT JBEG) IF IDIR<0
C> @param IDIR TRANSFORM FLAG
C> - IDIR>0 FOR WAVE TO GRID,
C> - IDIR<0 FOR GRID TO WAVE
C>
      SUBROUTINE sptranv(IROMB,MAXWV,IDRT,IMAX,JMAX,KMAX,
     &                   IPRIME,ISKIP,JNSKIP,JSSKIP,KWSKIP,KGSKIP,
     &                   JBEG,JEND,JCPU,
     &                   WAVED,WAVEZ,GRIDUN,GRIDUS,GRIDVN,GRIDVS,IDIR)
 
      REAL WAVED(*),WAVEZ(*),GRIDUN(*),GRIDUS(*),GRIDVN(*),GRIDVS(*)
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      MX=(maxwv+1)*((iromb+1)*maxwv+2)/2
      ip=iprime
      is=iskip
      jn=jnskip
      js=jsskip
      kw=kwskip
      kg=kgskip
      jb=jbeg
      je=jend
      jc=jcpu
      IF(ip.EQ.0) ip=1
      IF(is.EQ.0) is=1
      IF(jn.EQ.0) jn=imax
      IF(js.EQ.0) js=-jn
      IF(kw.EQ.0) kw=2*mx
      IF(kg.EQ.0) kg=imax*jmax
      IF(jb.EQ.0) jb=1
      IF(je.EQ.0) je=(jmax+1)/2
      IF(jc.EQ.0) jc=ncpus()
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      IF(idir.LT.0.AND.jbeg.EQ.0) THEN
        DO k=1,kmax
          kws=(k-1)*kw
          waved(kws+1:kws+2*mx)=0
          wavez(kws+1:kws+2*mx)=0
        ENDDO
      ENDIF
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      CALL sptranfv(iromb,maxwv,idrt,imax,jmax,kmax,
     &              ip,is,jn,js,kw,kg,jb,je,jc,
     &              waved,wavez,gridun,gridus,gridvn,gridvs,idir)
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      END