w3fi82.f

Go to the documentation of this file.

C> @file
C> @brief Convert to second diff array
C> @author Bill Cavanaugh @date 1993-07-14
 
C> Accept an input array, convert to array of second
C> differences.  return the original first value and the first
C> first-difference as separate values. align data in
C> boustrephedonic style, (alternate row reversal).
C>
C> Program history log:
C> - Bill Cavanaugh 1993-07-14
C> - Bill Cavanaugh 1994-01-27 Added reversal of even numbered rows
C> (boustrophedonic processing)
C> - Bill Cavanaugh 1994-03-02 Corrected improper ordering of even
C> numbered rows
C> - Ebisuzaki 1999-12-06 Linux port
C>
C> @param[inout] IFLD
C> - [in] Integer input array
C> - [out] Second differenced field
C> @param[in] NPTS Number of points in array
C> @param[in] IGDS
C> - (5) Number of rows in array
C> - (4) Number of columns in array
C> @param[in] PDS (8) Flag indicating presence of gds section
C> @param[out] FVAL1 Floating point original first value
C> @param[out] FDIFF1 Floating point first first-difference
C>
C> @author Bill Cavanaugh @date 1993-07-14
      SUBROUTINE w3fi82 (IFLD,FVAL1,FDIFF1,NPTS,PDS,IGDS)
C
      REAL        FVAL1,FDIFF1
C
      INTEGER     IFLD(*),NPTS,NBOUST(300),IGDS(*)
C
      CHARACTER*1 PDS(*)
C
C  ---------------------------------------------
C                  TEST FOR PRESENCE OF GDS
C
c looks like an error      CALL GBYTE(PDS,IQQ,56,8)
      call gbytec(pds,iqq,56,1)
      IF (iqq.NE.0) THEN
          nrow  = igds(5)
          ncol  = igds(4)
C
C      LAY OUT DATA BOUSTROPHEDONIC STYLE
C
C         PRINT*, '  DATA SET UP BOUSTROPHEDON'
C
          DO 210 i = 2, nrow, 2
C
C          REVERSE THE EVEN NUMBERED ROWS
C
              DO 200 j = 1, ncol
                  npos  = i * ncol - j + 1
                  nboust(j) = ifld(npos)
  200         CONTINUE
              DO 201 j = 1, ncol
                  npos  = ncol * (i-1) + j
                  ifld(npos)  = nboust(j)
  201         CONTINUE
  210     CONTINUE
C
C
      END IF
C  =================================================================
          DO 4000 i = npts, 2, -1
              ifld(i)  = ifld(i) - ifld(i-1)
 4000     CONTINUE
          DO 5000 i = npts, 3, -1
              ifld(i)  = ifld(i) - ifld(i-1)
 5000     CONTINUE
C
C                      SPECIAL FOR GRIB
C                         FLOAT OUTPUT OF FIRST POINTS TO ANTICIPATE
C                         GRIB FLOATING POINT OUTPUT
C
          fval1    = ifld(1)
          fdiff1   = ifld(2)
C
C       SET FIRST TWO POINTS TO SECOND DIFF VALUE FOR BETTER PACKING
C
          ifld(1)  = ifld(3)
          ifld(2)  = ifld(3)
C  -----------------------------------------------------------
      RETURN
      END