w3fa09.f

Go to the documentation of this file.

C> @file
C> @brief Temperature to saturation vapor pressure.
C> @author P. Chase @date 1978-10-01
 
C> Computes saturation vapor pressure in kilopascals given temperataure in kelvins.
C>
C> Program history log:
C> - P. Chase 1978-10-01  P.CHASE
C> - Ralph Jones 1984-06-26 Change to ibm vs fortran.
C> - Ralph Jones 1984-06-26 Change to microsoft fortran 4.10.
C> - Ralph Jones 1990-06-08 Change to sun fortran 1.3.
C> - Ralph Jones 1991-03-29 Convert to silicongraphic fortran.
C> - Ralph Jones 1993-03-29 Add save statement.
C> - Ralph Jones 1995-09-25 Change tk to cray 64 bit real, change double.
C> precision to cray 64 bit real.
C>
C> @param[in] TK REAL*8 Temperature in kelvins. if tk < 223.16, the value
C> 223.16 will be used.  if tk > 323.16, the value 323.16
C> will be used as the argument. 'tk' itself is unchanged.
C> @return VP Saturation vapor pressure in kilopascals 0.0063558 < VP < 12.3395.
C>
C> @note W3FA09 may be declared real*8 so that a real*8 value is
C> returned, but no increase in accuracy is implied.
C>
C> @author P. Chase @date 1978-10-01
      REAL function w3fa09 (tk)
C
C THE CHEBYSHEV COEFFICIENTS ARE IN ARRAY C, LOW-ORDER TERM FIRST.
C
      REAL   c(9)
      REAL   arg,h0,h1,h2
C
      SAVE
C
      DATA  c     /
     & 0.313732865927e+01, 0.510038215244e+01, 0.277816535655e+01,
     & 0.102673379933e+01, 0.254577145215e+00, 0.396055201295e-01,
     & 0.292209288468e-02,-0.119497199712e-03,-0.352745603496e-04/
C
C SCALE TK TO RANGE -2, +2 FOR SERIES EVALUATION.  INITIALIZE TERMS.
C
      arg = -1.09264e1+4.0e-2*amax1(223.16,amin1(323.16,tk))
      h0  = 0.0
      h1  = 0.0
C
C EVALUATE CHEBYSHEV POLYNOMIAL
C
      DO 10 i=1,9
        h2 = h1
        h1 = h0
        h0 = arg * h1 - h2 + c(10-i)
 10   CONTINUE
      w3fa09 = 0.5 * (c(1) - h2 + h0)
      RETURN
      END