spfftpt.f

Go to the documentation of this file.

C> @file
C> @brief Compute fourier transform to gridpoints.
C> @author Iredell @date 96-02-20
 
C> This subprogram computes a slow Fourier transform
C> from Fourier space to a set of gridpoints.
C>
C> @note This subprogram is thread-safe.
C>
C> @param M Fourier wavenumber truncation
C> @param N number of gridpoints
C> @param INCW first dimension of the complex amplitude array
C> (INCW >= M+1)
C> @param INCG first dimension of the gridpoint array
C> (INCG >= N)
C> @param KMAX number of Fourier fields
C> @param RLON grid longitudes in degrees
C> @param W Fourier amplitudes
C> @param G gridpoint values
C>
C> @author Iredell @date 96-02-20
      SUBROUTINE spfftpt(M,N,INCW,INCG,KMAX,RLON,W,G)
 
        IMPLICIT NONE
        INTEGER,INTENT(IN):: M,N,INCW,INCG,KMAX
        REAL,INTENT(IN):: RLON(N)
        REAL,INTENT(IN):: W(2*INCW,KMAX)
        REAL,INTENT(OUT):: G(INCG,KMAX)
        INTEGER I,K,L
        REAL RADLON,SLON(M),CLON(M)
        REAL,PARAMETER:: PI=3.14159265358979
 
        DO i=1,n
          radlon=pi/180*rlon(i)
          DO l=1,m
            slon(l)=sin(l*radlon)
            clon(l)=cos(l*radlon)
          ENDDO
          DO k=1,kmax
            g(i,k)=w(1,k)
          ENDDO
          DO l=1,m
            DO k=1,kmax
              g(i,k)=g(i,k)+2.*(w(2*l+1,k)*clon(l)-w(2*l+2,k)*slon(l))
            ENDDO
          ENDDO
        ENDDO
      END SUBROUTINE