w3oacpmd.F90

Go to the documentation of this file.

#include "w3macros.h"
!/ ------------------------------------------------------------------- /
MODULE w3oacpmd
  !/
  !/                  +-----------------------------------+
  !/                  | WAVEWATCH III           NOAA/NCEP |
  !/                  |           A. Thevenin             |
  !/                  |                        FORTRAN 90 |
  !/                  | Last update :         22-Mar-2021 |
  !/                  +-----------------------------------+
  !/
  !/      July-2013 : Origination.                         ( version 4.18 )
  !/                    For upgrades see subroutines.
  !/     April-2016 : Add comments (J. Pianezze)           ( version 5.07 )
  !/    25-Sep-2020 : Coupling at T+0 support              ( version 7.10 )
  !/    22-Mar-2021 : Adds extra coupling fields           ( version 7.13 )
  !/
  !/    Copyright 2009-2012 National Weather Service (NWS),
  !/       National Oceanic and Atmospheric Administration.  All rights
  !/       reserved.  WAVEWATCH III is a trademark of the NWS.
  !/       No unauthorized use without permission.
  !/
  !  1. Purpose :
  !
  !     Generic Module used for coupling applications with OASIS3-MCT
  !
  !  2. Variables and types :
  !
  !  3. Subroutines and functions :
  !
  !      Name                Type  Scope    Description
  !     ----------------------------------------------------------------
  !      CPL_OASIS_INIT      Subr. Public   Initialize the coupling
  !      CPL_OASIS_GRID      Subr. Public   Grids defintion
  !      CPL_OASIS_DEFINE    Subr. Public   Partition definition
  !      CPL_OASIS_SND       Subr. Public   Send fields to ocean/atmos model
  !      CPL_OASIS_RCV       Subr. Public   Receive fields from ocean/atmos model
  !      CPL_OASIS_FINALIZE  Subr. Public   Finalize the coupling
  !     ----------------------------------------------------------------
  !
  !  4. Subroutines and functions used :
  !
  !      Name                 Type    Module    Description
  !     --------------------------------------------------------------------
  !      GET_LIST_EXCH_FIELD  Subr.   W3OACPMD  List of the exchanged fields
  !      STRSPLIT             Subr.   W3SERVMD  Splits string into words
  !     --------------------------------------------------------------------
  !
  !  5. Remarks
  !
  !     Module adapted from WRF-OASIS routine implemented by
  !     Sebastien Masson (IPSL), Guillaume Samson (Legos) and Eric Maisonnave (Cerfacs)
  !
  !  6. Switches :
  !  7. Source code :
  !
  !/ ------------------------------------------------------------------- /
  !
  USE mod_oasis                                      ! OASIS3-MCT module
  !
  IMPLICIT NONE
  PRIVATE
  !
  INTEGER               :: IL_COMPID                 ! Component model ID returned by oasis_init_comp
  CHARACTER(LEN=6)      :: CL_MODEL_NAME = 'wwatch'  ! Model name (same as in namcouple)
  INTEGER               :: IL_ERR                    ! Return error code
  INTEGER, PUBLIC       :: il_nb_rcv, il_nb_snd      ! Number of coupling fields
  INTEGER, PARAMETER    :: ip_maxfld=50              ! Maximum number of coupling fields
  INTEGER               :: nnodes                    ! Total numbers of cell in the grid
  !
  TYPE, PUBLIC          :: cpl_field                 ! Type for coupling field information
    CHARACTER(LEN = 8) :: cl_field_name             ! Name of the coupling field
    INTEGER            :: il_field_id               ! Field ID
  END TYPE cpl_field
  !
  TYPE(cpl_field), DIMENSION(IP_MAXFLD), PUBLIC :: rcv_fld, snd_fld   ! Coupling fields
  !
  INTEGER, PUBLIC       :: id_oasis_time=0           ! time counter for coupling exchanges
  !
  LOGICAL, PUBLIC       :: cplt0                     ! Flag for coupling at T+0
  !
  ! * Accessibility
  PUBLIC cpl_oasis_init
  PUBLIC cpl_oasis_grid
  PUBLIC cpl_oasis_define
  PUBLIC cpl_oasis_snd
  PUBLIC cpl_oasis_rcv
  PUBLIC cpl_oasis_finalize
  !
