w3fi04.f

Go to the documentation of this file.

C> @file
C> @brief Find word size, endian, character set.
C> @author Ralph Jones @date 1994-10-07
 
C> Subroutine computes word size, the type of character
C> set, ASCII or EBCDIC, and if the computer is big-endian, or
C> little-endian.
C>
C> Program history log:
C> - Relph Jones 1994-10-07
C> - Stephen Gilbert 1998-07-08 Removed the Fortran SAVE Statement.
C> The SAVE statement is not needed for this outine, and may have been
C> causing errors using the f90 compiler under the 2.0 Programming Environment.
C> - Boi Vuong 2002-10-15 Replaced Function ICHAR with mova2i
C>
C> @param[out] IENDN Integer for big-endian or little-endian
C> - =0 big-endian
C> - =1 little-endian
C> - =2 cannot compute
C> @param[out] ITYPEC Integer for type of character set
C> - =0 ASCII character set
C> - =1 EBCDIC character set
C> - =2 not ASCII or EBCDIC
C> @param[out] LW Integer for words size of computer in bytes
C> - =4 for 32 bit computers
C> - =8 for 64 bit computers
C>
C> @author Ralph Jones @date 1994-10-07
      SUBROUTINE w3fi04(IENDN,ITYPEC,LW)
C
      INTEGER       ITEST1
      INTEGER       ITEST2
      INTEGER       ITEST3
      INTEGER       IENDN
      INTEGER       ITYPEC
      INTEGER       LW
C
      CHARACTER * 8 CTEST1
      CHARACTER * 8 CTEST2
      CHARACTER * 1 CTEST3(8)
      CHARACTER * 1 BLANK
C
      equivalence(ctest1,itest1),(ctest2,itest2)
C
      equivalence(itest3,ctest3(1))
C
      DATA  ctest1/'12345678'/
      DATA  itest3/z'01020304'/
      DATA  blank /' '/
C
C     SAVE
C
C     TEST FOR TYPE OF CHARACTER SET
C     BLANK IS 32 (20 HEX) IN ASCII, 64 (40 HEX) IN EBCDEC
C
      IF (mova2i(blank).EQ.32) THEN
        itypec = 0
      ELSE IF (mova2i(blank).EQ.64) THEN
C
C     COMPUTER IS PROBABLY AN IBM360, 370, OR 390 WITH
C     A 32 BIT WORD SIZE, AND BIG-ENDIAN.
C
        itypec = 1
      ELSE
        itypec = 2
      END IF
C
C     TEST FOR WORD SIZE, SET LW TO 4 FOR 32 BIT COMPUTER,
C     8 FOR FOR 64 BIT COMPUTERS
C
      itest2 = itest1
      IF (ctest1 .EQ. ctest2) THEN
C
C     COMPUTER MAY BE A CRAY, OR COULD BE DEC VAX ALPHA
C     OR SGI WITH R4000, R4400, R8800 AFTER THEY CHANGE
C     FORTRAN COMPILERS FOR 64 BIT INTEGER.
C
        lw = 8
      ELSE
        lw = 4
      ENDIF
C
C     USING ITEST3 WITH Z'01020304' EQUIVALNCED TO CTEST3
C     ON A 32 BIT BIG-ENDIAN COMPUTER 03 IS IN THE 3RD
C     BYTE OF A 4 BYTE WORD. ON A 32 BIT LITTLE-ENDIAN
C     COMPUTER IT IS IN 2ND BYTE.
C     ON A 64 BIT COMPUTER Z'01020304' IS RIGHT ADJUSTED IN
C     A 64 BIT WORD, 03 IS IN THE 7TH BYTE.  ON A LITTLE-
C     ENDIAN 64 BIT COMPUTER IT IS IN THE 2ND BYTE.
C
      IF (lw.EQ.4) THEN
        IF (mova2i(ctest3(3)).EQ.3) THEN
          iendn = 0
        ELSE IF (mova2i(ctest3(3)).EQ.2) THEN
          iendn = 1
        ELSE
          iendn = 2
        END IF
      ELSE IF (lw.EQ.8) THEN
        IF (mova2i(ctest3(7)).EQ.3) THEN
          iendn = 0
        ELSE IF (mova2i(ctest3(2)).EQ.3) THEN
          iendn = 1
        ELSE
          iendn = 2
        END IF
      ELSE
        iendn = 2
      END IF
C
      RETURN
      END