gbytes.f

Go to the documentation of this file.

C> @file
C> @brief This is the fortran version of gbytes.
C> @author Dr. Robert C. Gammill @date 1972-05
 
C> Program history log:
C> - Russell E. Jones 1991-03
C> Changes for SiliconGraphics IRIS-4D/25
C> SiliconGraphics 3.3 FORTRAN 77
C>
C> To unpack a series of bytes into a target
C> array. Each unpacked byte is right-justified
C> in its target word, and the remainder of the
C> word is zero-filled.
C>
C> @param[in] IPACKD The word or array containing the packed bytes.
C> @param[out] IUNPKD The array which will contain the unpacked bytes.
C> @param[in] NOFF The initial number of bits to skip, left to right,
C> in 'IPACKD' in order to locate the first byte to unpack.
C> @param[in] NBITS Number of bits in the byte to be unpacked.
C> Maximum of 64 bits on 64 bit machine, 32 bits on 32 bit machine.
C> @param[in] ISKIP The number of bits to skip between each byte in
C> 'IPACKD' in order to locate the next byte to be unpacked.
C> @param[in] ITER The number of bytes to be unpacked.
C>
      SUBROUTINE gbytes(IPACKD,IUNPKD,NOFF,NBITS,ISKIP,ITER)
 
      INTEGER    IPACKD(*)
 
      INTEGER    IUNPKD(*)
      INTEGER    MASKS(64)
C
      SAVE
C
      DATA ifirst/1/
      IF(ifirst.EQ.1) THEN
         CALL w3fi01(lw)
         nbitsw = 8 * lw
         jshift = -1 * nint(alog(float(nbitsw)) / alog(2.0))
         masks(1) = 1
         DO i=2,nbitsw-1
            masks(i) = 2 * masks(i-1) + 1
         ENDDO
         masks(nbitsw) = -1
         ifirst = 0
      ENDIF
C
C NBITS MUST BE LESS THAN OR EQUAL TO NBITSW
C
      icon   = nbitsw - nbits
      IF (icon.LT.0) RETURN
      mask   = masks(nbits)
C
C INDEX TELLS HOW MANY WORDS INTO THE ARRAY 'IPACKD' THE NEXT BYTE
C APPEARS.
C
      index  = ishft(noff,jshift)
C
C II TELLS HOW MANY BITS THE BYTE IS FROM THE LEFT SIDE OF THE WORD.
C
      ii     = mod(noff,nbitsw)
C
C ISTEP IS THE DISTANCE IN BITS FROM THE START OF ONE BYTE TO THE NEXT.
C
      istep  = nbits + iskip
C
C IWORDS TELLS HOW MANY WORDS TO SKIP FROM ONE BYTE TO THE NEXT.
C
      iwords = istep / nbitsw
C
C IBITS TELLS HOW MANY BITS TO SKIP AFTER SKIPPING IWORDS.
C
      ibits  = mod(istep,nbitsw)
C
      DO 10 i = 1,iter
C
C MOVER SPECIFIES HOW FAR TO THE RIGHT A BYTE MUST BE MOVED IN ORDER
C
C    TO BE RIGHT ADJUSTED.
C
      mover = icon - ii
C
C THE BYTE IS SPLIT ACROSS A WORD BREAK.
C
      IF (mover.LT.0) THEN
        movel   = - mover
        mover   = nbitsw - movel
        iunpkd(i) = iand(ior(ishft(ipackd(index+1),movel),
     &            ishft(ipackd(index+2),-mover)),mask)
C
C RIGHT ADJUST THE BYTE.
C
      ELSE IF (mover.GT.0) THEN
        iunpkd(i) = iand(ishft(ipackd(index+1),-mover),mask)
C
C THE BYTE IS ALREADY RIGHT ADJUSTED.
C
      ELSE
        iunpkd(i) = iand(ipackd(index+1),mask)
      ENDIF
C
C INCREMENT II AND INDEX.
C
        ii    = ii + ibits
        index = index + iwords
        IF (ii.GE.nbitsw) THEN
          ii    = ii - nbitsw
          index = index + 1
        ENDIF
C
   10 CONTINUE
        RETURN
      END