w3wdatmd.F90

Go to the documentation of this file.

 
 
#include "w3macros.h"
!/ ------------------------------------------------------------------- /
MODULE w3wdatmd
  !/
  !/                  +-----------------------------------+
  !/                  | WAVEWATCH III           NOAA/NCEP |
  !/                  |           H. L. Tolman            |
  !/                  |                        FORTRAN 90 |
  !/                  | Last update :         22-Mar-2021 |
  !/                  +-----------------------------------+
  !/
  !/    22-Oct-2004 : Origination.                        ( version 3.06 )
  !/    13-Jun-2006 : Allocate VA consistent with MPI     ( version 3.09 )
  !/                  data types and initialize as needed.
  !/    05-Jul-2006 : Consolidate stress vector.          ( version 3.09 )
  !/    04-Oct-2006 : Add filter to array pointers.       ( version 3.10 )
  !/    29-May-2009 : Preparing distribution version.     ( version 3.14 )
  !/    16-May-2010 : Add iceberg damping                 ( version 3.14.4 )
  !/    14-Nov-2013 : Initialize UST and USTDIR.          ( version 4.13 )
  !/    10-Dec-2014 : Add checks for allocate status      ( version 5.04 )
  !/    06-Jun-2018 : Add PDLIB/SETUP/DEBUGINIT           ( version 6.04 )
  !/    22-Mar-2021 : Support for variable air density    ( version 7.13 )
  !/    28-Jun-2021 : GKE NL5 parameters (Q. Liu)         ( version 7.13 )
  !/
  !/    Copyright 2009-2013 National Weather Service (NWS),
  !/       National Oceanic and Atmospheric Administration.  All rights
  !/       reserved.  WAVEWATCH III is a trademark of the NWS.
  !/       No unauthorized use without permission.
  !/
  !  1. Purpose :
  !
  !     Define data structures to set up wave model dynamic data for
  !     several models simultaneously.
  !
  !  2. Variables and types :
  !
  !      Name      Type  Scope    Description
  !     ----------------------------------------------------------------
  !      NWDATA    Int.  Public   Number of models in array dim.
  !      IWDATA    Int.  Public   Selected model for output, init. at -1.
  !      WDATA     TYPE  Public   Basic data structure.
  !      WDATAS    WDATA Public   Array of data structures.
  !     ----------------------------------------------------------------
  !
  !     All elements of WDATA are aliased to pointers with the same
  !     name. These pointers are defined as :
  !
  !      Name      Type  Scope    Description
  !     ----------------------------------------------------------------
  !      TIME      I.A.  Public   Valid time for spectra.
  !      TIME00    I.A.  Public   Initial time
  !      TIMEEND   I.A.  Public   Final time
  !      QI5TBEG   I.A.  Public   Initial time for NL5 (absol. time)
  !      QR5TIM0   R.A.  Public   Previous time step t0 (relat. time)
  !      QR5CVK0   R.A.  Public   Cvk @ t0
  !      QC5INT0   C.A.  Public   Inpqr (time integral) @ t0
  !      QR5TMIX   R.A.  Public   Previous time for phase mixing
  !      TLEV      I.A.  Public   Valid time for water levels.
  !      TICE      I.A.  Public   Valid time for ice concentration
  !      TRHO      I.A.  Public   Valid time for air density
  !      TIC1      I.A.  Public   Valid time for ice thickness
  !      TIC5      I.A.  Public   Valid time for ice floe
  !      VA        R.A.  Public   Storage array for spectra.
  !      WLV       R.A.  Public   Water levels.
  !      ICE       R.A.  Public   Ice coverage.
  !      RHOAIR    R.A.  Public   Air density
  !      ICEH      R.A.  Public   Ice thickness.
  !      ICEF      R.A.  Public   Ice flow maximum diameter.
  !      ICEDMAX   R.A.  Public   Ice flow maximum diameter for updates.
  !      BERG      R.A.  Public   Iceberg damping.
  !      UST       R.A.  Public   Friction velocity (absolute).
  !      USTDIR    R.A.  Public   Friction velocity direction.
  !      ASF       R.A.  Public   Stability correction factor.
  !      FPIS      R.A.  Public   Input peak frequencies.
  !      DINIT     Log.  Public   Flag for array initialization.
  !      FL_ALL    Log.  Public   Flag for initializing all arrays,
  !                               otherwise VA is skipped.
  !     ----------------------------------------------------------------
  !
  !  3. Subroutines and functions :
  !
  !      Name      Type  Scope    Description
  !     ----------------------------------------------------------------
  !      W3NDAT    Subr. Public   Set number of grids/models.
  !      W3DIMW    Subr. Public   Set dimensions of arrays.
  !      W3SETW    Subr. Public   Point to selected grid / model.
  !     ----------------------------------------------------------------
  !
  !  4. Subroutines and functions used :
  !
  !      Name      Type  Module   Description
  !     ----------------------------------------------------------------
  !      W3SETG    Subr. W3GDATMD Point to proper model grid.
  !      STRACE    Subr. W3SERVMD Subroutine tracing.
  !      EXTCDE    Subr. W3SERVMD Abort program with exit code.
  !     ----------------------------------------------------------------
  !
  !  5. Remarks :
  !
  !     - The number of grids is taken from W3GDATMD, and needs to be
  !       set first with W3DIMG.
  !
  !  6. Switches :
  !
  !     !/S    Enable subroutine tracing.
  !     !/T    Enable test output
  !
  !  7. Source code :
  !
  !/ ------------------------------------------------------------------- /
  PUBLIC
  !/
  !/ Module private variable for checking error returns
  !/
  INTEGER, PRIVATE        :: ISTAT
  !/
  !/ Conventional declarations
  !/
  INTEGER                 :: nwdata = -1, iwdata = -1
  !/
  !/ Data structures
  !/
  TYPE wdata
    INTEGER               :: time(2), tlev(2), tice(2), trho(2),  &
         tic1(2), tic5(2)
