w3ymdh4.f

Go to the documentation of this file.

C> @file
C> @brief 4-byte date word unpacker and packer.
C> @author K. F. Brill @date 1998-07-29
 
C> Obtains the components of the nmc date word (ncep y2k
C> compliant form), or given its components, forms an nmc type date
C> word. The packing is done using base 32.
C>
C> If the first byte of IDATE is less than 101, then the old
C> Office Note 84 packing is assumed. A four-digit year is
C> always returned. To pack the "old" way, pass in a 2-digit
C> year.
C>
C> This program will work for the years ranging from A.D. 101
C> through 79359.
C>
C> On unpacking, years less than or equal to 100 are returned
C> as follows:
C>
C> - 0-50   2000--2050
C> - 51-100 1951--2000
C>
C>
C> ### Program History Log:
C> Date | Programmer | Comment
C> -----|------------|--------
C> 1998-07-29 | K. F. Brill | Initial.
C> 1999-03-15 | Gilbert | Removed Call to W3FS11() and put its processing inline.
C> W3FS11 was deleted from the W3LIB.
C>
C> @param[inout] IDATE Left 4 bytes of integer 64 bit word, or can be
C> IDATE(4) or CHARACTER*4 IDATE.
C> @param[inout] IYEAR Year (4 digits or 2 digits for on84)
C> @param[inout] MONTH Month
C> @param[inout] IDAY Day
C> @param[inout] IHOUR Hour
C> @param[in] NN Code:
C>  - .eq. 0 pack iyear, month, iday, ihour into idate
C>  - .ne. 0 unpack idate into iyear, month, iday, ihour
C>
C> @author K. F. Brill @date 1998-07-29
      SUBROUTINE w3ymdh4 (IDATE,IYEAR,MONTH,IDAY,IHOUR,NN)
C
      CHARACTER IDATE(4)
C
      IF (nn.NE.0) THEN
C
    itemp = mova2i(idate(1))
    IF ( itemp .lt. 101 ) THEN
            iyear  = mova2i(idate(1))
            month  = mova2i(idate(2))
            iday   = mova2i(idate(3))
            ihour  = mova2i(idate(4))
        IF(iyear.LE.100) iyear=2050-mod(2050-iyear,100)
        RETURN
    END IF
    itemp = itemp - 101
    itemp = itemp * 256 + mova2i(idate(2))
    itemp = itemp * 256 + mova2i(idate(3))
    itemp = itemp * 256 + mova2i(idate(4))
    ihour = mod( itemp, 32 )
    itemp = itemp / 32
    iday  = mod( itemp, 32 )
    itemp = itemp / 32
    month = mod( itemp, 32 )
    iyear = itemp / 32
C
      ELSE
C
    itemp = iyear
    IF ( itemp .lt. 101 ) THEN
            idate(1) = char(iyear)
            idate(2) = char(month)
            idate(3) = char(iday)
            idate(4) = char(ihour)
        RETURN
    END IF
    itemp = itemp * 32 + month
    itemp = itemp * 32 + iday
    itemp = itemp * 32 + ihour
C*
    idate(4)=char(mod(itemp,256))
    itemp = itemp / 256
    idate(3)=char(mod(itemp,256))
    itemp = itemp / 256
    idate(2)=char(mod(itemp,256))
    itemp = itemp / 256
    itemp = itemp + 101
    idate(1)=char(itemp)
C
      ENDIF
C
      RETURN
      END