CONTAINS
  !/ ------------------------------------------------------------------- /
  SUBROUTINE cpl_oasis_init(ID_LCOMM)
    !/
    !/                  +-----------------------------------+
    !/                  | WAVEWATCH III           NOAA/NCEP |
    !/                  |           A. Thevenin             |
    !/                  |                        FORTRAN 90 |
    !/                  | Last update :          April-2016 |
    !/                  +-----------------------------------+
    !/
    !/     Jul-2013 : Origination.                    ( version 4.18 )
    !/     April-2016 : Add comments (J. Pianezze)    ( version 5.07 )
    !/
    !  1. Purpose :
    !
    !     Initialize the coupling
    !
    !  2. Method :
    !  3. Parameters :
    !
    !     Parameter list
    !     ----------------------------------------------------------------
    !     ID_LCOMM     Int.     O    MPI communicator
    !     ----------------------------------------------------------------
    !
    !  4. Subroutines used :
    !
    !  5. Called by :
    !
    !      Name                Type     Module    Description
    !     ----------------------------------------------------------------
    !      WW3_SHEL            Prog.    -         Main program
    !     ----------------------------------------------------------------
    !
    !  6. Error messages :
    !  7. Remarks :
    !  8. Structure :
    !  9. Switches :
    ! 10. Source code :
    !
    !/ ------------------------------------------------------------------- /
    !
    ! * Argument
    INTEGER, INTENT(OUT) :: id_lcomm                   ! Model local communicator
    !
    !----------------------------------------------------------------------
    ! * Executable part
    !
    !! Initialize the coupling
    CALL oasis_init_comp(il_compid, cl_model_name, il_err)
    IF (il_err /= 0) THEN
      CALL oasis_abort(il_compid, 'CPL_OASIS_INIT', 'Problem during oasis_init_comp')
    ENDIF
    !
    !! Get the value of a local MPI communicator to be used by WW3 for its internal parallelisation
    CALL oasis_get_localcomm(id_lcomm, il_err)
    IF (il_err /= 0) THEN
      CALL oasis_abort(il_compid, 'CPL_OASIS_INIT', 'Problem during oasis_get_localcomm')
    ENDIF
    !
    !/ ------------------------------------------------------------------- /
  END SUBROUTINE cpl_oasis_init
  !/ ------------------------------------------------------------------- /
  SUBROUTINE cpl_oasis_grid(LD_MASTER,ID_LCOMM)
    !/
    !/                  +-----------------------------------+
    !/                  | WAVEWATCH III           NOAA/NCEP |
    !/                  |           A. Thevenin             |
    !/                  |           V. Garnier              |
    !/                  |           M. Accensi              |
    !/                  |                        FORTRAN 90 |
    !/                  | Last update :          April-2016 |
    !/                  +-----------------------------------+
    !/
    !/    Jul-2013 : Origination.                    ( version 4.18 )
    !/    April-2016 : Add comments (J. Pianezze)    ( version 5.07 )
    !/    Sept-2016 : Correct bug MPI (J. Pianezze)  ( version 5.12 )
    !/
    !  1. Purpose :
    !
    !     Grid data file definition
    !
    !  2. Method :
    !  3. Parameters :
    !
    !     Parameter list
    !     ----------------------------------------------------------------
    !     LD_MASTER         Bool.    I     Flag to know the master process
    !     ID_LCOMM          Int.     I     MPI communicator
    !     ----------------------------------------------------------------
    !
    !  4. Subroutines used :
    !  5. Called by :
    !
    !      Name                Type     Module    Description
    !     ----------------------------------------------------------------
    !      WW3_SHEL            Prog.    -         Main program
    !     ----------------------------------------------------------------
    !
    !  6. Error messages :
    !  7. Remarks :
    !  8. Structure :
    !  9. Switches :
    ! 10. Source code :
    !
    !/ ------------------------------------------------------------------- /
    !
    USE constants, ONLY: radius, dera
    USE w3gdatmd,  ONLY: nx, ny, flagll, xgrd, ygrd, mapsta, &
         & hpfac, hqfac, gtype, &
         & ungtype, rlgtype, clgtype, smctype
#ifdef W3_SMC
    USE w3gdatmd,  ONLY: nsea, x0, y0, mrfct, sx, sy, ijkcel
#endif
#ifdef W3_MPI
    include "mpif.h"
#endif
    !
    !/ ------------------------------------------------------------------- /
    !/ Parameter list
    !/
    LOGICAL, INTENT(IN) :: ld_master    ! MASTER process or not
    INTEGER, INTENT(IN) :: id_lcomm     ! Model local communicator
    !
    !/ ------------------------------------------------------------------- /
    !/ Local parameters
    !/
    INTEGER, ALLOCATABLE :: mask(:,:)
    INTEGER              :: i, ix, iy, nxw, nxe, nys, nyn, inode, ierr_mpi
    REAL, ALLOCATABLE    :: lon(:,:),lat(:,:),area(:,:),      &
         corlon(:,:,:),corlat(:,:,:)
    REAL                 :: factor
#ifdef W3_SMC
    REAL                 :: dlon, dlat
#endif
    !/ ------------------------------------------------------------------- /
    !
    IF (ld_master) THEN
      !
      !
      ! 0. Create grids file
      ! --------------------------------
      CALL oasis_start_grids_writing(ierr_mpi)
      !
      ! 1. Get the lat/lon/corners,areas and masks
      ! -------------------------------------------
      IF (gtype .EQ. rlgtype .OR. gtype .EQ. clgtype) THEN
        !
        IF (flagll) THEN
          factor = 1.
        ELSE
          factor = 1. / (radius * dera)
        END IF
        !
        ! 1.1. regular and curvilinear grids
        ! ----------------------------------
        nnodes = nx*ny
        nxw=1
        nxe=nx
        nys=1
        nyn=ny
        !
        ! lat/lon
        ALLOCATE ( lon(nnodes,1), lat(nnodes,1) )
        i = 0
        DO iy = nys, nyn
          DO ix = nxw, nxe
            i = i+1
            lon(i,1)=xgrd(iy,ix)*factor
            lat(i,1)=ygrd(iy,ix)*factor
          END DO
        END DO
        !
        ! areas, corners
        ALLOCATE ( area(nnodes,1), corlon(nnodes,1,4), corlat(nnodes,1,4) )
        i = 0
        DO iy = nys, nyn
          DO ix = nxw, nxe
            i = i+1
            corlon(i,1,1)=lon(i,1)+hpfac(iy,ix)/2.*factor
            corlon(i,1,2)=lon(i,1)-hpfac(iy,ix)/2.*factor
            corlon(i,1,3)=lon(i,1)-hpfac(iy,ix)/2.*factor
            corlon(i,1,4)=lon(i,1)+hpfac(iy,ix)/2.*factor
            corlat(i,1,1)=lat(i,1)+hqfac(iy,ix)/2.*factor
            corlat(i,1,2)=lat(i,1)+hqfac(iy,ix)/2.*factor
            corlat(i,1,3)=lat(i,1)-hqfac(iy,ix)/2.*factor
            corlat(i,1,4)=lat(i,1)-hqfac(iy,ix)/2.*factor
            area(i,1)=hpfac(iy,ix)*hqfac(iy,ix)
          END DO
        END DO
        !
        ! Model grid mask
        ALLOCATE ( mask(nnodes,1) )
        i = 0
        DO iy = nys, nyn
          DO ix = nxw, nxe
            i = i+1
            ! Get the mask : 0 - sea  / 1 - open boundary cells (the land is already excluded)
            IF ((mapsta(iy,ix) .EQ. 1)) THEN
              mask(i,1) = 0
            ELSE
              mask(i,1) = 1
            END IF
          END DO
        END DO
