gtbits.f

Go to the documentation of this file.

C> @file
C> @brief The number of bits required to pack a given field.
C> @author Mark Iredell @date 1992-10-31
 
C> The number of bits required to pack a given field
c> at a particular decimal scaling is computed using the field range.
C> The field is rounded off to the decimal scaling for packing.
C> The minimum and maximum rounded field values are also returned.
C> Grib bitmap masking for valid data is optionally used.
C>
C> Program history log:
C> - Mark Iredell 1992-10-31
C>
C> @param[in] ibm integer bitmap flag (=0 for no bitmap).
c> @param[in] ids integer decimal scaling
c> (e.g. ids=3 to round field to nearest milli-value).
c> @param[in] len integer length of the field and bitmap.
c> @param[in] mg integer (len) bitmap if ibm=1 (0 to skip, 1 to keep).
c> @param[in] g real (len) field.
c> @param[out] ground real (len) field rounded to decimal scaling
c> (set to zero where bitmap is 0 if ibm=1).
c> @param[out] gmin real minimum valid rounded field value.
c> @param[out] gmax real maximum valid rounded field value.
c> @param[out] nbit integer number of bits to pack.
C>
C> @author Mark Iredell @date 1992-10-31
      SUBROUTINE gtbits(IBM,IDS,LEN,MG,G,GROUND,GMIN,GMAX,NBIT)
      dimension mg(len),g(len),ground(len)
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
C  ROUND FIELD AND DETERMINE EXTREMES WHERE BITMAP IS ON
      ds=10.**ids
      IF(ibm.EQ.0) THEN
        ground(1)=nint(g(1)*ds)/ds
        gmax=ground(1)
        gmin=ground(1)
        DO i=2,len
          ground(i)=nint(g(i)*ds)/ds
          gmax=max(gmax,ground(i))
          gmin=min(gmin,ground(i))
        ENDDO
      ELSE
        i1=isrchne(len,mg,1,0)
        IF(i1.GT.0.AND.i1.LE.len) THEN
          DO i=1,i1-1
            ground(i)=0.
          ENDDO
          ground(i1)=nint(g(i1)*ds)/ds
          gmax=ground(i1)
          gmin=ground(i1)
          DO i=i1+1,len
            IF(mg(i).NE.0) THEN
              ground(i)=nint(g(i)*ds)/ds
              gmax=max(gmax,ground(i))
              gmin=min(gmin,ground(i))
            ELSE
              ground(i)=0.
            ENDIF
          ENDDO
        ELSE
          DO i=1,len
            ground(i)=0.
          ENDDO
          gmax=0.
          gmin=0.
        ENDIF
      ENDIF
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
C  COMPUTE NUMBER OF BITS
      nbit=log((gmax-gmin)*ds+0.9)/log(2.)+1.
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      RETURN
      END