w3fa13.f

Go to the documentation of this file.

C> @file
C> @brief Computes Trig Functions
C> @author Joe Sela @date 1980-11-21
 
C> Computes trig functions used in 2.5 by 2.5 lat,lon
C> mapping routines. w3fa13() must be called at least once before
C> calls to w3ft08(), w3ft09(), w3ft10(), w3ft11().
C>
C> Program history log:
C> - Joe Sela 1980-11-21
C> - Ralph Jones 1984-06-01 Change to vs fortran
C>
C> @param[out] TRIGS 216 trig values, used by subroutine w3fa12().
C> @param[out] RCOS 37 colatitudes used by subroutines w3ft09() ,w3ft11()
C>
C> @author Joe Sela @date 1980-11-21
      SUBROUTINE w3fa13(TRIGS,RCOS)
C
       REAL            RCOS(*)
       REAL            TRIGS(*)
C
       SAVE
C
       DATA  pi    /3.14159265358979323846/
C
         n = 144
         mode = 3
         drad = 2.5*pi/180.
C
         DO 100 lat = 2,37
           arg = (lat-1)*drad
           rcos(lat) = 1./sin(arg)
 100     CONTINUE
C
         rcos(1) = 77777.777
         imode = iabs(mode)
         nn = n
         IF (imode.GT.1.AND.imode.LT.6) nn = n/2
         angle = 0.0
         del = (pi+pi)/float(nn)
         l = nn+nn
C
         DO 200 i = 1,l,2
           trigs(i) = cos(angle)
           trigs(i+1) = sin(angle)
           angle = angle+del
 200     CONTINUE
C
         IF (imode.EQ.1) RETURN
         IF (imode.EQ.8) RETURN
         angle = 0.0
         del = 0.5*del
         nh = (nn+1)/2
         l = nh+nh
         la = nn+nn
C
         DO 300 i = 1,l,2
           trigs(la+i) = cos(angle)
           trigs(la+i+1) = sin(angle)
           angle = angle+del
 300     CONTINUE
C
         IF (imode.LE.3) RETURN
         del = 0.5*del
         angle = del
         la = la+nn
C
         DO 400 i = 2,nn
           trigs(la+i) = 2.0*sin(angle)
           angle = angle+del
 400     CONTINUE
C
         RETURN
       END