#ifdef W3_SMC
      ELSE IF( gtype .EQ. smctype ) THEN
        !
        ! 1.2. SMC grids
        ! ----------------------------------
        nnodes = nsea
        !
        ! Calculate the smallest grid cell increments depending on the number of SMC levels
        dlon = sx / mrfct
        dlat = sy / mrfct
        !
        ALLOCATE ( lon(nnodes,1), lat(nnodes,1) )
        ALLOCATE ( area(nnodes,1), corlon(nnodes,1,4), corlat(nnodes,1,4) )
        ALLOCATE ( mask(nnodes,1) )
        DO i=1, nnodes
          ! lat/lon
          lon(i,1) = x0 + (ijkcel(1,i) + ijkcel(3,i)*0.5)*dlon
          lat(i,1) = y0 + (ijkcel(2,i) + ijkcel(4,i)*0.5)*dlat
          ! corners
          corlon(i,1,1) = x0 + ijkcel(1,i)*dlon
          corlon(i,1,2) = x0 + (ijkcel(1,i) + ijkcel(3,i))*dlon
          corlon(i,1,3) = corlon(i,1,2)
          corlon(i,1,4) = corlon(i,1,1)
          corlat(i,1,1) = y0 + ijkcel(2,i)*dlat
          corlat(i,1,2)=corlat(i,1,1)
          corlat(i,1,3) = y0 + (ijkcel(2,i) + ijkcel(4,i))*dlat
          corlat(i,1,4)=corlat(i,1,3)
          ! areas
          area(i,1) = 0.25 * ijkcel(3,i)*dlon * ijkcel(4,i)*dlat
          ! Model grid mask
          mask(i,1) = 1
        ENDDO
#endif
        !
      ELSE
        !
        ! 1.3. Unstructured grids
        ! ----------------------------------
        WRITE(*,*) 'TO BE IMPLEMENT FOR UNSTRUCTURED GRIDS'
        stop
      END IF
      !
      CALL oasis_write_grid('ww3t',nnodes,1,lon,lat)
      CALL oasis_write_corner('ww3t',nnodes,1,4,corlon,corlat)
      CALL oasis_write_area('ww3t',nnodes,1,area)
      CALL oasis_write_mask('ww3t',nnodes,1,mask)
      !
      ! 2. Terminate grid writing
      ! -------------------------
      CALL oasis_terminate_grids_writing()
      !
      DEALLOCATE(lon)
      DEALLOCATE(lat)
      DEALLOCATE(corlon)
      DEALLOCATE(corlat)
      DEALLOCATE(area)
      DEALLOCATE(mask)
      !
    ENDIF
    !
#ifdef W3_MPI
    CALL mpi_bcast(nnodes,1,mpi_integer,0,id_lcomm,ierr_mpi)
