sptrunv.f

Go to the documentation of this file.

C> @file
C>
C> Spectrally truncate gridded vector fields
C> @author IREDELL @date 96-02-29
 
C> This subprogram spectrally truncates vector fields
C> on a global cylindrical grid, returning the fields
C> to a possibly different global cylindrical grid.
C> The wave-space can be either triangular or rhomboidal.
C> Either grid-space can be either an equally-spaced grid
C> (with or without pole points) or a Gaussian grid.
C> The grid fields may have general indexing.
C> The transforms are all multiprocessed.
C> Over zonal wavenumber to ensure reproducibility.
C> Transform several fields at a time to improve vectorization.
C> Subprogram can be called from a multiprocessing environment.
C>
C> PROGRAM HISTORY LOG:
C> -  96-02-29  IREDELL
C> - 1998-12-15  IREDELL  OPENMP DIRECTIVES INSERTED
C>
C> @param IROMB    - INTEGER SPECTRAL DOMAIN SHAPE
C>                (0 FOR TRIANGULAR, 1 FOR RHOMBOIDAL)
C> @param MAXWV    - INTEGER SPECTRAL TRUNCATION
C> @param IDRTI    - INTEGER INPUT GRID IDENTIFIER
C>                (IDRTI=4 FOR GAUSSIAN GRID,
C>                 IDRTI=0 FOR EQUALLY-SPACED GRID INCLUDING POLES,
C>                 IDRTI=256 FOR EQUALLY-SPACED GRID EXCLUDING POLES)
C> @param IMAXI    - INTEGER EVEN NUMBER OF INPUT LONGITUDES.
C> @param JMAXI    - INTEGER NUMBER OF INPUT LATITUDES.
C> @param IDRTO    - INTEGER OUTPUT GRID IDENTIFIER
C>                (IDRTO=4 FOR GAUSSIAN GRID,
C>                 IDRTO=0 FOR EQUALLY-SPACED GRID INCLUDING POLES,
C>                 IDRTO=256 FOR EQUALLY-SPACED GRID EXCLUDING POLES)
C> @param IMAXO    - INTEGER EVEN NUMBER OF OUTPUT LONGITUDES.
C> @param JMAXO    - INTEGER NUMBER OF OUTPUT LATITUDES.
C> @param KMAX     - INTEGER NUMBER OF FIELDS TO TRANSFORM.
C> @param IPRIME   - INTEGER INPUT LONGITUDE INDEX FOR THE PRIME MERIDIAN.
C>                (DEFAULTS TO 1 IF IPRIME=0)
C>                (OUTPUT LONGITUDE INDEX FOR PRIME MERIDIAN ASSUMED 1.)
C> @param ISKIPI   - INTEGER SKIP NUMBER BETWEEN INPUT LONGITUDES
C>                (DEFAULTS TO 1 IF ISKIPI=0)
C> @param JSKIPI   - INTEGER SKIP NUMBER BETWEEN INPUT LATITUDES FROM SOUTH
C>                (DEFAULTS TO -IMAXI IF JSKIPI=0)
C> @param KSKIPI   - INTEGER SKIP NUMBER BETWEEN INPUT GRID FIELDS
C>                (DEFAULTS TO IMAXI*JMAXI IF KSKIPI=0)
C> @param ISKIPO   - INTEGER SKIP NUMBER BETWEEN OUTPUT LONGITUDES
C>                (DEFAULTS TO 1 IF ISKIPO=0)
C> @param JSKIPO   - INTEGER SKIP NUMBER BETWEEN OUTPUT LATITUDES FROM SOUTH
C>                (DEFAULTS TO -IMAXO IF JSKIPO=0)
C> @param KSKIPO   - INTEGER SKIP NUMBER BETWEEN OUTPUT GRID FIELDS
C>                (DEFAULTS TO IMAXO*JMAXO IF KSKIPO=0)
C> @param JCPU     - INTEGER NUMBER OF CPUS OVER WHICH TO MULTIPROCESS
C>                (DEFAULTS TO ENVIRONMENT NCPUS IF JCPU=0)
C> @param GRIDUI   - REAL (*) INPUT GRID U-WINDS
C> @param GRIDVI   - REAL (*) INPUT GRID V-WINDS
C> @param LUV      - LOGICAL FLAG WHETHER TO RETURN WINDS
C> @param LDZ      - LOGICAL FLAG WHETHER TO RETURN DIVERGENCE AND VORTICITY
C> @param LPS      - LOGICAL FLAG WHETHER TO RETURN POTENTIAL AND STREAMFCN
C> @param GRIDUO   - REAL (*) OUTPUT U-WINDS IF LUV
C>                (MAY OVERLAY INPUT FIELDS IF GRID SHAPE IS APPROPRIATE)
C> @param GRIDVO   - REAL (*) OUTPUT V-WINDS IF LUV
C>                (MAY OVERLAY INPUT FIELDS IF GRID SHAPE IS APPROPRIATE)
C> @param GRIDDO   - REAL (*) OUTPUT DIVERGENCES IF LDZ
C>                (MAY OVERLAY INPUT FIELDS IF GRID SHAPE IS APPROPRIATE)
C> @param GRIDZO   - REAL (*) OUTPUT VORTICITIES IF LDZ
C>                (MAY OVERLAY INPUT FIELDS IF GRID SHAPE IS APPROPRIATE)
C> @param GRIDPO   - REAL (*) OUTPUT POTENTIALS IF LPS
C>                (MAY OVERLAY INPUT FIELDS IF GRID SHAPE IS APPROPRIATE)
C> @param GRIDSO   - REAL (*) OUTPUT STREAMFCNS IF LPS
C>                (MAY OVERLAY INPUT FIELDS IF GRID SHAPE IS APPROPRIATE)
C>
C> SUBPROGRAMS CALLED:
C>   - SPWGET()       GET WAVE-SPACE CONSTANTS
C>   - SPLAPLAC()     COMPUTE LAPLACIAN IN SPECTRAL SPACE
C>   - SPTRAN()       PERFORM A SCALAR SPHERICAL TRANSFORM
C>   - SPTRANV()      PERFORM A VECTOR SPHERICAL TRANSFORM
C>   - NCPUS()        GETS ENVIRONMENT NUMBER OF CPUS
C>
C> REMARKS: MINIMUM GRID DIMENSIONS FOR UNALIASED TRANSFORMS TO SPECTRAL:
C>   DIMENSION                    |LINEAR             |QUADRATIC
C>   -----------------------      |---------           |-------------
C>   IMAX                         |2*MAXWV+2           |3*MAXWV/2*2+2
C>   JMAX (IDRT=4,IROMB=0)        |1*MAXWV+1           |3*MAXWV/2+1
C>   JMAX (IDRT=4,IROMB=1)        |2*MAXWV+1           |5*MAXWV/2+1
C>   JMAX (IDRT=0,IROMB=0)        |2*MAXWV+3           |3*MAXWV/2*2+3
C>   JMAX (IDRT=0,IROMB=1)        |4*MAXWV+3           |5*MAXWV/2*2+3
C>   JMAX (IDRT=256,IROMB=0)      |2*MAXWV+1           |3*MAXWV/2*2+1
C>   JMAX (IDRT=256,IROMB=1)      |4*MAXWV+1           |5*MAXWV/2*2+1
      SUBROUTINE sptrunv(IROMB,MAXWV,IDRTI,IMAXI,JMAXI,
     &                   IDRTO,IMAXO,JMAXO,KMAX,
     &                   IPRIME,ISKIPI,JSKIPI,KSKIPI,
     &                   ISKIPO,JSKIPO,KSKIPO,JCPU,GRIDUI,GRIDVI,
     &                   LUV,GRIDUO,GRIDVO,LDZ,GRIDDO,GRIDZO,
     &                   LPS,GRIDPO,GRIDSO)
      LOGICAL LUV,LDZ,LPS
      REAL GRIDUI(*),GRIDVI(*)
      REAL GRIDUO(*),GRIDVO(*),GRIDDO(*),GRIDZO(*),GRIDPO(*),GRIDSO(*)
      REAL EPS((MAXWV+1)*((IROMB+1)*MAXWV+2)/2),EPSTOP(MAXWV+1)
      REAL ENN1((MAXWV+1)*((IROMB+1)*MAXWV+2)/2)
      REAL ELONN1((MAXWV+1)*((IROMB+1)*MAXWV+2)/2)
      REAL EON((MAXWV+1)*((IROMB+1)*MAXWV+2)/2),EONTOP(MAXWV+1)
      REAL WD((MAXWV+1)*((IROMB+1)*MAXWV+2)/2*2+1,KMAX)
      REAL WZ((MAXWV+1)*((IROMB+1)*MAXWV+2)/2*2+1,KMAX)
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
C  TRANSFORM INPUT GRID TO WAVE
      jc=jcpu
      IF(jc.EQ.0) jc=ncpus()
      mx=(maxwv+1)*((iromb+1)*maxwv+2)/2
      mdim=2*mx+1
      jn=-jskipi
      IF(jn.EQ.0) jn=imaxi
      js=-jn
      inp=(jmaxi-1)*max(0,-jn)+1
      isp=(jmaxi-1)*max(0,-js)+1
      CALL sptranv(iromb,maxwv,idrti,imaxi,jmaxi,kmax,
     &             iprime,iskipi,jn,js,mdim,kskipi,0,0,jc,
     &             wd,wz,
     &             gridui(inp),gridui(isp),gridvi(inp),gridvi(isp),-1)
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
C  TRANSFORM WAVE TO OUTPUT WINDS
      jn=-jskipo
      IF(jn.EQ.0) jn=imaxo
      js=-jn
      inp=(jmaxo-1)*max(0,-jn)+1
      isp=(jmaxo-1)*max(0,-js)+1
      IF(luv) THEN
        CALL sptranv(iromb,maxwv,idrto,imaxo,jmaxo,kmax,
     &               0,iskipo,jn,js,mdim,kskipo,0,0,jc,
     &               wd,wz,
     &               griduo(inp),griduo(isp),gridvo(inp),gridvo(isp),1)
      ENDIF
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
C  TRANSFORM WAVE TO OUTPUT DIVERGENCE AND VORTICITY
      IF(ldz) THEN
        CALL sptran(iromb,maxwv,idrto,imaxo,jmaxo,kmax,
     &              0,iskipo,jn,js,mdim,kskipo,0,0,jc,
     &              wd,griddo(inp),griddo(isp),1)
        CALL sptran(iromb,maxwv,idrto,imaxo,jmaxo,kmax,
     &              0,iskipo,jn,js,mdim,kskipo,0,0,jc,
     &              wz,gridzo(inp),gridzo(isp),1)
      ENDIF
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
C  TRANSFORM WAVE TO OUTPUT POTENTIAL AND STREAMFUNCTION
      IF(lps) THEN
        CALL spwget(iromb,maxwv,eps,epstop,enn1,elonn1,eon,eontop)
C$OMP PARALLEL DO
        DO k=1,kmax
          CALL splaplac(iromb,maxwv,enn1,wd(1,k),wd(1,k),-1)
          CALL splaplac(iromb,maxwv,enn1,wz(1,k),wz(1,k),-1)
          wd(1:2,k)=0.
          wz(1:2,k)=0.
        ENDDO
        CALL sptran(iromb,maxwv,idrto,imaxo,jmaxo,kmax,
     &              0,iskipo,jn,js,mdim,kskipo,0,0,jc,
     &              wd,gridpo(inp),gridpo(isp),1)
        CALL sptran(iromb,maxwv,idrto,imaxo,jmaxo,kmax,
     &              0,iskipo,jn,js,mdim,kskipo,0,0,jc,
     &              wz,gridso(inp),gridso(isp),1)
      ENDIF
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      END