sptgptv.f

Go to the documentation of this file.

C> @file
C> @brief Transform spectral vector to station points.
C>
C> ### Program History Log
C> Date | Programmer | Comments
C> -----|------------|---------
C> 96-02-29 | IREDELL | Initial
C> 1998-12-15 | IREDELL | Openmp directives inserted
C> 1999-08-18 | IREDELL | Openmp directive typo fixed 
C> 2003-06-30 | IREDELL | use spfftpt()
C>
C> @author IREDELL @date 96-02-29
 
C> This subprogram performs a spherical transform
C> from spectral coefficients of divergences and curls
C> to specified sets of station point vectors on the globe.
C>
C> The wave-space can be either triangular or rhomboidal.
C>
C> The wave and point fields may have general indexing,
C> but each wave field is in sequential 'IBM order',
C> i.e. with zonal wavenumber as the slower index.
C>
C> The transforms are all multiprocessed over stations.
C>
C> Transform several fields at a time to improve vectorization.
C>
C> Subprogram can be called from a multiprocessing environment.
C>
C> @param IROMB spectral domain shape
c> (0 for triangular, 1 for rhomboidal)
C> @param MAXWV spectral truncation
C> @param KMAX number of fields to transform.
C> @param NMAX number of station points to return
C> @param KWSKIP skip number between wave fields
c> (defaults to (MAXWV+1)*((IROMB+1)*MAXWV+2) IF KWSKIP=0)
C> @param KGSKIP skip number between station point sets
c> (defaults to NMAX IF KGSKIP=0)
C> @param NRSKIP skip number between station lats and lons
c> (defaults to 1 if NRSKIP=0)
C> @param NGSKIP skip number between station points
c> (defaults to 1 if NGSKIP=0)
C> @param RLAT station latitudes in degrees
C> @param RLON station longitudes in degrees
C> @param WAVED wave divergence fields
C> @param WAVEZ wave vorticity fields
C> @param UP station point u-wind sets
C> @param VP station point v-wind sets
C>
C> @author IREDELL @date 96-02-29
      SUBROUTINE sptgptv(IROMB,MAXWV,KMAX,NMAX,
     &                   KWSKIP,KGSKIP,NRSKIP,NGSKIP,
     &                   RLAT,RLON,WAVED,WAVEZ,UP,VP)
 
      REAL RLAT(*),RLON(*),WAVED(*),WAVEZ(*),UP(*),VP(*)
      REAL EPS((MAXWV+1)*((IROMB+1)*MAXWV+2)/2),EPSTOP(MAXWV+1)
      REAL ENN1((MAXWV+1)*((IROMB+1)*MAXWV+2)/2)
      REAL ELONN1((MAXWV+1)*((IROMB+1)*MAXWV+2)/2)
      REAL EON((MAXWV+1)*((IROMB+1)*MAXWV+2)/2),EONTOP(MAXWV+1)
      INTEGER MP(2*KMAX)
      REAL W((MAXWV+1)*((IROMB+1)*MAXWV+2)/2*2+1,2*KMAX)
      REAL WTOP(2*(MAXWV+1),2*KMAX)
      REAL PLN((MAXWV+1)*((IROMB+1)*MAXWV+2)/2),PLNTOP(MAXWV+1)
      REAL F(2*MAXWV+3,2,2*KMAX)
      REAL G(2*KMAX)
      parameter(pi=3.14159265358979)
 
C  CALCULATE PRELIMINARY CONSTANTS
      CALL spwget(iromb,maxwv,eps,epstop,enn1,elonn1,eon,eontop)
      mx=(maxwv+1)*((iromb+1)*maxwv+2)/2
      mxtop=maxwv+1
      mdim=2*mx+1
      idim=2*maxwv+3
      kw=kwskip
      kg=kgskip
      nr=nrskip
      ng=ngskip
      IF(kw.EQ.0) kw=2*mx
      IF(kg.EQ.0) kg=nmax
      IF(nr.EQ.0) nr=1
      IF(ng.EQ.0) ng=1
      mp=1
 
C  CALCULATE SPECTRAL WINDS
C$OMP PARALLEL DO PRIVATE(KWS)
      DO k=1,kmax
        kws=(k-1)*kw
        CALL spdz2uv(iromb,maxwv,enn1,elonn1,eon,eontop,
     &               waved(kws+1),wavez(kws+1),
     &               w(1,k),w(1,kmax+k),wtop(1,k),wtop(1,kmax+k))
      ENDDO
 
C  CALCULATE STATION FIELDS
C$OMP PARALLEL DO PRIVATE(KU,KV,RADLAT,SLAT1,CLAT1)
C$OMP&            PRIVATE(PLN,PLNTOP,F,G,NK)
      DO n=1,nmax
        radlat=pi/180*rlat((n-1)*nr+1)
        IF(rlat((n-1)*nr+1).GE.89.9995) THEN
          slat1=1.
          clat1=0.
        ELSEIF(rlat((n-1)*nr+1).LE.-89.9995) THEN
          slat1=-1.
          clat1=0.
        ELSE
          slat1=sin(radlat)
          clat1=cos(radlat)
        ENDIF
        CALL splegend(iromb,maxwv,slat1,clat1,eps,epstop,
     &                pln,plntop)
        CALL spsynth(iromb,maxwv,2*maxwv,idim,mdim,2*mxtop,2*kmax,
     &               clat1,pln,plntop,mp,w,wtop,f)
        CALL spfftpt(maxwv,1,2*maxwv+3,1,2*kmax,rlon((n-1)*nr+1),f,g)
        DO k=1,kmax
          ku=k
          kv=k+kmax
          nk=(n-1)*ng+(k-1)*kg+1
          up(nk)=g(ku)
          vp(nk)=g(kv)
        ENDDO
      ENDDO
 
      END