#endif
    !
    !/ ------------------------------------------------------------------- /
  END SUBROUTINE cpl_oasis_grid
  !/ ------------------------------------------------------------------- /
  SUBROUTINE cpl_oasis_define(NDSO,RCV_STR,SND_STR)
    !/
    !/                  +-----------------------------------+
    !/                  | WAVEWATCH III           NOAA/NCEP |
    !/                  |           A. Thevenin             |
    !/                  |           V. Garnier              |
    !/                  |           M. Accensi              |
    !/                  |                        FORTRAN 90 |
    !/                  | Last update :         08-Jun-2018 |
    !/                  +-----------------------------------+
    !/
    !/      Jul-2013 : Origination.                         ( version 4.18 )
    !/    April-2016 : Add coupling for unstructured grids  ( version 5.07 )
    !/                   (R. Baraille & J. Pianezze)
    !/    April-2016 : Add comments (J. Pianezze)           ( version 5.07 )
    !/    08-Jun-2018 : use INIT_GET_ISEA                   ( version 6.04 )
    !/
    !  1. Purpose :
    !
    !     Partition definition and coupling fields declaration
    !
    !  2. Method :
    !  3. Parameters :
    !
    !     Parameter list
    !     ----------------------------------------------------------------
    !     NDSO             Int.      I      Id. of the output file
    !     RCV_STR          Char.     I      Name of receive fields
    !     SND_STR          Char.     I      Name of send fields
    !     ----------------------------------------------------------------
    !
    !  4. Subroutines used :
    !
    !      Name                 Type    Module    Description
    !     ----------------------------------------------------------------
    !      GET_LIST_EXCH_FIELD  Subr.   W3OACPMD  List of the exchanged fields
    !     ----------------------------------------------------------------
    !
    !  5. Called by :
    !
    !      Name                Type     Module    Description
    !     ----------------------------------------------------------------
    !      WW3_SHEL            Prog.    -         Main program
    !     ----------------------------------------------------------------
    !
    !  6. Error messages :
    !  7. Remarks :
    !  8. Structure :
    !  9. Switches :
    ! 10. Source code :
    !
    !/ ------------------------------------------------------------------- /
    !
    USE w3gdatmd, ONLY: nseal,nsea, nx, ny, mapsta, mapsf, gtype, &
         & ungtype, rlgtype, clgtype, smctype
    USE w3odatmd, ONLY: naproc, iaproc
    USE w3parall, ONLY : init_get_isea
    !
    !/ ------------------------------------------------------------------- /
    !/ Parameter list
    !/
    INTEGER, INTENT(IN)                          :: ndso
    CHARACTER(LEN=1024), INTENT(IN)              :: rcv_str,snd_str
    !/
    !/ ------------------------------------------------------------------- /
    !/ Local parameters
    !/
    INTEGER                 :: ib_i,i
    INTEGER                 :: il_part_id      ! PartitionID
    INTEGER, ALLOCATABLE, DIMENSION(:)   :: ila_paral       ! Description of the local partition in the global index space
    INTEGER, DIMENSION(4)   :: ila_shape       ! Vector giving the min & max index for each dim of the fields
    INTEGER, DIMENSION(2)   :: ila_var_nodims  ! rank of fields & number of bundles (1 with OASIS3-MCT)
    INTEGER                 :: isea, jsea, ix, iy
    INTEGER                 :: nhxw, nhxe, nhys, nhyn  ! size of the halo at the western, eastern, southern, northern boundaries
    LOGICAL                 :: ll_mpi_file     ! to check if there an mpi.txt file for domain decompasition
    !/
    !/ ------------------------------------------------------------------- /
    !/ Executable part
    !/
    !
    IF (gtype .EQ. rlgtype .OR. gtype .EQ. clgtype) THEN
      !
      ! 1.1. regular and curvilinear grids
      ! ----------------------------------
      nhxw = 1 ; nhxe = nx ; nhys = 1 ; nhyn = ny
      nhxw = nhxw - 1
      nhxe = nx - nhxe
      nhys = nhys - 1
      nhyn = ny - nhyn
      !
      ALLOCATE(ila_paral(2+nseal*2))
      !
      ! * Define the partition : OASIS ORANGE partition
      ila_paral(1) = 3
      !
      ! * total number of segments of the global domain
      ila_paral(2) = nseal
      !
      DO jsea=1, nseal
        CALL init_get_isea(isea,jsea)
 
        ix = mapsf(isea,1)
        iy = mapsf(isea,2)
        ila_paral(jsea*2+1) = (iy - nhyn -1)*(nx - nhxe - nhxw) + (ix - nhxw - 1)
        ila_paral(jsea*2+2) = 1
      END DO
#ifdef W3_SMC
    ELSE IF( gtype .EQ. smctype ) THEN
      !
      ! 1.2. SMC grids
      ! ----------------------------------
      ALLOCATE(ila_paral(2+nseal))
      !
      ! * Define the partition : OASIS POINTS partition
      ila_paral(1) = 4
      !
      ! * total number of segments of the global domain
      ila_paral(2) = nseal
      !
      DO jsea=1, nseal
        ila_paral(jsea+2) = iaproc + (jsea-1)*naproc
      ENDDO