#ifdef W3_OASIS
    INTEGER               :: time00(2)
    INTEGER               :: timeend(2)
#endif
#ifdef W3_NL5
    INTEGER               :: qi5tbeg(2)
    REAL, POINTER         :: qr5tim0(:), qr5cvk0(:, :), qr5tmix(:)
    COMPLEX, POINTER      :: qc5int0(:, :)
#endif
    REAL, POINTER         :: va(:,:), wlv(:), ice(:), rhoair(:),   &
         ust(:), ustdir(:), asf(:), fpis(:),  &
         berg(:), iceh(:), icef(:), icedmax(:)
#ifdef W3_SETUP
    REAL, POINTER :: zeta_setup(:), fx_zs(:), fy_zs(:)
    REAL, POINTER :: sxx_zs(:), sxy_zs(:), syy_zs(:)
#endif
#ifdef W3_PDLIB
    REAL, POINTER     :: vstot(:,:), vdtot(:,:)
    REAL, POINTER     :: vaold(:,:)
    LOGICAL, POINTER  :: shavetot(:)
#endif
    LOGICAL               :: dinit, fl_all
  END TYPE wdata
  !
  !/
  !/ Data storage
  !/
  TYPE(wdata), TARGET, ALLOCATABLE :: wdatas(:)
  !/
  !/ Data aliasses for structure WDATA(S)
  !/
  INTEGER, POINTER        :: time(:), tlev(:), tice(:), trho(:),  &
       tic1(:), tic5(:)
#ifdef W3_OASIS
  INTEGER, POINTER        :: time00(:)
  INTEGER, POINTER        :: timeend(:)
#endif
#ifdef W3_NL5
  INTEGER, POINTER        :: qi5tbeg(:)
  REAL, POINTER           :: qr5tim0(:), qr5cvk0(:, :), qr5tmix(:)
  COMPLEX, POINTER        :: qc5int0(:, :)
#endif
  REAL, POINTER           :: va(:,:), wlv(:), ice(:), rhoair(:),  &
       ust(:), ustdir(:), asf(:), fpis(:),  &
       berg(:), iceh(:), icef(:), icedmax(:)
#ifdef W3_SETUP
  REAL, POINTER :: zeta_setup(:), fx_zs(:), fy_zs(:)
  REAL, POINTER :: sxx_zs(:), sxy_zs(:), syy_zs(:)
#endif
#ifdef W3_PDLIB
  REAL, POINTER           :: vstot(:,:), vdtot(:,:)
  REAL, POINTER           :: vaold(:,:)
  LOGICAL, POINTER        :: shavetot(:)
#endif
  LOGICAL, POINTER        :: dinit, fl_all
  !/
