CALMCVG.f

Go to the documentation of this file.

 
!-----------------------------------------------------------------------
!-----------------------------------------------------------------------
      SUBROUTINE calmcvg(Q1D,U1D,V1D,QCNVG)
 
!
!     
!     
      use masks,        only: dx, dy, hbm2
      use params_mod,   only: d00, d25
      use ctlblk_mod,   only: jsta_2l, jend_2u, spval, jsta_m, jend_m,       &
                              jsta_m2, jend_m2, im, jm,                      &
                              ista_2l, iend_2u, ista_m, iend_m, ista_m2, iend_m2 
      use gridspec_mod, only: gridtype
!- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      implicit none
!     
!     DECLARE VARIABLES.
!     
      REAL,dimension(ista_2l:iend_2u,jsta_2l:jend_2u),intent(in)    ::  Q1D, U1D, V1D
      REAL,dimension(ista_2l:iend_2u,jsta_2l:jend_2u),intent(inout) ::  QCNVG
 
      REAL R2DY, R2DX
      REAL, dimension(ista_2l:iend_2u,jsta_2l:jend_2u) ::  UWND, VWND, QV
      INTEGER IHE(JM),IHW(JM),IVE(JM),IVW(JM)
      integer I,J,ISTA2,IEND2
      real QVDY,QUDX
!     
!***************************************************************************
!     START CALMCVG HERE.
!
!     
!     INITIALIZE MOISTURE CONVERGENCE ARRAY.  LOAD TEMPORARY WIND ARRAYS.
!     
       CALL exch(q1d)
       CALL exch(u1d)
       CALL exch(v1d)
 
!$omp  parallel do private(i,j)
      DO j=jsta_2l,jend_2u
!        DO I=1,IM
        DO i=ista_2l,iend_2u
          IF(u1d(i,j)<spval)THEN
          qcnvg(i,j) = 0.
          ELSE
          qcnvg(i,j) = spval
          ENDIF
          uwnd(i,j)  = u1d(i,j)
          vwnd(i,j)  = v1d(i,j)
          IF (uwnd(i,j) == spval) uwnd(i,j) = d00
          IF (vwnd(i,j) == spval) vwnd(i,j) = d00
        ENDDO
      ENDDO
!
      IF(gridtype == 'A')THEN
!$omp  parallel do private(i,j,qudx,qvdy,r2dx,r2dy)
       DO j=jsta_m,jend_m
!         DO I=2,IM-1
         DO i=ista_m,iend_m
           IF(q1d(i,j+1)<spval.AND.q1d(i,j-1)<spval.AND.          &
              q1d(i+1,j)<spval.AND.q1d(i-1,j)<spval.AND. &
              q1d(i,j)<spval) THEN
             r2dx   = 1./(2.*dx(i,j))   !MEB DX?
             r2dy   = 1./(2.*dy(i,j))   !MEB DY?  
             qudx   = (q1d(i+1,j)*uwnd(i+1,j)-q1d(i-1,j)*uwnd(i-1,j))*r2dx
             qvdy   = (q1d(i,j+1)*vwnd(i,j+1)-q1d(i,j-1)*vwnd(i,j-1))*r2dy
             qcnvg(i,j) = -(qudx + qvdy)
           ELSE
             qcnvg(i,j) = spval
           ENDIF
         ENDDO
       ENDDO
      ELSE IF(gridtype == 'E')THEN
 
       DO j=jsta_m,jend_m
         ihe(j) = mod(j+1,2)
         ihw(j) = ihe(j)-1
         ive(j) = mod(j,2)
         ivw(j) = ive(j)-1 
       END DO
     
!$omp  parallel do private(i,j)
       DO j=jsta_m,jend_m
!         ISTA = 1+MOD(J+1,2)
!         IEND = IM-MOD(J,2)
!         DO I=ISTA,IEND
         DO i=ista_m,iend_m
          IF(q1d(i,j-1)<spval.AND.q1d(i+ivw(j),j)<spval.AND.&
             q1d(i+ive(j),j)<spval.AND.q1d(i,j+1)<spval) THEN
           qv(i,j) = d25*(q1d(i,j-1)+q1d(i+ivw(j),j)                   &
                         +q1d(i+ive(j),j)+q1d(i,j+1))
          ELSE
           qv(i,j) = spval
          ENDIF
         END DO
       END DO
 
       CALL exch(qv)
!      CALL EXCH(VWND)
 
!
!$omp  parallel do private(i,j,qudx,qvdy,r2dx,r2dy)
       DO j=jsta_m2,jend_m2
!         IEND = IM-1-MOD(J,2)
!         DO I=2,IEND
         DO i=ista_m,iend_m-mod(j,2)
          IF(qv(i+ihe(j),j)<spval.AND.uwnd(i+ihe(j),j)<spval.AND.&
             qv(i+ihw(j),j)<spval.AND.uwnd(i+ihw(j),j)<spval.AND.&
             qv(i,j)<spval.AND.qv(i,j-1)<spval.AND.qv(i,j+1)<spval) THEN
           r2dx   = 1./(2.*dx(i,j))
           r2dy   = 1./(2.*dy(i,j))
           qudx   = (qv(i+ihe(j),j)*uwnd(i+ihe(j),j)                   &
                    -qv(i+ihw(j),j)*uwnd(i+ihw(j),j))*r2dx
           qvdy   = (qv(i,j+1)*vwnd(i,j+1)-qv(i,j-1)*vwnd(i,j-1))*r2dy
 
           qcnvg(i,j) = -(qudx + qvdy) * hbm2(i,j)
          ELSE
           qcnvg(i,j) = spval
          ENDIF
         ENDDO
       ENDDO
      ELSE IF(gridtype=='B')THEN
     
!       CALL EXCH(UWND)
!
!$omp  parallel do private(i,j,qudx,qvdy,r2dx,r2dy)
       DO j=jsta_m,jend_m
!        DO I=2,IM-1
        DO i=ista_m,iend_m
         IF(uwnd(i,j)<spval.AND.uwnd(i,j-1)<spval.AND.&
            uwnd(i-1,j)<spval.AND.uwnd(i-1,j-1)<spval.AND.&
            q1d(i,j)<spval.AND.q1d(i+1,j)<spval.AND.q1d(i-1,j)<spval.AND.&
            vwnd(i,j)<spval.AND.vwnd(i-1,j)<spval.AND.&
            vwnd(i,j-1)<spval.AND.vwnd(i-1,j-1)<spval.AND.&
            q1d(i,j+1)<spval.AND.q1d(i,j-1)<spval) THEN
          r2dx   = 1./dx(i,j)
          r2dy   = 1./dy(i,j)
          qudx=(0.5*(uwnd(i,j)+uwnd(i,j-1))*0.5*(q1d(i,j)+q1d(i+1,j))        &
               -0.5*(uwnd(i-1,j)+uwnd(i-1,j-1))*0.5*(q1d(i,j)+q1d(i-1,j)))*r2dx
          qvdy=(0.5*(vwnd(i,j)+vwnd(i-1,j))*0.5*(q1d(i,j)+q1d(i,j+1))        &
               -0.5*(vwnd(i,j-1)+vwnd(i-1,j-1))*0.5*(q1d(i,j)+q1d(i,j-1)))*r2dy
  
          qcnvg(i,j) = -(qudx + qvdy)
         ELSE
          qcnvg(i,j) = spval
         ENDIF
!     print*,'mcvg=',i,j,r2dx,r2dy,QCNVG(I,J)
        ENDDO
       ENDDO
      ENDIF
!meb not sure about the indexing for the c-grid
!
!     END OF ROUTINE.
!     
      RETURN
      END