#endif
      !
    ELSE
      !
      ! 1.3. Unstructured grids
      ! ----------------------------------
      WRITE(*,*) 'TO BE VERIFIED FOR UNSTRUCTURED GRIDS'
      stop
      !
      DO jsea=1,nseal
        ila_paral(jsea*2+1) = (iaproc-1) + (jsea-1)*naproc
        ila_paral(jsea*2+2) = 1
      END DO
      !
    ENDIF
    !
    ! 2. Partition definition
    ! ----------------------------------
    CALL oasis_def_partition(il_part_id, ila_paral,il_err,nnodes)
    IF(il_err /= 0) THEN
      CALL oasis_abort(il_compid, 'CPL_OASIS_DEFINE', 'Problem during oasis_def_partition')
    ENDIF
    !
    ! 3. Coupling fields declaration
    ! ----------------------------------
    ila_shape(:) = (/1, nseal, 1, 1 /)
    !
    ila_var_nodims(1) = 2    ! rank of fields array
    ila_var_nodims(2) = 1    ! always 1 with OASIS3-MCT 2.0
    !
    CALL get_list_exch_field(ndso, rcv_fld, snd_fld, il_nb_rcv, il_nb_snd, rcv_str, snd_str)
    !
    ! 3.1 Send coupling fields
    ! ----------------------------------
    DO ib_i = 1, il_nb_snd
      CALL oasis_def_var (snd_fld(ib_i)%IL_FIELD_ID     &
           &            , snd_fld(ib_i)%CL_FIELD_NAME   &
           &            , il_part_id                    &
           &            , ila_var_nodims                &
           &            , oasis_out                     &
           &            , ila_shape                     &
           &            , oasis_real                    &
           &            , il_err )
 
      IF (il_err /= 0) THEN
        CALL oasis_abort(il_compid, 'CPL_OASIS_DEFINE', 'Problem during oasis_def_var')
      ENDIF
    ENDDO
    !
    ! 3.2 Received coupling fields
    ! ----------------------------------
    DO ib_i = 1, il_nb_rcv
      CALL oasis_def_var (rcv_fld(ib_i)%IL_FIELD_ID    &
           &            , rcv_fld(ib_i)%CL_FIELD_NAME  &
           &            , il_part_id                   &
           &            , ila_var_nodims               &
           &            , oasis_in                     &
           &            , ila_shape                    &
           &            , oasis_real                   &
           &            , il_err )
      !
      IF (il_err /= 0) THEN
        CALL oasis_abort(il_compid, 'CPL_OASIS_DEFINE', 'Problem during oasis_def_var')
      ENDIF
    ENDDO
    !
    ! 4. End of definition phase
    ! ----------------------------------
    CALL oasis_enddef(il_err)
 
    IF (il_err /= 0) THEN
      CALL oasis_abort(il_compid, 'CPL_OASIS_DEFINE', 'Problem during oasis_enddef')
    ENDIF
    !
    !/ ------------------------------------------------------------------- /
  END SUBROUTINE cpl_oasis_define
  !/ ------------------------------------------------------------------- /
  SUBROUTINE cpl_oasis_snd(ID_NB, ID_TIME, RDA_FIELD, LD_ACTION)
    !/
    !/                  +-----------------------------------+
    !/                  | WAVEWATCH III           NOAA/NCEP |
    !/                  |           A. Thevenin             |
    !/                  |                        FORTRAN 90 |
    !/                  | Last update :          April-2016 |
    !/                  +-----------------------------------+
    !/
    !/    Jul-2013 : Origination.                    ( version 4.18 )
    !/    April-2016 : Add comments (J. Pianezze)    ( version 5.07 )
    !/
    !  1. Purpose :
    !
    !     In the model time step loop, each process sends its parts of the coupling field
    !
    !  2. Method :
    !  3. Parameters :
    !
    !     Parameter list
    !     ----------------------------------------------------------------
    !     ID_NB           Int.      I       Number of the field to be send
    !     ID_TIME         Int.      I       Atmosphere time-step in seconds
    !     RDA_FIELD       Real      I       Coupling field array to be send
    !     LD_ACTION       Bool.     O       Action performed
    !     ----------------------------------------------------------------
    !
    !  4. Subroutines used :
    !  5. Called by :
    !
    !      Name                  Type    Module     Description
    !     ----------------------------------------------------------------
    !      SND_FIELDS_TO_ATMOS   Subr.   W3AGCMMD   Send fields to atmos. model
    !      SND_FIELDS_TO_OCEAN   Subr.   W3OGCMMD   Send fields to ocean model
    !      SND_FIELDS_TO_ICE     Subr.   W3IGCMMD   Send fields to ice model
    !     ----------------------------------------------------------------
    !
    !  6. Error messages :
    !  7. Remarks :
    !  8. Structure :
    !  9. Switches :
    ! 10. Source code :
    !
    !/ ------------------------------------------------------------------- /
    !/ Parameter list
    !/
    INTEGER, INTENT(IN)   :: id_nb                         ! Number of the field to be send
    INTEGER, INTENT(IN)   :: id_time                       ! Atmosphere time-step in seconds
    REAL(kind=8), dimension(:,:), INTENT(IN) :: rda_field  ! Coupling field array to be send
    LOGICAL, INTENT(OUT)  :: ld_action                     ! Action performed
    !/
    !/ ------------------------------------------------------------------- /
    !/ Local parameters
    !/
    INTEGER :: il_info                                     ! OASIS3-MCT info argument
    !/
    !/ ------------------------------------------------------------------- /
    !/ Executable part
    !/
    CALL oasis_put ( snd_fld(id_nb)%IL_FIELD_ID &
         &              , id_time                    &
         &              , rda_field                  &
         &              , il_info                    &
         &                )
 
    ld_action = il_info == oasis_sent     .OR. il_info == oasis_torest .OR.   &
         &           il_info == oasis_sentout  .OR. il_info == oasis_torestout
 
    !/ ------------------------------------------------------------------- /
  END SUBROUTINE cpl_oasis_snd
  !/ ------------------------------------------------------------------- /
  SUBROUTINE cpl_oasis_rcv(ID_NB, ID_TIME, RDA_FIELD, LD_ACTION)
    !/
    !/                  +-----------------------------------+
    !/                  | WAVEWATCH III           NOAA/NCEP |
    !/                  |           A. Thevenin             |
    !/                  |                        FORTRAN 90 |
    !/                  | Last update :          April-2016 |
    !/                  +-----------------------------------+
    !/
    !/    Jul-2013 : Origination.                    ( version 4.18 )
    !/    April-2016 : Add comments (J. Pianezze)    ( version 5.07 )
    !/
    !  1. Purpose :
    !
    !     In the model time step loop, each process receives its parts of the coupling field
    !
    !  2. Method :
    !  3. Parameters :
    !
    !     Parameter list
    !     ----------------------------------------------------------------
    !     ID_NB           Int.      I       Number of the field to be received
    !     ID_TIME         Int.      I       Ocean time-step in seconds
    !     RDA_FIELD       Real      I       Coupling field array to be received
    !     LD_ACTION       Bool.     O       Action performed
    !     ----------------------------------------------------------------
    !
    !  4. Subroutines used :
    !  5. Called by :
    !
    !      Name                  Type    Module     Description
    !     ----------------------------------------------------------------
    !      RCV_FIELDS_FROM_ATMOS   Subr.   W3AGCMMD   Receive fields from atmos. model
    !      RCV_FIELDS_FROM_OCEAN   Subr.   W3OGCMMD   Receive fields from ocean model
    !      RCV_FIELDS_FROM_ICE     Subr.   W3IGCMMD   Receive fields from ice model
    !     ----------------------------------------------------------------
    !
    !  6. Error messages :
    !  7. Remarks :
    !  8. Structure :
    !  9. Switches :
    ! 10. Source code :
    !
    !/ ------------------------------------------------------------------- /
    !/ Parameter list
    !/
    INTEGER, INTENT(IN)   :: id_nb                          ! Number of the field to be received
    INTEGER, INTENT(IN)   :: id_time                        ! Ocean time-step in seconds
    REAL(kind=8), dimension(:,:), INTENT(OUT) :: rda_field    ! Coupling field array to be received
    LOGICAL, INTENT(OUT)  :: ld_action                      ! Action performed
    !/
    !/ ------------------------------------------------------------------- /
    !/ Local parameters
    !/
    INTEGER :: il_info                                      ! OASIS3-MCT info argument
    !/
    !/ ------------------------------------------------------------------- /
    !/ Executable part
    !/
    CALL oasis_get ( rcv_fld(id_nb)%IL_FIELD_ID &
         &              , id_time                    &
         &              , rda_field                  &
         &              , il_info                    &
         &                )
    !
    ld_action = il_info == oasis_recvd   .OR. il_info == oasis_fromrest .OR.   &
         &           il_info == oasis_recvout .OR. il_info == oasis_fromrestout
    !
    !/ ------------------------------------------------------------------- /
  END SUBROUTINE cpl_oasis_rcv
  !/ ------------------------------------------------------------------- /
  SUBROUTINE cpl_oasis_finalize
    !/
    !/                  +-----------------------------------+
    !/                  | WAVEWATCH III           NOAA/NCEP |
    !/                  |           A. Thevenin             |
    !/                  |                        FORTRAN 90 |
    !/                  | Last update :          April-2016 |
    !/                  +-----------------------------------+
    !/
    !/    Jul-2013 : Origination.                    ( version 4.18 )
    !/  April-2016 : Add comments (J. Pianezze)      ( version 5.07 )
    !/
    !  1. Purpose :
    !
    !     Terminate the coupling
    !
    !  2. Method :
    !  3. Parameters :
    !  4. Subroutines used :
    !  5. Called by :
    !
    !      Name                Type     Module    Description
    !     ----------------------------------------------------------------
    !      WW3_SHEL            Prog.    -         Main program
    !     ----------------------------------------------------------------
    !
    !  6. Error messages :
    !  7. Remarks :
    !  8. Structure :
    !  9. Switches :
    ! 10. Source code :
    !
    !/ ------------------------------------------------------------------- /
    !/ Executable part
    !/
    CALL oasis_terminate(il_err)
    !
    IF (il_err /= 0) THEN
      CALL oasis_abort(il_compid, 'CPL_OASIS_FINALIZE', 'Problem during oasis_terminate')
    ENDIF
    !
    !/ ------------------------------------------------------------------- /
  END SUBROUTINE cpl_oasis_finalize
  !/ ------------------------------------------------------------------- /
  SUBROUTINE get_list_exch_field(NDSO, RCV, SND, ID_NB_RCV, ID_NB_SND, RCV_STR, SND_STR)
    !/
    !/                  +-----------------------------------+
    !/                  | WAVEWATCH III           NOAA/NCEP |
    !/                  |           A. Thevenin             |
    !/                  |           V. Garnier              |
    !/                  |           A.C. Bennis             |
    !/                  |                        FORTRAN 90 |
    !/                  | Last update :         22-Mar-2021 |
    !/                  +-----------------------------------+
    !/
    !/    Jul-2013 : Origination.                               ( version 4.18 )
    !/    Mar-2014 : J. Pianezze (LPO) : Add atmospheric fields ( version 5.07 )
    !/    Apr-2015 : M. Accensi  (LPO) : Add fields selection   ( version 5.07 )
    !/    Apr-2016 : Add comments (J. Pianezze)                 ( version 5.07 )
    !/ 22-Mar-2021 : Adds extra coupling fields                 ( version 7.13 )
    !/
    !  1. Purpose :
    !
    !     Provides the list of coupling fields
    !
    !  2. Method :
    !  3. Parameters :
    !
    !     Parameter list
    !     ----------------------------------------------------------------
    !     NDSO         Int.      I       Id. of the output file
    !     RCV          Type     I/O      Received variables
    !     SND          Type     I/O      Send variables
    !     ID_NB_RCV    Int.     I/O      Number of received variables
    !     ID_NB_SND    Int.     I/O      Number of send variables
    !     RCV_STR      Char.     I       Name of the received variables
    !     SND_STR      Char      I       Name of the send variables
    !     ----------------------------------------------------------------
    !
    !  4. Subroutines used :
    !
    !      Name                Type    Module     Description
    !     ----------------------------------------------------------------
    !      STRSPLIT            Subr.   W3SERVMD   Splits string into words
    !     ----------------------------------------------------------------
    !
    !  5. Called by :
    !
    !      Name                Type    Module     Description
    !     ----------------------------------------------------------------
    !      CPL_OASIS_DEFINE    Subr.   W3OACPMD   Partition definition
    !     ----------------------------------------------------------------
    !
    !  6. Error messages :
    !  7. Remarks :
    !  8. Structure :
    !  9. Switches :
    ! 10. Source code :
    !
    !/ ------------------------------------------------------------------- /
    !
    USE w3servmd, ONLY: strsplit
    !
    !/ ------------------------------------------------------------------- /
    !/ Parameter list
    !/
    TYPE(cpl_field), DIMENSION(IP_MAXFLD), INTENT (INOUT)   :: rcv, snd
    INTEGER, INTENT(INOUT)                                  :: id_nb_rcv, id_nb_snd
    INTEGER, INTENT(IN)                                     :: ndso
    CHARACTER(LEN=1024), INTENT(IN)                         :: rcv_str, snd_str
    !/
    !/ ------------------------------------------------------------------- /
    !/ Local parameters
    !/
    CHARACTER(LEN=100)                                      :: out_names(50), teststr
    INTEGER                                                 :: iout
    !/
    !/ ------------------------------------------------------------------- /
    !/ Executable part
    !/
    !
    ! 1. Coupling fields received by WW3
    ! ----------------------------------
    id_nb_rcv = 0
    !
    out_names(:)=''
    CALL strsplit(rcv_str,out_names)
    iout=0
    DO WHILE (len_trim(out_names(iout+1)).NE.0)
      teststr=out_names(iout+1)
      SELECT CASE(trim(teststr(1:6)))
        !
        !
        ! OCEAN MODEL VARIABLES
        !