CONTAINS
  !/ ------------------------------------------------------------------- /
  SUBROUTINE w3ndat ( NDSE, NDST )
    !/
    !/                  +-----------------------------------+
    !/                  | WAVEWATCH III           NOAA/NCEP |
    !/                  |           H. L. Tolman            |
    !/                  |                        FORTRAN 90 |
    !/                  | Last update :         10-Dec-2014 !
    !/                  +-----------------------------------+
    !/
    !/    31-Mar-2004 : Origination.                        ( version 3.06 )
    !/    10-Dec-2014 : Add checks for allocate status      ( version 5.04 )
    !/
    !  1. Purpose :
    !
    !     Set up the number of grids to be used.
    !
    !  2. Method :
    !
    !     Use data stored in NGRIDS in W3GDATMD.
    !
    !  3. Parameters :
    !
    !     Parameter list
    !     ----------------------------------------------------------------
    !       NDSE    Int.   I   Error output unit number.
    !       NDST    Int.   I   Test output unit number.
    !     ----------------------------------------------------------------
    !
    !  4. Subroutines used :
    !
    !     See module documentation.
    !
    !  5. Called by :
    !
    !     Any program that uses this grid structure.
    !
    !  6. Error messages :
    !
    !     - Error checks on previous setting of variable NGRIDS.
    !
    !  7. Remarks :
    !
    !  8. Structure :
    !
    !  9. Switches :
    !
    !     !/S    Enable subroutine tracing.
    !     !/T    Enable test output
    !
    ! 10. Source code :
    !
    !/ ------------------------------------------------------------------- /
    USE w3gdatmd, ONLY: ngrids
    USE w3servmd, ONLY: extcde
#ifdef W3_S
    USE w3servmd, ONLY: strace
#endif
    !
    IMPLICIT NONE
    !/
    !/ ------------------------------------------------------------------- /
    !/ Parameter list
    !/
    INTEGER, INTENT(IN)     :: NDSE, NDST
    !/
    !/ ------------------------------------------------------------------- /
    !/ Local parameters
    !/
    INTEGER                 :: I
#ifdef W3_S
    INTEGER, SAVE           :: IENT = 0
#endif
    !/
#ifdef W3_S
    CALL strace (ient, 'W3NDAT')
#endif
    !
    ! -------------------------------------------------------------------- /
    ! 1.  Test input and module status
    !
    IF ( ngrids .EQ. -1 ) THEN
      WRITE (ndse,1001) ngrids
      CALL extcde (1)
    END IF
    !
    ! -------------------------------------------------------------------- /
    ! 2.  Set variable and allocate arrays
    !
    ALLOCATE ( wdatas(0:ngrids), stat=istat )
    check_alloc_status( istat )
    nwdata = ngrids
    !
    ! -------------------------------------------------------------------- /
    ! 3.  Initialize parameters
    !
    DO i=0, ngrids
      wdatas(i)%DINIT  = .false.
      wdatas(i)%FL_ALL = .false.
    END DO
    !
#ifdef W3_T
    WRITE (ndst,9000) ngrids
#endif
    !
    RETURN
    !
    ! Formats
    !
1001 FORMAT (/' *** ERROR W3NDAT : NGRIDS NOT YET SET *** '/         &
         '                    NGRIDS = ',i10/                   &
         '                    RUN W3NMOD FIRST'/)
    !
