w3src0md Module Reference

Mean wave parameter computation for case without input and dissipation. More...

Functions/Subroutines
subroutine	w3spr0 (A, CG, WN, EMEAN, FMEAN, WNMEAN, AMAX)
	Calculate mean wave parameters. More...

Detailed Description

Mean wave parameter computation for case without input and dissipation.

Author

H. L. Tolman

Date

29-May-2009

Function/Subroutine Documentation

w3spr0()

subroutine w3src0md::w3spr0	(	real, dimension(nth,nk), intent(in)	A,
		real, dimension(nk), intent(in)	CG,
		real, dimension(nk), intent(in)	WN,
		real, intent(out)	EMEAN,
		real, intent(out)	FMEAN,
		real, intent(out)	WNMEAN,
		real, intent(out)	AMAX
	)

Calculate mean wave parameters.

Parameters

[in]	A	Action as a function of direction and wavenumber.
[in]	CG	Group velocities.
[in]	WN	Wavenumbers.
[out]	EMEAN	Mean wave energy.
[out]	FMEAN	Mean wave frequency.
[out]	WNMEAN	Mean wavenumber.
[out]	AMAX	Maximum action density in spectrum.

Author

H. L. Tolman

Date

05-Jul-2006

Definition at line 82 of file w3src0md.F90.

    !/
    !/                  +-----------------------------------+
    !/                  | WAVEWATCH III           NOAA/NCEP |
    !/                  |           H. L. Tolman            |
    !/                  |                        FORTRAN 90 |
    !/                  | Last update :         05-Jul-2006 |
    !/                  +-----------------------------------+
    !/
    !/    05-Jul-2006 : Origination.                        ( version 3.09 )
    !/
    !  1. Purpose :
    !
    !     Calculate mean wave parameters.
    !
    !  2. Method :
    !
    !     See source term routines.
    !
    !  3. Parameters :
    !
    !     Parameter list
    !     ----------------------------------------------------------------
    !       A       R.A.  I   Action as a function of direction and
    !                         wavenumber.
    !       CG      R.A.  I   Group velocities.
    !       WN      R.A.  I   Wavenumbers.
    !       EMEAN   Real  O   Mean wave energy.
    !       FMEAN   Real  O   Mean wave frequency.
    !       WNMEAN  Real  O   Mean wavenumber.
    !       AMAX    Real  O   Maximum action density in spectrum.
    !     ----------------------------------------------------------------
    !
    !  4. Subroutines used :
    !
    !      Name      Type  Module   Description
    !     ----------------------------------------------------------------
    !      STRACE    Subr. W3SERVMD Subroutine tracing.
    !     ----------------------------------------------------------------
    !
    !  5. Called by :
    !
    !      Name      Type  Module   Description
    !     ----------------------------------------------------------------
    !      W3SRCE    Subr. W3SRCEMD Source term integration.
    !      W3EXPO    Subr.   N/A    Point output post-processor.
    !      GXEXPO    Subr.   N/A    GrADS point output post-processor.
    !     ----------------------------------------------------------------
    !
    !  6. Error messages :
    !
    !     None.
    !
    !  7. Remarks :
    !
    !  8. Structure :
    !
    !     See source code.
    !
    !  9. Switches :
    !
    !     !/S  Enable subroutine tracing.
    !     !/T  Enable test output.
    !
    ! 10. Source code :
    !
    !/ ------------------------------------------------------------------- /
    USE constants
    USE w3gdatmd, ONLY: nk, nth, sig, dden, fte, ftf, ftwn
#ifdef W3_T
    USE w3odatmd, ONLY: ndst
#endif
#ifdef W3_S
    USE w3servmd, ONLY: strace
#endif
    !
    IMPLICIT NONE
    !/
    !/ ------------------------------------------------------------------- /
    !/ Parameter list
    !/
    REAL, INTENT(IN)        :: A(NTH,NK), CG(NK), WN(NK)
    REAL, INTENT(OUT)       :: EMEAN, FMEAN, WNMEAN, AMAX
    !/
    !/ ------------------------------------------------------------------- /
    !/ Local parameters
    !/
    INTEGER                 :: IK, ITH
#ifdef W3_S
    INTEGER, SAVE           :: IENT = 0
#endif
    REAL                    :: EB(NK), EBAND
    !/
    !/ ------------------------------------------------------------------- /
    !/
#ifdef W3_S
    CALL strace (ient, 'W3SPR0')
#endif
    !
    emean  = 0.
    fmean  = 0.
    wnmean = 0.
    amax   = 0.
    !
    ! 1.  Integral over directions
    !
    DO ik=1, nk
      eb(ik) = 0.
      DO ith=1, nth
        eb(ik) = eb(ik) + a(ith,ik)
        amax   = max( amax , a(ith,ik) )
      END DO
    END DO
    !
    ! 2.  Integrate over directions
    !
    DO ik=1, nk
      eb(ik) = eb(ik) * dden(ik) / cg(ik)
      emean  = emean  + eb(ik)
      fmean  = fmean  + eb(ik) / sig(ik)
      wnmean = wnmean + eb(ik) / sqrt(wn(ik))
    END DO
    !
    ! 3.  Add tail beyond discrete spectrum
    !     ( DTH * SIG absorbed in FTxx )
    !
    eband  = eb(nk) / dden(nk)
    emean  = emean  + eband * fte
    fmean  = fmean  + eband * ftf
    wnmean = wnmean + eband * ftwn
    !
    ! 4.  Final processing
    !
    fmean  = tpiinv * emean / max( 1.e-7 , fmean )
    wnmean = ( emean / max( 1.e-7 , wnmean ) )**2
    !
#ifdef W3_T
    WRITE (ndst,9000) emean, fmean, wnmean
#endif
    !
    RETURN
    !
    ! Formats
    !
#ifdef W3_T
9000 FORMAT (' TEST W3SPR0 : E,F,WN MEAN ',3e10.3)
#endif
    !/
    !/ End of W3SPR0 ----------------------------------------------------- /
    !/

References w3gdatmd::dden, w3gdatmd::fte, w3gdatmd::ftf, w3gdatmd::ftwn, w3odatmd::ndst, w3gdatmd::nk, w3gdatmd::nth, w3gdatmd::sig, w3servmd::strace(), and constants::tpiinv.

Referenced by w3srcemd::w3srce().