WW3/w3nmluprstrmd_8F90_source.html

#include "w3macros.h"

!/ ------------------------------------------------------------------- /

MODULE w3nmluprstrmd

  !/

  !/                  +-----------------------------------+

  !/                  | WAVEWATCH III           NOAA/NCEP |

  !/                  |           M. Accensi              |

  !/                  |                                   |

  !/                  |                        FORTRAN 90 |

  !/                  | Last update :         06-Oct-2020 |

  !/                  +-----------------------------------+

  !/

  !/    For updates see subroutines.

  !/

  !  1. Purpose :

  !

  !     Manages namelists from configuration file ww3_uprstr.nml for ww3_uprstr program

  !

  !/ ------------------------------------------------------------------- /


  ! module defaults

  IMPLICIT NONE


  PUBLIC


  ! restart time

  TYPE nml_restart_t

    CHARACTER(15)               :: restarttime

  END TYPE nml_restart_t


  ! update approach

  TYPE nml_update_t

    CHARACTER(5)                :: updproc

    REAL                        :: prcntg

    REAL                        :: prcntgcap

    REAL                        :: thrwsea

    CHARACTER(30)               :: file

  END TYPE nml_update_t


  ! miscellaneous

  CHARACTER(256)                :: msg

  INTEGER                       :: ndsn


CONTAINS

  !/ ------------------------------------------------------------------- /

  SUBROUTINE w3nmluprstr (NDSI, INFILE, NML_RESTART, NML_UPDATE, IERR)

    !/

    !/                  +-----------------------------------+

    !/                  | WAVEWATCH III           NOAA/NCEP |

    !/                  |           M. Accensi              |

    !/                  |                                   |

    !/                  |                        FORTRAN 90 |

    !/                  | Last update :         06-Oct-2020 |

    !/                  +-----------------------------------+

    !/

    !

    !  1. Purpose :

    !

    !     Reads all the namelist to define the output field

    !

    !  2. Method :

    !

    !     See source term routines.

    !

    !  3. Parameters :

    !

    !     Parameter list

    !     ----------------------------------------------------------------

    !      NDSI        Int.

    !      INFILE      Char.

    !      NML_RESTART type.

    !      NML_UPDATE  type.

    !      IERR        Int.

    !     ----------------------------------------------------------------

    !

    !  4. Subroutines used :

    !

    !      Name      TYPE  Module   Description

    !     ----------------------------------------------------------------

    !      STRACE    Subr. W3SERVMD SUBROUTINE tracing.

    !      READ_RESTART_NML

    !      READ_UPDATE_NML

    !     ----------------------------------------------------------------

    !

    !  5. Called by :

    !

    !      Name       TYPE   Module   Description

    !     ----------------------------------------------------------------

    !      WW3_UPRSTR Prog.  N/A      Update restart file

    !     ----------------------------------------------------------------

    !

    !  6. Error messages :

    !

    !     None.

    !

    !  7. Remarks :

    !

    !  8. Structure :

    !

    !     See source code.

    !

    !  9. Switches :

    !

    ! 10. Source code :

    !

    !/ ------------------------------------------------------------------- /


    USE w3odatmd, ONLY: ndse

#ifdef W3_S

    USE w3servmd, ONLY: strace

#endif


    IMPLICIT NONE


    INTEGER, INTENT(IN)                         :: NDSI

    CHARACTER*(*), INTENT(IN)                   :: INFILE

    TYPE(nml_restart_t), INTENT(INOUT)          :: NML_RESTART

    TYPE(nml_update_t), INTENT(INOUT)           :: NML_UPDATE

    INTEGER, INTENT(OUT)                        :: IERR

#ifdef W3_S

    INTEGER, SAVE                             :: IENT = 0

#endif


    ierr = 0

#ifdef W3_S

    CALL strace (ient, 'W3NMLUPRSTR')