#ifdef W3_T
9000 FORMAT (' TEST W3NDAT : SETTING UP FOR ',i4,' GRIDS')
#endif
    !/
    !/ End of W3NDAT ----------------------------------------------------- /
    !/
  END SUBROUTINE w3ndat
  !/ ------------------------------------------------------------------- /
  SUBROUTINE w3dimw  ( IMOD, NDSE, NDST, F_ONLY )
    !/
    !/                  +-----------------------------------+
    !/                  | WAVEWATCH III           NOAA/NCEP |
    !/                  |           H. L. Tolman            |
    !/                  |                        FORTRAN 90 |
    !/                  | Last update :         22-Mar-2021 !
    !/                  +-----------------------------------+
    !/
    !/    22-Oct-2004 : Origination.                        ( version 3.06 )
    !/    13-Jun-2006 : Allocate VA consistent with MPI     ( version 3.09 )
    !/                  data types and initialize as needed.
    !/    05-Jul-2006 : Consolidate stress vector.          ( version 3.09 )
    !/    04-Oct-2006 : Add filter to array pointers.       ( version 3.10 )
    !/    14-Nov-2013 : Initialize UST and USTDIR.          ( version 4.13 )
    !/    10-Dec-2014 : Add checks for allocate status      ( version 5.04 )
    !/    22-Mar-2021 : Support for variable air density    ( version 7.13 )
    !/
    !  1. Purpose :
    !
    !     Initialize an individual data grid at the proper dimensions.
    !
    !  2. Method :
    !
    !     Allocate directly into the structure array. Note that
    !     this cannot be done through the pointer alias!
    !
    !  3. Parameters :
    !
    !     Parameter list
    !     ----------------------------------------------------------------
    !       IMOD    Int.   I   Model number to point to.
    !       NDSE    Int.   I   Error output unit number.
    !       NDST    Int.   I   Test output unit number.
    !       F_ONLY  L.O.   I   FLag for initializing field arrays only.
    !     ----------------------------------------------------------------
    !
    !  4. Subroutines used :
    !
    !     See module documentation.
    !
    !  5. Called by :
    !
    !      Name      Type  Module   Description
    !     ----------------------------------------------------------------
    !      W3IOGO    Subr. W3IOGOMD Grid output IO routine.
    !      W3IORS    Subr. W3IORSMD Restart file IO routine.
    !      WW3_SHEL  Prog.   N/A    Main wave model driver.
    !      WW3_STRT  Prog.   N/A    Initial conditions program.
    !     ----------------------------------------------------------------
    !
    !  6. Error messages :
    !
    !     - Check on input parameters.
    !     - Check on previous allocation.
    !
    !  7. Remarks :
    !
    !     - W3SETW needs to be called after allocation to point to
    !       proper allocated arrays.
    !
    !  8. Structure :
    !
    !     See source code.
    !
    !  9. Switches :
    !
    !     !/S    Enable subroutine tracing.
    !     !/T    Enable test output
    !
    ! 10. Source code :
    !
    !/ ------------------------------------------------------------------- /
    USE w3gdatmd, ONLY: ngrids, igrid, w3setg, nspec, nsea, nseal, grids
    USE w3odatmd, ONLY: naproc, iaproc
    USE w3servmd, ONLY: extcde
    USE constants, ONLY : lpdlib, dair
    USE w3parall, ONLY: set_up_nseal_nsealm, lsloc
#ifdef W3_NL5
    USE w3gdatmd, ONLY: qi5nnz
#endif
#ifdef W3_PDLIB
    use yownodepool, only: npa, np
    use yowrankmodule, only : rank
    USE w3gdatmd, ONLY: gtype, ungtype
#endif
#ifdef W3_S
    USE w3servmd, ONLY: strace
#endif
    !
    IMPLICIT NONE
    !
    !/
    !/ ------------------------------------------------------------------- /
    !/ Parameter list
    !/
    INTEGER, INTENT(IN)           :: IMOD, NDSE, NDST
    LOGICAL, INTENT(IN), OPTIONAL :: F_ONLY
    !/
    !/ ------------------------------------------------------------------- /
    !/ Local parameters
    !/
    INTEGER                 :: JGRID, NSEALM, NSEATM
    INTEGER                 :: NSEAL_DUMMY, ISEA
#ifdef W3_PDLIB
    INTEGER IRANK
#endif
#ifdef W3_S
    INTEGER, SAVE           :: IENT = 0
#endif
    !/
#ifdef W3_S
    CALL strace (ient, 'W3DIMW')
#endif
 
    !
    ! -------------------------------------------------------------------- /
    ! 1.  Test input and module status
    !
    IF ( PRESENT(f_only) ) THEN
      fl_all = .NOT. f_only
    ELSE
      fl_all = .true.
    END IF
    !
    IF ( ngrids .EQ. -1 ) THEN
      WRITE (ndse,1001)
      CALL extcde (1)
    END IF
    !
    IF ( imod.LT.1 .OR. imod.GT.nwdata ) THEN
      WRITE (ndse,1002) imod, nwdata
      CALL extcde (2)
    END IF
    !
    IF ( wdatas(imod)%DINIT ) THEN
      WRITE (ndse,1003)
      CALL extcde (3)
    END IF
    !
#ifdef W3_T
    WRITE (ndst,9000) imod