#ifdef W3_OASOCM
      CASE('DRY')
        ! wet-drying at the middle of the cell
        id_nb_rcv=id_nb_rcv+1
        rcv(id_nb_rcv)%CL_FIELD_NAME='WW3_OWDH'
        !
        ! wet-drying at u-location
        id_nb_rcv=id_nb_rcv+1
        rcv(id_nb_rcv)%CL_FIELD_NAME='WW3_OWDU'
        !
        ! wet-drying at v-location
        id_nb_rcv=id_nb_rcv+1
        rcv(id_nb_rcv)%CL_FIELD_NAME='WW3_OWDV'
        !
      CASE('SSH')
        ! ssh : sea surface height (m)
        id_nb_rcv=id_nb_rcv+1
        rcv(id_nb_rcv)%CL_FIELD_NAME='WW3__SSH'
        !
      CASE('CUR')
        ! uz : sea surface zonal currents (m.s-1)
        id_nb_rcv=id_nb_rcv+1
        rcv(id_nb_rcv)%CL_FIELD_NAME='WW3_OSSU'
        !
        ! vz : sea surface meridional currents (m.s-1)
        id_nb_rcv=id_nb_rcv+1
        rcv(id_nb_rcv)%CL_FIELD_NAME='WW3_OSSV'
#endif
        !
 
        !
        ! ATMOSPHERE MODEL VARIABLES
        !
