spgrady.f

Go to the documentation of this file.

C> @file
C> @brief Compute y-gradient in spectral space.
C> @author IREDELL @date 92-10-31
 
C> Computes the horizontal vector y-gradient of a scalar field
c> in spectral space.
C>
C> Subprogram speps should be called already.
C>
C> If L is the zonal wavenumber, N is the total wavenumber,
C> EPS(L,N)=SQRT((N**2-L**2)/(4*N**2-1)) and A is Earth radius,
C> then the meridional gradient of Q(L,N) is computed as
C> EPS(L,N+1)*(N+2)/A*Q(L,N+1)-EPS(L,N+1)*(N-1)/A*Q(L,N-1).
C>
C> Extra terms are computed over top of the spectral domain.
C>
C> Advantage is taken of the fact that EPS(L,L)=0
C> in order to vectorize over the entire spectral domain.
C>
C> @param I spectral domain shape
c> (0 for triangular, 1 for rhomboidal)
C> @param M spectral truncation
C> @param ENN1 N*(N+1)/A**2
C> @param EON EPSILON/N*A
C> @param EONTOP EPSILON/N*A over top
C> @param Q scalar field
C> @param QDY merid gradient (times coslat)
C> @param QDYTOP merid gradient (times coslat) over top
C>
C> @author IREDELL @date 92-10-31
      SUBROUTINE spgrady(I,M,ENN1,EON,EONTOP,Q,QDY,QDYTOP)
 
      REAL ENN1((M+1)*((I+1)*M+2)/2)
      REAL EON((M+1)*((I+1)*M+2)/2),EONTOP(M+1)
      REAL Q((M+1)*((I+1)*M+2))
      REAL QDY((M+1)*((I+1)*M+2))
      REAL QDYTOP(2*(M+1))
 
C  TAKE MERIDIONAL GRADIENT
      k=1
      qdy(2*k-1)=eon(k+1)*enn1(k+1)*q(2*k+1)
      qdy(2*k)=eon(k+1)*enn1(k+1)*q(2*k+2)
      DO k=2,(m+1)*((i+1)*m+2)/2-1
        qdy(2*k-1)=eon(k+1)*enn1(k+1)*q(2*k+1)-eon(k)*enn1(k-1)*q(2*k-3)
        qdy(2*k)=eon(k+1)*enn1(k+1)*q(2*k+2)-eon(k)*enn1(k-1)*q(2*k-2)
      ENDDO
      k=(m+1)*((i+1)*m+2)/2
      qdy(2*k-1)=-eon(k)*enn1(k-1)*q(2*k-3)
      qdy(2*k)=-eon(k)*enn1(k-1)*q(2*k-2)
 
C  TAKE MERIDIONAL GRADIENT OVER TOP
      DO l=0,m
        k=l*(2*m+(i-1)*(l-1))/2+i*l+m+1
        qdytop(2*l+1)=-eontop(l+1)*enn1(k)*q(2*k-1)
        qdytop(2*l+2)=-eontop(l+1)*enn1(k)*q(2*k)
      ENDDO
 
      RETURN
      END