#endif
    !
    jgrid  = igrid
    IF ( jgrid .NE. imod ) CALL w3setg ( imod, ndse, ndst )
    !
    ! -------------------------------------------------------------------- /
    ! 2.  Allocate arrays
    !
    CALL set_up_nseal_nsealm(nseal_dummy, nsealm)
    nseatm = nsealm * naproc
    !
    IF ( fl_all ) THEN
      ALLOCATE ( wdatas(imod)%VA(nspec,0:nsealm), stat=istat ); wdatas(imod)%VA = 0.
      check_alloc_status( istat )
#ifdef W3_PDLIB
      ALLOCATE ( wdatas(imod)%SHAVETOT(nseal), stat=istat )
#endif
#ifdef W3_PDLIB
      IF (.not. lsloc) THEN
        ALLOCATE ( wdatas(imod)%VSTOT(nspec,nseal), stat=istat )
#endif
#ifdef W3_PDLIB
        ALLOCATE ( wdatas(imod)%VDTOT(nspec,nseal), stat=istat )
#endif
#ifdef W3_PDLIB
      ENDIF ! LSLOC
      ALLOCATE ( wdatas(imod)%VAOLD(nspec,nseal), stat=istat )
#endif
#ifdef W3_PDLIB
      IF (.not. lsloc) THEN
        wdatas(imod)%VSTOT=0
#endif
#ifdef W3_PDLIB
        wdatas(imod)%VDTOT=0
#endif
#ifdef W3_PDLIB
      ENDIF ! LSLOC
      wdatas(imod)%SHAVETOT=.false.
#endif
      !
      ! * Four arrays for NL5 (QL)
      ! * AFAIK, the set up of QR5TIM0, QR5CVK0, QC5INT0 should be similar
      ! * to VA, though I am not really clear about how FL_ALL works.
      ! *
#ifdef W3_NL5
      ALLOCATE ( wdatas(imod)%QR5TIM0(0:nsealm),             &
           wdatas(imod)%QR5CVK0(nspec, 0:nsealm),      &
           wdatas(imod)%QC5INT0(qi5nnz, 0:nsealm),     &
           wdatas(imod)%QR5TMIX(0:nsealm), stat=istat)
      check_alloc_status( istat )
#endif
      !
      ! * Initialized NL5 arrays with zero (QL)
#ifdef W3_NL5
      wdatas(imod)%QR5TIM0 = 0.0
      wdatas(imod)%QR5CVK0 = 0.0
      wdatas(imod)%QC5INT0 = (0.0, 0.0)
      wdatas(imod)%QR5TMIX = 0.0
#endif
      !
#ifdef W3_NL5
      WRITE(*, *)
      WRITE(*, '(A, I4, I12)') '⊚ → [WW3 WDAT]: IMOD & QI5NNZ: ', imod, qi5nnz
      WRITE(*, *)
#endif
      !
      IF ( nseal .NE. nsealm ) THEN
        DO isea=nseal+1,nsealm
          wdatas(imod)%VA(:,isea) = 0.
          !
#ifdef W3_NL5
          wdatas(imod)%QR5TIM0(isea)   = 0.0
          wdatas(imod)%QR5CVK0(:,isea) = 0.0
          wdatas(imod)%QC5INT0(:,isea) = (0.0, 0.0)
          wdatas(imod)%QR5TMIX(isea)   = 0.0
#endif
        END DO
      END IF
    END IF
    !
    ! ICE, ICEH, ICEF must be defined from 0:NSEA
    ALLOCATE ( wdatas(imod)%WLV(nsea),                              &
         wdatas(imod)%ICE(0:nsea),                            &
         wdatas(imod)%RHOAIR(nsea),                           &
#ifdef W3_SETUP
         wdatas(imod)%ZETA_SETUP(nsea),                       &
#endif
         wdatas(imod)%BERG(nsea),                             &
         wdatas(imod)%ICEH(0:nsea),                           &
         wdatas(imod)%ICEF(0:nsea),                           &
         wdatas(imod)%ICEDMAX(nsea),                          &
         wdatas(imod)%UST(0:nseatm),                          &
         wdatas(imod)%USTDIR(0:nseatm),                       &
         wdatas(imod)%ASF(nseatm),                            &
         wdatas(imod)%FPIS(nseatm), stat=istat                )
    check_alloc_status( istat )
 
    wdatas(imod)%WLV   (:) = 0.
    wdatas(imod)%ICE   (0:nsea) = 0.
    wdatas(imod)%RHOAIR(:) = dair
#ifdef W3_SETUP
    wdatas(imod)%ZETA_SETUP(:) = 0.
