spuv2dz.f

Go to the documentation of this file.

C> @file
C> @brief Compute divergence and vorticity from winds.
C> @author Iredell @date 92-10-31
 
C> Computes the divergence and vorticity from wind components
C> in spectral space.
C>
C> Subprogram speps() should be called already.
C>
C> If L is the zonal wavenumber, N is the total wavenumber,
C> EPS(L,N)=SQRT((N**2-L**2)/(4*N**2-1)) and A is earth radius,
C> then the divergence D is computed as:
C> <pre>
C> D(L,N)=I*L*A*U(L,N)
C> +EPS(L,N+1)*N*A*V(L,N+1)-EPS(L,N)*(N+1)*A*V(L,N-1)
C> </pre>
C>
C> and the vorticity Z is computed as:
C> <pre>
C> Z(L,N)=I*L*A*V(L,N)
C> -EPS(L,N+1)*N*A*U(L,N+1)+EPS(L,N)*(N+1)*A*U(L,N-1)
C> </pre>
C>
C> where U is the zonal wind and V is the meridional wind.
C>
C> U and V are weighted by the secant of latitude.
C>
C> Extra terms are used over top of the spectral domain.
C>
C> Advantage is taken of the fact that EPS(L,L)=0
C> in order to vectorize over the entire spectral domain.
C>
C> @param I integer spectral domain shape
C> (0 for triangular, 1 for rhomboidal)
C> @param M INTEGER spectral truncation
C> @param ENN1 ((M+1)*((I+1)*M+2)/2) N*(N+1)/A**2
C> @param ELONN1 ((M+1)*((I+1)*M+2)/2) L/(N*(N+1))*A
C> @param EON ((M+1)*((I+1)*M+2)/2) EPSILON/N*A
C> @param EONTOP (M+1) EPSILON/N*A over top
C> @param U ((M+1)*((I+1)*M+2)) zonal wind (over coslat)
C> @param V ((M+1)*((I+1)*M+2)) merid wind (over coslat)
C> @param UTOP (2*(M+1)) zonal wind (over coslat) over top
C> @param VTOP (2*(M+1)) merid wind (over coslat) over top
C> @param D ((M+1)*((I+1)*M+2)) divergence
C> @param Z ((M+1)*((I+1)*M+2)) vorticity
C>
C> @author Iredell @date 92-10-31
      SUBROUTINE spuv2dz(I,M,ENN1,ELONN1,EON,EONTOP,U,V,UTOP,VTOP,D,Z)
      REAL ENN1((M+1)*((I+1)*M+2)/2),ELONN1((M+1)*((I+1)*M+2)/2)
      REAL EON((M+1)*((I+1)*M+2)/2),EONTOP(M+1)
      REAL U((M+1)*((I+1)*M+2)),V((M+1)*((I+1)*M+2))
      REAL UTOP(2*(M+1)),VTOP(2*(M+1))
      REAL D((M+1)*((I+1)*M+2)),Z((M+1)*((I+1)*M+2))
 
C  COMPUTE TERMS FROM THE SPECTRAL DOMAIN
      k=1
      d(2*k-1)=0.
      d(2*k)=0.
      z(2*k-1)=0.
      z(2*k)=0.
      DO k=2,(m+1)*((i+1)*m+2)/2-1
        d(2*k-1)=-elonn1(k)*u(2*k)+eon(k+1)*v(2*k+1)-eon(k)*v(2*k-3)
        d(2*k)=elonn1(k)*u(2*k-1)+eon(k+1)*v(2*k+2)-eon(k)*v(2*k-2)
        z(2*k-1)=-elonn1(k)*v(2*k)-eon(k+1)*u(2*k+1)+eon(k)*u(2*k-3)
        z(2*k)=elonn1(k)*v(2*k-1)-eon(k+1)*u(2*k+2)+eon(k)*u(2*k-2)
      ENDDO
      k=(m+1)*((i+1)*m+2)/2
      d(2*k-1)=-elonn1(k)*u(2*k)-eon(k)*v(2*k-3)
      d(2*k)=elonn1(k)*u(2*k-1)-eon(k)*v(2*k-2)
      z(2*k-1)=-elonn1(k)*v(2*k)+eon(k)*u(2*k-3)
      z(2*k)=elonn1(k)*v(2*k-1)+eon(k)*u(2*k-2)
 
C  COMPUTE TERMS FROM OVER TOP OF THE SPECTRAL DOMAIN
CDIR$ IVDEP
      DO l=0,m
        k=l*(2*m+(i-1)*(l-1))/2+i*l+m+1
        d(2*k-1)=d(2*k-1)+eontop(l+1)*vtop(2*l+1)
        d(2*k)=d(2*k)+eontop(l+1)*vtop(2*l+2)
        z(2*k-1)=z(2*k-1)-eontop(l+1)*utop(2*l+1)
        z(2*k)=z(2*k)-eontop(l+1)*utop(2*l+2)
      ENDDO
 
C  MULTIPLY BY LAPLACIAN TERM
      DO k=2,(m+1)*((i+1)*m+2)/2
        d(2*k-1)=d(2*k-1)*enn1(k)
        d(2*k)=d(2*k)*enn1(k)
        z(2*k-1)=z(2*k-1)*enn1(k)
        z(2*k)=z(2*k)*enn1(k)
      ENDDO
      RETURN
      END