w3fi83.f

Go to the documentation of this file.

C> @file
C> @brief Restore delta packed data to original.
C> @author Bill Cavanaugh @date 1993-08-18
 
C> Restore delta packed data to original values
C> restore from boustrephedonic alignment.
C>
C> Program history log:
C> - Bill Cavanaugh 1993-07-14
C> - John Satckpole 1993-07-22 Additions to fix scaling.
C> - Bill Cavanaugh 1994-01-27 Added reversal of even numbered rows
C> (boustrophedonic processing) to restore
C> data to original sequence.
C> - Bill Cavanaugh 1994-03-02 Corrected reversal of even numbered rows.
C> - Mark Iredell 1995-10-31 Removed saves and prints.
C>
C> @param[inout] DATA
C> - [in] Second order differences.
C> - [out] Expanded original data values.
C> @param[in] NPTS Number of points in array.
C> @param[in] FVAL1 Original first entry in array.
C> @param[in] FDIFF1 Original first first-difference.
C> @param[in] ISCAL2 Power-of-two exponent for unscaling.
C> @param[in] ISC10 Power-of-ten exponent for unscaling.
C> @param[in] KPDS Array of information for pds.
C> @param[in] KGDS Array of information for gds.
C>
C> @note Subprogram can be called from a multiprocessing environment.
C>
C> @author Bill Cavanaugh @date 1993-08-18
      SUBROUTINE w3fi83 (DATA,NPTS,FVAL1,FDIFF1,ISCAL2,
     *                                ISC10,KPDS,KGDS)
C
      REAL          FVAL1,FDIFF1
      REAL          DATA(*),BOUST(200)
      INTEGER       NPTS,NROW,NCOL,KPDS(*),KGDS(*),ISC10
C  ---------------------------------------
C
C     REMOVE DECIMAL UN-SCALING INTRODUCED DURING UNPACKING
C
      dscal = 10.0 ** isc10
      IF (dscal.EQ.0.0) THEN
          DO 50 i=1,npts
              DATA(i) = 1.0
   50     CONTINUE
      ELSE IF (dscal.EQ.1.0) THEN
      ELSE
          DO 51 i=1,npts
              DATA(i) = DATA(i) * dscal
   51     CONTINUE
      END IF
C
      DATA(1)  = fval1
      DATA(2)  = fdiff1
      DO 200 j = 3,2,-1
          DO 100 k = j, npts
              DATA(k)  = DATA(k) + DATA(k-1)
  100     CONTINUE
  200 CONTINUE
C
C     NOW REMOVE THE BINARY SCALING FROM THE RECONSTRUCTED FIELD
C     AND THE DECIMAL SCALING TOO
C
      IF (dscal.EQ.0) THEN
          scale  = 0.0
      ELSE
          scale =(2.0**iscal2)/dscal
      END IF
      DO 300 i=1,npts
        DATA(i) = DATA(i) * scale
  300 CONTINUE
C  ==========================================================
      IF (iand(kpds(4),128).NE.0) THEN
          nrow  = kgds(3)
          ncol  = kgds(2)
C
C      DATA LAID OUT BOUSTROPHEDONIC STYLE
C
C
C         PRINT*, '  REVERSE BOUSTROPHEDON'
          DO 210 i = 2, nrow, 2
C
C          REVERSE THE EVEN NUMBERED ROWS
C
              DO 201 j = 1, ncol
                  npos  = i * ncol - j + 1
                  boust(j) = DATA(npos)
  201         CONTINUE
              DO 202 j = 1, ncol
                  npos  = ncol * (i-1) + j
                  DATA(npos)  = boust(j)
  202         CONTINUE
  210     CONTINUE
C
C
      END IF
C  =================================================================
      RETURN
      END