#endif
    wdatas(imod)%BERG  (:) = 0.
    wdatas(imod)%ICEH  (0:nsea) = grids(imod)%IICEHINIT
    wdatas(imod)%ICEF  (0:nsea) = 1000.
    wdatas(imod)%ICEDMAX(:) = 1000.
    wdatas(imod)%UST   (0:nseatm) = 1.e-5
    wdatas(imod)%USTDIR(0:nseatm) = 0.
    wdatas(imod)%ASF   (:) = 0.
    wdatas(imod)%FPIS  (:) = 0.
    wdatas(imod)%DINIT     = .true.
    CALL w3setw ( imod, ndse, ndst )
    !
#ifdef W3_T
    WRITE (ndst,9003)
#endif
    !
    ! -------------------------------------------------------------------- /
    ! 5.  Restore previous grid setting if necessary
    !
    IF ( jgrid .NE. imod ) CALL w3setg ( jgrid, ndse, ndst )
    !
    RETURN
    !
    ! Formats
    !
1001 FORMAT (/' *** ERROR W3DIMW : GRIDS NOT INITIALIZED *** '/      &
         '                    RUN W3NMOD FIRST '/)
1002 FORMAT (/' *** ERROR W3DIMW : ILLEGAL MODEL NUMBER *** '/       &
         '                    IMOD   = ',i10/                   &
         '                    NWDATA = ',i10/)
1003 FORMAT (/' *** ERROR W3DIMW : ARRAY(S) ALREADY ALLOCATED *** ')
    !
#ifdef W3_T
9000 FORMAT (' TEST W3DIMW : MODEL ',i4,' DIM. AT ',2i5,i7)
#endif
    !
#ifdef W3_T
    WRITE (ndst,9001)
#endif
    !
    ! -------------------------------------------------------------------- /
    ! 3.  Point to allocated arrays
    !
    CALL w3setw ( imod, ndse, ndst )
    !
#ifdef W3_T
    WRITE (ndst,9002)
#endif
    !
    ! -------------------------------------------------------------------- /
    ! 4.  Update counters in grid
#ifdef W3_T
9001 FORMAT (' TEST W3DIMW : ARRAYS ALLOCATED')
9002 FORMAT (' TEST W3DIMW : POINTERS RESET')
9003 FORMAT (' TEST W3DIMW : DIMENSIONS STORED')
#endif
    !/
    !/ End of W3DIMW ----------------------------------------------------- /
    !/
  END SUBROUTINE w3dimw
  !/ ------------------------------------------------------------------- /
  SUBROUTINE w3setw ( IMOD, NDSE, NDST )
    !/
    !/                  +-----------------------------------+
    !/                  | WAVEWATCH III           NOAA/NCEP |
    !/                  |           H. L. Tolman            |
    !/                  |                        FORTRAN 90 |
    !/                  | Last update :         22-Mar-2021 !
    !/                  +-----------------------------------+
    !/
    !/    31-Mar-2004 : Origination.                        ( version 3.06 )
    !/    05-Jul-2006 : Consolidate stress vector.          ( version 3.09 )
    !/    04-Oct-2006 : Add filter to array pointers.       ( version 3.10 )
    !/    22-Mar-2021 : Support for variable air density    ( version 7.13 )
    !/
    !  1. Purpose :
    !
    !     Select one of the WAVEWATCH III grids / models.
    !
    !  2. Method :
    !
    !     Point pointers to the proper variables in the proper element of
    !     the GRIDS array.
    !
    !  3. Parameters :
    !
    !     Parameter list
    !     ----------------------------------------------------------------
    !       IMOD    Int.   I   Model number to point to.
    !       NDSE    Int.   I   Error output unit number.
    !       NDST    Int.   I   Test output unit number.
    !     ----------------------------------------------------------------
    !
    !  4. Subroutines used :
    !
    !     See module documentation.
    !
    !  5. Called by :
    !
    !     Many subroutines in the WAVEWATCH system.
    !
    !  6. Error messages :
    !
    !     Checks on parameter list IMOD.
    !
    !  7. Remarks :
    !
    !  8. Structure :
    !
    !  9. Switches :
    !
    !     !/S    Enable subroutine tracing.
    !     !/T    Enable test output
    !
    ! 10. Source code :
    !
    !/ ------------------------------------------------------------------- /
    USE w3servmd, ONLY: extcde