#endif


    ! open namelist log file

    ndsn = 3

    OPEN (ndsn, file=trim(infile)//'.log', form='formatted', iostat=ierr)

    IF (ierr.NE.0) THEN

      WRITE (ndse,'(A)') 'ERROR: open full nml file '//trim(infile)//'.log failed'

      RETURN

    END IF


    ! open input file

    OPEN (ndsi, file=trim(infile), form='formatted', status='old', iostat=ierr)

    IF (ierr.NE.0) THEN

      WRITE (ndse,'(A)') 'ERROR: open input file '//trim(infile)//' failed'

      RETURN

    END IF


    ! read restart time namelist

    CALL read_restart_nml (ndsi, nml_restart)

    CALL report_restart_nml (nml_restart)


    ! read update approach namelist

    CALL read_update_nml (ndsi, nml_update)

    CALL report_update_nml (nml_update)


    ! close namelist files

    CLOSE (ndsi)

    CLOSE (ndsn)


  END SUBROUTINE w3nmluprstr


  !/ ------------------------------------------------------------------- /


  !/ ------------------------------------------------------------------- /


  SUBROUTINE read_restart_nml (NDSI, NML_RESTART)

    !/

    !/                  +-----------------------------------+

    !/                  | WAVEWATCH III           NOAA/NCEP |

    !/                  |           M. Accensi              |

    !/                  |                                   |

    !/                  |                        FORTRAN 90 |

    !/                  | Last update :         06-Oct-2020 |

    !/                  +-----------------------------------+

    !/

    !  1. Purpose :

    !

    !

    !  2. Method :

    !

    !     See source term routines.

    !

    !  3. Parameters :

    !

    !     Parameter list

    !     ----------------------------------------------------------------

    !      NDSI         Int.

    !      NML_RESTART  Type.

    !     ----------------------------------------------------------------

    !

    !  4. Subroutines used :

    !

    !      Name      TYPE  Module   Description

    !     ----------------------------------------------------------------

    !      STRACE    Subr. W3SERVMD SUBROUTINE tracing.

    !     ----------------------------------------------------------------

    !

    !  5. Called by :

    !

    !      Name        TYPE   Module  Description

    !     ----------------------------------------------------------------

    !      W3NMLUPRSTR Subr.   N/A    Namelist configuration routine.

    !     ----------------------------------------------------------------

    !

    !  6. Error messages :

    !

    !     None.

    !

    !  7. Remarks :

    !

    !  8. Structure :

    !

    !     See source code.

    !

    !  9. Switches :

    !

    ! 10. Source code :

    !

    !/ ------------------------------------------------------------------- /


    USE w3odatmd, ONLY: ndse

    USE w3servmd, ONLY: extcde

#ifdef W3_S

    USE w3servmd, ONLY: strace

#endif


    IMPLICIT NONE


    INTEGER, INTENT(IN)                 :: NDSI

    TYPE(nml_restart_t), INTENT(INOUT)    :: NML_RESTART


    ! locals

    INTEGER                                :: IERR

    TYPE(nml_restart_t) :: RESTART

    namelist /restart_nml/ restart

#ifdef W3_S

    INTEGER, SAVE                           :: IENT = 0

#endif


    ierr = 0

#ifdef W3_S

    CALL strace (ient, 'READ_RESTART_NML')

#endif


    ! set default values

    restart%RESTARTTIME  = '19680607 120000'


    ! read restart namelist

    rewind(ndsi)

    READ (ndsi, nml=restart_nml, iostat=ierr, iomsg=msg)

    IF (ierr.NE.0) THEN

      WRITE (ndse,'(A,/A)') &

           'ERROR: READ_RESTART_NML: namelist read error', &

           'ERROR: '//trim(msg)

      CALL extcde (1)

    END IF


    ! save namelist

    nml_restart = restart


  END SUBROUTINE read_restart_nml


  !/ ------------------------------------------------------------------- /


  !/ ------------------------------------------------------------------- /


  SUBROUTINE read_update_nml (NDSI, NML_UPDATE)

    !/

    !/                  +-----------------------------------+

    !/                  | WAVEWATCH III           NOAA/NCEP |

    !/                  |           M. Accensi              |

    !/                  |                                   |

    !/                  |                        FORTRAN 90 |

    !/                  | Last update :         06-Oct-2020 |

    !/                  +-----------------------------------+

    !/

    !  1. Purpose :

    !

    !

    !  2. Method :

    !

    !     See source term routines.

    !

    !  3. Parameters :

    !

    !     Parameter list

    !     ----------------------------------------------------------------

    !      NDSI         Int.

    !      NML_UPDATE   Type.

    !     ----------------------------------------------------------------

    !

    !  4. Subroutines used :

    !

    !      Name      TYPE  Module   Description

    !     ----------------------------------------------------------------

    !      STRACE    Subr. W3SERVMD SUBROUTINE tracing.

    !     ----------------------------------------------------------------

    !

    !  5. Called by :

    !

    !      Name        TYPE   Module  Description

    !     ----------------------------------------------------------------

    !      W3NMLUPRSTR Subr.   N/A    Namelist configuration routine.

    !     ----------------------------------------------------------------

    !

    !  6. Error messages :

    !

    !     None.

    !

    !  7. Remarks :

    !

    !  8. Structure :

    !

    !     See source code.

    !

    !  9. Switches :

    !

    ! 10. Source code :

    !

    !/ ------------------------------------------------------------------- /


    USE w3odatmd, ONLY: ndse

    USE w3servmd, ONLY: extcde

#ifdef W3_S

    USE w3servmd, ONLY: strace

#endif


    IMPLICIT NONE


    INTEGER, INTENT(IN)                 :: NDSI

    TYPE(nml_update_t), INTENT(INOUT)   :: NML_UPDATE


    ! locals

    INTEGER                                :: IERR

    TYPE(nml_update_t) :: UPDATE

    namelist /update_nml/ update

#ifdef W3_S

    INTEGER, SAVE                           :: IENT = 0

#endif


    ierr = 0

#ifdef W3_S

    CALL strace (ient, 'READ_UPDATE_NML')

#endif


    ! set default values for update approach

    ! as set, these would run the update but not correct

    ! any spectra (scalar correction by factor of 1.0)

    update%UPDPROC    = 'UPD0F'      ! Update type

    update%PRCNTG     = 1.0          ! Scalar correction factor (1.0=no correction)

    update%PRCNTGCAP  = 10.0         ! Cap on correction factor

    update%THRWSEA    = 0.7          ! Energy threshold for wind-sea dominance

    update%FILE       = 'anl.grbtxt' ! Corrected analysed SWH field file


    ! read file namelist

    rewind(ndsi)

    READ (ndsi, nml=update_nml, iostat=ierr, iomsg=msg)

    IF (ierr.GT.0) THEN

      WRITE (ndse,'(A,/A)') &

           'ERROR: READ_UPDATE_NML: namelist read error', &

           'ERROR: '//trim(msg)

      CALL extcde (2)

    END IF


    ! save namelist

    nml_update = update


  END SUBROUTINE read_update_nml


  !/ ------------------------------------------------------------------- /


  !/ ------------------------------------------------------------------- /


  SUBROUTINE report_restart_nml (NML_RESTART)

    !/

    !/                  +-----------------------------------+

    !/                  | WAVEWATCH III           NOAA/NCEP |

    !/                  |           M. Accensi              |

    !/                  |                        FORTRAN 90 |

    !/                  | Last update :         06-Oct-2020 |

    !/                  +-----------------------------------+

    !/

    !/

    !  1. Purpose :

    !

    !

    !  2. Method :

    !

    !     See source term routines.

    !

    !  3. Parameters :

    !

    !     Parameter list

    !     ----------------------------------------------------------------

    !      NML_RESTART  Type.

    !     ----------------------------------------------------------------

    !

    !  4. Subroutines used :

    !

    !      Name      TYPE  Module   Description

    !     ----------------------------------------------------------------

    !      STRACE    Subr. W3SERVMD SUBROUTINE tracing.

    !     ----------------------------------------------------------------

    !

    !  5. Called by :

    !

    !      Name        TYPE   Module  Description

    !     ----------------------------------------------------------------

    !      W3NMLUPRSTR Subr.   N/A    Namelist configuration routine.

    !     ----------------------------------------------------------------

    !

    !  6. Error messages :

    !

    !     None.

    !

    !  7. Remarks :

    !

    !  8. Structure :

    !

    !     See source code.

    !

    !  9. Switches :

    !

    ! 10. Source code :

    !

    !/ ------------------------------------------------------------------- /


#ifdef W3_S

    USE w3servmd, ONLY: strace

#endif


    IMPLICIT NONE


    TYPE(nml_restart_t), INTENT(IN) :: NML_RESTART

#ifdef W3_S

    INTEGER, SAVE                           :: IENT = 0

#endif


#ifdef W3_S

    CALL strace (ient, 'REPORT_RESTART_NML')

#endif


    WRITE (msg,'(A)') 'RESTART % '

    WRITE (ndsn,'(A)')

    WRITE (ndsn,10) trim(msg),'RESTARTTIME = ', trim(nml_restart%RESTARTTIME)


10  FORMAT (a,2x,a,a)


  END SUBROUTINE report_restart_nml


  !/ ------------------------------------------------------------------- /


  !/ ------------------------------------------------------------------- /


  SUBROUTINE report_update_nml (NML_UPDATE)

    !/

    !/                  +-----------------------------------+

    !/                  | WAVEWATCH III           NOAA/NCEP |

    !/                  |           M. Accensi              |

    !/                  |                        FORTRAN 90 |

    !/                  | Last update :         06-Oct-2020 |

    !/                  +-----------------------------------+

    !/

    !/

    !  1. Purpose :

    !

    !

    !  2. Method :

    !

    !     See source term routines.

    !

    !  3. Parameters :

    !

    !     Parameter list

    !     ----------------------------------------------------------------

    !      NML_UPDATE  Type.

    !     ----------------------------------------------------------------

    !

    !  4. Subroutines used :

    !

    !      Name      TYPE  Module   Description

    !     ----------------------------------------------------------------

    !      STRACE    Subr. W3SERVMD SUBROUTINE tracing.

    !     ----------------------------------------------------------------

    !

    !  5. Called by :

    !

    !      Name        TYPE   Module  Description

    !     ----------------------------------------------------------------

    !      W3NMLUPRSTR Subr.   N/A    Namelist configuration routine.

    !     ----------------------------------------------------------------

    !

    !  6. Error messages :

    !

    !     None.

    !

    !  7. Remarks :

    !

    !  8. Structure :

    !

    !     See source code.

    !

    !  9. Switches :

    !

    ! 10. Source code :

    !

    !/ ------------------------------------------------------------------- /


#ifdef W3_S

    USE w3servmd, ONLY: strace

#endif


    IMPLICIT NONE


    TYPE(nml_update_t), INTENT(IN) :: NML_UPDATE

#ifdef W3_S

    INTEGER, SAVE                           :: IENT = 0

#endif


#ifdef W3_S

    CALL strace (ient, 'REPORT_UPDATE_NML')

#endif


    WRITE (msg,'(A)') 'UPDATE % '

    WRITE (ndsn,'(A)')

    WRITE (ndsn,10) trim(msg),'UPDPROC   = ', trim(nml_update%UPDPROC)

    ! PRCNTG only used by UPD0F

    IF (trim(nml_update%UPDPROC) .EQ. 'UPD0F') THEN

      WRITE (ndsn,11) trim(msg),'PRCNTG    = ', nml_update%PRCNTG

    ELSE

      WRITE (ndsn,11) trim(msg),'PRCNTGCAP = ', nml_update%PRCNTGCAP

      ! THRWSEA only used by UPD5/6

      IF ((trim(nml_update%UPDPROC) .EQ. 'UPD5') .OR. &

           (trim(nml_update%UPDPROC) .EQ. 'UPD6')) THEN

        WRITE (ndsn,11) trim(msg),'THRWSEA   = ', nml_update%THRWSEA

      ENDIF

      WRITE (ndsn,10) trim(msg),'FILE      = ', trim(nml_update%FILE)

    ENDIF


10  FORMAT (a,2x,a,a)

11  FORMAT (a,2x,a,f5.3)


  END SUBROUTINE report_update_nml


  !/ ------------------------------------------------------------------- /


END MODULE w3nmluprstrmd


!/ ------------------------------------------------------------------- /