WW3/w3flx5md_8F90_source.html

#include "w3macros.h"


!/ ------------------------------------------------------------------- /

MODULE w3flx5md

  !/

  !/                  +-----------------------------------+

  !/                  | WAVEWATCH III           NOAA/NCEP |

  !/                  |                                   |

  !/                  |           N.G. Valiente           |

  !/                  |           J. Edward               |

  !/                  |           A. Saulter              |

  !/                  |                        FORTRAN 90 |

  !/                  | Last update :         01-Jul-2021 |

  !/                  +-----------------------------------+

  !/

  !/    22-Mar-2021 : Origination.                        ( version 7.14 )

  !/    22-Mar-2021 : Enable direct use of atmospheric model wind stress

  !/                  by source terms ST6

  !/    01-Jul-2021 : Enable direct use of atmospheric model wind stress

  !/                  by source terms ST4

  !/

  !/    Copyright 2009 National Weather Service (NWS),

  !/       National Oceanic and Atmospheric Administration.  All rights

  !/       reserved.  WAVEWATCH III is a trademark of the NWS.

  !/       No unauthorized use without permission.

  !/

  !  1. Purpose :

  !

  !     Unified process to obtain friction velocity and drag when stresses are an

  !     input (from atmospheric model).

  !

  !     References:

  !          XX

  !

  !  2. Variables and types :

  !

  !  3. Subroutines and functions :

  !

  !      Name      Type  Scope    Description

  !     ----------------------------------------------------------------

  !      W3FLX5    Subr. Public   Stresses closure

  !     ----------------------------------------------------------------

  !

  !  4. Subroutines and functions used :

  !

  !      Name      Type  Module   Description

  !     ----------------------------------------------------------------

  !      STRACE    Subr. W3SERVMD Subroutine tracing.

  !     ----------------------------------------------------------------

  !

  !  5. Remarks :

  !

  !  6. Switches :

  !

  !     !/S  Enable subroutine tracing.

  !

  !  7. Source code :

  !/

  !/ ------------------------------------------------------------------- /

  !/

  PUBLIC

  !/

CONTAINS

  !/ ------------------------------------------------------------------- /

  SUBROUTINE w3flx5 ( ZWND, U10, U10D, TAUA, TAUADIR, RHOAIR, UST, USTD, Z0, CD, CHARN )

    !/

    !/                  +-----------------------------------+

    !/                  | WAVEWATCH III           NOAA/NCEP |

    !/                  |                     |

    !/                  |           N.G. Valiente           |

    !/                  |           J. Edward               |

    !/                  |           A. Saulter              |

    !/                  |                        FORTRAN 90 |

    !/                  | Last update :         01-Jul-2021 |

    !/                  +-----------------------------------+

    !/

    !/    22-Mar-2021 : Origination.                        ( version 7.14 )

    !/    22-Mar-2021 : Enable direct use of atmospheric model wind stress

    !/                  by source terms ST6

    !/    01-Jul-2021 : Enable direct use of atmospheric model wind stress

    !/                  by source terms ST4

    !/

    !  1. Purpose :

    !

    !     Unified process to obtain friction velocity and drag when stresses are an

    !     input (from atmospheric model).

    !

    !  2. Method :

    !

    !     UST       = SQRT(TAUA / RHOAIR)

    !     USTD      = TAUADIR

    !     CD        = (UST/U10)**2

    !     SQRTCDM1  = MIN(U10/UST,100.0)

    !     Z0        = ZWND*EXP(-KAPPA*SQRTCDM1)

    !

    !  3. Parameters :

    !

    !     Parameter list

    !     ----------------------------------------------------------------

    !       ZWND    Real   I   Wind height.

    !       U10     Real   I   Wind speed.

    !       U10D    Real   I   Wind direction.

    !       TAUA    Real   I   Atm. total stress.

    !       TAUADIR Real   I   Atm. total stress direction.

    !       RHOAIR  Real   I   Air density.

    !       UST     Real   O   Friction velocity.

    !       USTD    Real   0   Direction of friction velocity.

    !       Z0      Real   O   z0 in profile law.

    !       CD      Real   O   Drag coefficient.

    !       CHARN   Real   O   Charnock coefficient

    !     ----------------------------------------------------------------

    !

    !  4. Subroutines used :

    !

    !      Name      Type  Module   Description

    !     ----------------------------------------------------------------

    !      STRACE    Subr. W3SERVMD Subroutine tracing.

    !     ----------------------------------------------------------------

    !

    !  5. Called by :

    !

    !      Name      Type  Module   Description

    !     ----------------------------------------------------------------

    !      W3SRCE    Subr. W3SRCEMD Source term integration.

    !     ----------------------------------------------------------------

    !

    !  6. Error messages :

    !

    !       None.

    !

    !  7. Remarks :

    !

    !  8. Structure :

    !

    !     See source code.

    !

    !  9. Switches :

    !

    !     !/S  Enable subroutine tracing.

    !

    ! 10. Source code :

    !

    !/ ------------------------------------------------------------------- /

    USE constants, ONLY: kappa, grav, nu_air

    USE w3odatmd, ONLY: ndse, iaproc, naperr

    USE w3servmd, ONLY: extcde

#ifdef W3_S

    USE w3servmd, ONLY: strace

#endif

    !/

    IMPLICIT NONE

    !/

    !/ ------------------------------------------------------------------- /

    !/ Parameter list

    !/

    REAL, INTENT(IN)        :: ZWND, U10, U10D, TAUA, TAUADIR, RHOAIR

    REAL, INTENT(OUT)       :: UST, USTD, Z0, CD, CHARN

    REAL                    :: UNZ, SQRTCDM1

    !/

    !/ ------------------------------------------------------------------- /

    !/ Local parameters

    !/

#ifdef W3_S

    INTEGER, SAVE           :: IENT = 0

#endif

    !/

    !/ ------------------------------------------------------------------- /

    !/

#ifdef W3_S

    CALL strace (ient, 'W3FLX5')

#endif

    !

    ! 1.  Tests ---------------------------------------------------------- *

    !

    IF ( abs(zwnd-10.) .GT. 0.01 ) THEN

      IF ( iaproc .EQ. naperr ) WRITE (ndse,1000) zwnd

      CALL extcde (1)

    END IF

    !

    ! 2.  Computation ---------------------------------------------------- *

    !

    !

    ust    = max( 1e-4, sqrt(taua/rhoair) )

    unz    = max( 0.01 , u10 )

    cd     = (ust/unz)**2

    ustd   = tauadir

    sqrtcdm1  = min(unz/ust,100.0)

    z0        = zwnd*exp(-kappa*sqrtcdm1)

    IF (unz.GT.2.5) THEN

      charn = (z0 - 0.11 * nu_air / ust) * grav / ust**2

      charn = max( charn , 0.0095 )

      charn = min( 0.035 , charn )

    ELSE

      charn = 0.0095

    END IF

    !

    RETURN

    !

    ! Formats

    !

1000 FORMAT (/' *** WAVEWATCH III ERROR IN W3FLX5 : '/                 &

         '     HEIGHT OF WIND SHOULD BE 10m IN THIS APPROACH '/   &

         '     ZWND =',f8.2,'m'/)

    !/

    !/ End of W3FLX5 ----------------------------------------------------- /

    !/

  END SUBROUTINE w3flx5

  !/

  !/ End of module W3FLX5MD -------------------------------------------- /

  !/

END MODULE w3flx5md