#ifdef W3_S
    USE w3servmd, ONLY: strace
#endif
    !
    IMPLICIT NONE
    !/
    !/ ------------------------------------------------------------------- /
    !/ Parameter list
    !/
    INTEGER, INTENT(IN)     :: IMOD, NDSE, NDST
    !/
    !/ ------------------------------------------------------------------- /
    !/ Local parameters
    !/
#ifdef W3_S
    INTEGER, SAVE           :: IENT = 0
#endif
    !/
#ifdef W3_S
    CALL strace (ient, 'W3SETW')
#endif
    !
    ! -------------------------------------------------------------------- /
    ! 1.  Test input and module status
    !
    IF ( nwdata .EQ. -1 ) THEN
      WRITE (ndse,1001)
      CALL extcde (1)
    END IF
    !
    IF ( imod.LT.0 .OR. imod.GT.nwdata ) THEN
      WRITE (ndse,1002) imod, nwdata
      CALL extcde (2)
    END IF
    !
#ifdef W3_T
    WRITE (ndst,9000) imod
#endif
    !
    ! -------------------------------------------------------------------- /
    ! 2.  Set model numbers
    !
    iwdata = imod
    !
    ! -------------------------------------------------------------------- /
    ! 3.  Set pointers
    !
    time   => wdatas(imod)%TIME
#ifdef W3_OASIS
    time00 => wdatas(imod)%TIME00
    timeend => wdatas(imod)%TIMEEND
#endif
#ifdef W3_NL5
    qi5tbeg => wdatas(imod)%QI5TBEG
#endif
    tlev   => wdatas(imod)%TLEV
    tice   => wdatas(imod)%TICE
    trho   => wdatas(imod)%TRHO
    tic1   => wdatas(imod)%TIC1
    tic5   => wdatas(imod)%TIC5
    dinit  => wdatas(imod)%DINIT
    fl_all => wdatas(imod)%FL_ALL
    !
    IF ( dinit ) THEN
      IF ( fl_all ) THEN
        va     => wdatas(imod)%VA
#ifdef W3_NL5
        qr5tim0 => wdatas(imod)%QR5TIM0
        qr5cvk0 => wdatas(imod)%QR5CVK0
        qc5int0 => wdatas(imod)%QC5INT0
        qr5tmix => wdatas(imod)%QR5TMIX
#endif
#ifdef W3_PDLIB
        shavetot     => wdatas(imod)%SHAVETOT
        vstot     => wdatas(imod)%VSTOT
        vdtot     => wdatas(imod)%VDTOT
        vaold     => wdatas(imod)%VAOLD
#endif
      END IF
      wlv    => wdatas(imod)%WLV
      ice    => wdatas(imod)%ICE
      rhoair => wdatas(imod)%RHOAIR
#ifdef W3_SETUP
      zeta_setup => wdatas(imod)%ZETA_SETUP
      fx_zs => wdatas(imod)%FX_zs
      fy_zs => wdatas(imod)%FY_zs
      sxx_zs => wdatas(imod)%SXX_zs
      sxy_zs => wdatas(imod)%SXY_zs
      syy_zs => wdatas(imod)%SYY_zs
#endif
      berg   => wdatas(imod)%BERG
      iceh   => wdatas(imod)%ICEH
      icef   => wdatas(imod)%ICEF
      icedmax=> wdatas(imod)%ICEDMAX
      ust    => wdatas(imod)%UST
      ustdir => wdatas(imod)%USTDIR
      asf    => wdatas(imod)%ASF
      fpis   => wdatas(imod)%FPIS
    END IF
    !
    RETURN
    !
    ! Formats
    !
1001 FORMAT (/' *** ERROR W3SETW : GRIDS NOT INITIALIZED *** '/      &
         '                    RUN W3NMOD FIRST '/)
1002 FORMAT (/' *** ERROR W3SETW : ILLEGAL MODEL NUMBER *** '/       &
         '                    IMOD   = ',i10/                   &
         '                    NWDATA = ',i10/)
    !
#ifdef W3_T
9000 FORMAT (' TEST W3SETW : MODEL ',i4,' SELECTED')
#endif
    !/
    !/ End of W3SETW ----------------------------------------------------- /
    !/
  END SUBROUTINE w3setw
  !/
  !/ End of module W3WDATMD -------------------------------------------- /
  !/
END MODULE w3wdatmd