w3fm08.f

Go to the documentation of this file.

C> @file
C> @brief Nine point smoother/desmoother.
C> @author J. Howcroft @date 1971-02-01
 
C> Nine point smoother/desmoother. Smoother pass uses an
C> equivalent linear smoother with stencil (.25 .5 .25) and the
C> desmoother uses stencil (-.25 1.5 -.25). Two grid interval waves
C> are annihilated, four grid interval waves have a .75 response.
C>
C> Program history log:
C> - J. Howcroft 1971-02-01
C> - Ralph Jones 1984-07-01 Change to ibm vs fortran.
C> - Ralph Jones 1994-07-27 Change to cray cft77 fortran.
C>
C> @param[inout] A
C> - [in] Real size (li,lj) array to hold field to be smoothed.
C> - [out] Array holding smoothed field.
C> @param[in] Z - Real size (li,lj) work area.
C> @param[in] LI - Integer number of columns.
C> @param[in] LJ - Integer number of rows.
C>
C> @author J. Howcroft @date 1971-02-01
      SUBROUTINE w3fm08 (A,Z,LI,LJ)
C
      REAL     A(LI,LJ)
      REAL     Z(LI,LJ)
C
      SAVE
C
      li1 = li - 1
      lj1 = lj - 1
      DO 1  j=2,lj1
      DO 1  i=2,li1
      crux = a(i-1,j-1) + a(i+1,j-1) + a(i+1,j+1) + a(i-1,j+1)
      plus = a(i,j-1) + a(i,j+1) + a(i-1,j) + a(i+1,j)
      z(i,j) = 0.25 * a(i,j)  + .125 * plus + .0625 * crux
    1 CONTINUE
      DO 2  i=1,li
      z(i,1) = a(i,1)
      z(i,lj) = a(i,lj)
    2 CONTINUE
      DO 3  j=1,lj
      z(1,j) = a(1,j)
      z(li,j) = a(li,j)
    3 CONTINUE
      DO 4  j=2,lj1
      DO 4  i=2,li1
      crux = z(i-1,j-1) + z(i+1,j-1) + z(i+1,j+1) + z(i-1,j+1)
      plus = z(i,j-1) + z(i,j+1) + z(i-1,j) + z(i+1,j)
      a(i,j) = 2.25 * z(i,j)  - .375 * plus + .0625 * crux
    4 CONTINUE
      RETURN
      END