skgb.f

Go to the documentation of this file.

C> @file
C> @brief Search for next grib message.
C> @author Mark Iredell @date 1993-11-22
 
C> This subprogram searches a file for the next grib 1 message.
C> A grib 1 message is identified by its indicator section, i.e.
C> an 8-byte sequence with 'grib' in bytes 1-4 and 1 in byte 8.
C> If found, the length of the message is decoded from bytes 5-7.
C> The search is done over a given section of the file.
C> The search is terminated if an eof or i/o error is encountered.
C>
C> Program history log:
C> - Mark Iredell 1993-11-22
C> - Mark Iredell 1995-10-31 Add call to baread.
C> - Mark Iredell 1997-03-14 Check for '7777'.
C> - Stephen Gilbert 2001-12-05 Modified to also look for grib2 messages.
C>
C> @param[in] LUGB Integer logical unit of input grib file.
C> @param[in] ISEEK Integer number of bytes to skip before search.
C> @param[in] MSEEK Integer maximum number of bytes to search.
C> @param[out] LSKIP Integer number of bytes to skip before message.
C> @param[out] LGRIB Integer number of bytes in message (0 if not found).
C>
C> @author Mark Iredell @date 1993-11-22
C-----------------------------------------------------------------------
      SUBROUTINE skgb(LUGB,ISEEK,MSEEK,LSKIP,LGRIB)
      parameter(lseek=128)
      CHARACTER Z(LSEEK)
      CHARACTER Z4(4)
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      lgrib=0
      ks=iseek
      kn=min(lseek,mseek)
      kz=lseek
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
C  LOOP UNTIL GRIB MESSAGE IS FOUND
      dowhile(lgrib.EQ.0.AND.kn.GE.8.AND.kz.EQ.lseek)
C  READ PARTIAL SECTION
        CALL baread(lugb,ks,kn,kz,z)
        km=kz-8+1
        k=0
C  LOOK FOR 'GRIB...1' IN PARTIAL SECTION
        dowhile(lgrib.EQ.0.AND.k.LT.km)
          CALL gbytec(z,i4,(k+0)*8,4*8)
          CALL gbytec(z,i1,(k+7)*8,1*8)
          IF(i4.EQ.1196575042.AND.(i1.EQ.1.OR.i1.EQ.2)) THEN
C  LOOK FOR '7777' AT END OF GRIB MESSAGE
            IF (i1.EQ.1) CALL gbytec(z,kg,(k+4)*8,3*8)
            IF (i1.EQ.2) CALL gbytec(z,kg,(k+12)*8,4*8)
            CALL baread(lugb,ks+k+kg-4,4,k4,z4)
            IF(k4.EQ.4) THEN
              CALL gbytec(z4,i4,0,4*8)
              IF(i4.EQ.926365495) THEN
C  GRIB MESSAGE FOUND
                lskip=ks+k
                lgrib=kg
              ENDIF
            ENDIF
          ENDIF
          k=k+1
        ENDDO
        ks=ks+km
        kn=min(lseek,iseek+mseek-ks)
      ENDDO
C - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      RETURN
      END