#ifdef W3_OASACM
      CASE('WND')
        ! U10 : 10m u-wind speed (m.s-1)
        id_nb_rcv=id_nb_rcv+1
        rcv(id_nb_rcv)%CL_FIELD_NAME='WW3__U10'
        !
        ! V10 : 10m v-wind speed (m.s-1)
        id_nb_rcv=id_nb_rcv+1
        rcv(id_nb_rcv)%CL_FIELD_NAME='WW3__V10'
        !
      CASE('TAU')
        ! UTAUA : u-momentum (m2.s-2)
        id_nb_rcv=id_nb_rcv+1
        rcv(id_nb_rcv)%CL_FIELD_NAME='WW3_UTAU'
        !
        ! V10 : v-momentum speed (m2.s-2)
        id_nb_rcv=id_nb_rcv+1
        rcv(id_nb_rcv)%CL_FIELD_NAME='WW3_VTAU'
        !
      CASE('RHO')
        ! rhoa : air density (kg.m-3)
        id_nb_rcv=id_nb_rcv+1
        rcv(id_nb_rcv)%CL_FIELD_NAME='WW3_RHOA'
#endif
        !
 
        !
        ! ICE MODEL VARIABLES
        !
#ifdef W3_OASICM
      CASE('IC1')
        ! IC1 : ice thickness (m)
        id_nb_rcv=id_nb_rcv+1
        rcv(id_nb_rcv)%CL_FIELD_NAME='WW3__IC1'
        !
      CASE('IC5')
        ! ICEF : ice floe diameters (m)
        id_nb_rcv=id_nb_rcv+1
        rcv(id_nb_rcv)%CL_FIELD_NAME='WW3__IC5'
        !
      CASE('ICE')
        ! ICE : ice concentration (n.d)
        id_nb_rcv=id_nb_rcv+1
        rcv(id_nb_rcv)%CL_FIELD_NAME='WW3__ICE'
#endif
        !
 
      CASE DEFAULT
        WRITE (ndso,1001) trim(teststr(1:6))
      END SELECT
      iout=iout+1
    END DO
    !
    ! 2. Coupling fields sent by WW3
    ! ----------------------------------
    id_nb_snd = 0
    !
    out_names(:)=''
    CALL strsplit(snd_str,out_names)
    iout=0
    DO WHILE (len_trim(out_names(iout+1)).NE.0)
      teststr=out_names(iout+1)
      SELECT CASE(trim(teststr(1:6)))
        !
        !
        ! OCEAN MODEL VARIABLES
        !
#ifdef W3_OASOCM
      CASE('OHS')
        ! Significant wave height (m)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3__OHS'
        !
      CASE('DRY')
        ! mask to manage wet-drying
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_ODRY'
        !
      CASE('T0M1')
        ! T0M1 / wave_t0m1 : mean period (s)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_T0M1'
        !
      CASE('T01')
        ! T01 / wave_t01 : mean period (s)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3__T01'
        !
      CASE('DIR')
        ! THM / wave_thm : cosinus of mean direction (n/a)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_CDIR'
        !
        ! THM / wave_thm : sinus of mean direction (n/a)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_SDIR'
        !
      CASE('THM')
        ! THM / wave_thm : mean direction (n/a)
        ! exchange the mean direction instead of cos/sin projection
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3__DIR'
        !
      CASE('BHD')
        ! BHD / wave_bhd : wave-induced Bernoulli head pressure (bhd in N.m-1)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3__BHD'
        !
      CASE('TWO')
        ! tauox / wave_tauox : x-component of the wave-ocean momentum flux (tauox in m2.s-2)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_TWOX'
        !
        ! tauoy / wave_tauoy : y-component of the wave-ocean momentum flux (tauox in m2.s-2)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_TWOY'
        !
      CASE('TOC')
        ! tauocx / wave_tauocx : x-component of the total wave-ocean momentum flux (tauocx in m2.s-2)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_TOCX'
        !
        ! tauocy / wave_tauocy : y-component of the total wave-ocean momentum flux (tauocx in m2.s-2)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_TOCY'
        !
      CASE('FOC')
        ! phioc / wave_phioc : Wave-to-ocean TKE flux (phioc in W.m-2)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3__FOC'
        !
      CASE('TBB')
        ! Momentum flux due to bottom friction, u component (m2.s-2)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_TBBX'
        !
        ! Momentum flux due to bottom friction, v component (m2.s-2)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_TBBY'
        !
      CASE('FBB')
        ! phibbl / wave_phibbl : Energy flux due to bottom friction (phioc in W.m-2)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3__FBB'
        !
      CASE('UBR')
        ! uba / wave_ubrx : x component of the rms amplitude of orbital velocity of the waves (m/s)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_UBRX'
        !
        ! uba / wave_ubry : y component of the rms amplitude of orbital velocity of the waves (m/s)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_UBRY'
        !
      CASE('TAW')
        ! tauwix / wave_tauwix : Net wave-supported stress, u component (tauwix in m2.s-2)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_TAWX'
        !
        ! tauwiy / wave_tauwiy : ! Net wave-supported stress, v component (tauwix in m2.s-2)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_TAWY'
        !
      CASE('LM')
        ! wlm / wave_wlm : mean length wave (m)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3___LM'
        !
      CASE('WNM')
        ! wnmean / wave_wnmean : mean wave number (m-1)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3__WNM'
        !
      CASE('TUS')
        ! Volume transport associated to Stokes drift, u component (m2.s-1)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_TUSX'
        !
        ! Volume transport associated to Stokes drift, v component (m2.s-1)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_TUSY'
        !
      CASE('USS')
        ! Surface Stokes drift, u component (m.s-1)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_USSX'
        !
        ! Surface Stokes drift, v component (m.s-1)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_USSY'
        !
      CASE('OCHA')
        ! Charnock Coefficient (-)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_OCHA'
#endif
 
        !
        ! ATMOSPHERE MODEL VARIABLES
        !
#ifdef W3_OASACM
      CASE('AHS')
        ! Significant wave height (m)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3__AHS'
        !
      CASE('CUR')
        ! Ocean sea surface current (m.s-1)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_WSSU'
        !
        ! Ocean sea surface current (m.s-1)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_WSSV'
        !
      CASE('ACHA')
        ! Charnock Coefficient (-)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_ACHA'
        !
      CASE('FP')
        ! Peak frequency (s-1)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3___FP'
        !
      CASE('TP')
        ! Peak period (s)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3___TP'
        !
      CASE('FWS')
        ! Wind_sea_mean_period_T0M1 (s)
        id_nb_snd=id_nb_snd+1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3__FWS'
#endif
        !
 
        !
        ! ICE MODEL VARIABLES
        !
#ifdef W3_OASICM
      CASE('IC5')
        ! Ice floe diameters (m)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_ICEF'
        !
      CASE('TWI')
        ! TWIX : x stress to ice , u component (twix in m2.s-2)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_TWIX'
        ! TWIY : y stress to ice , v component (twiy in m2.s-2)
        id_nb_snd = id_nb_snd +1
        snd(id_nb_snd)%CL_FIELD_NAME='WW3_TWIY'
#endif
        !
      CASE DEFAULT
        WRITE (ndso,1002) trim(teststr(1:6))
      END SELECT
      iout=iout+1
    END DO
    !
    ! Formats
    !
1001 FORMAT (/' *** WAVEWATCH III WARNING IN W3OACPMD : '/                       &
         '     REQUESTED COUPLING RECEIVED FIELD ',a,' WAS NOT RECOGNIZED.'/)
    !
1002 FORMAT (/' *** WAVEWATCH III WARNING IN W3OACPMD : '/                       &
         '     REQUESTED COUPLING SENT FIELD ',a,' WAS NOT RECOGNIZED.'/)
    !/
    !/ ------------------------------------------------------------------- /
  END SUBROUTINE get_list_exch_field
  !/ ------------------------------------------------------------------- /
  !/
END MODULE w3oacpmd
!/
!/ ------------------------------------------------------------------- /