wmunitmd.F90

Go to the documentation of this file.

 
 
#include "w3macros.h"
!/ ------------------------------------------------------------------- /
 
MODULE wmunitmd
  !/
  !/                  +-----------------------------------+
  !/                  | WAVEWATCH III           NOAA/NCEP |
  !/                  |           H. L. Tolman            |
  !/                  |                        FORTRAN 90 |
  !/                  | Last update :         29-May-2009 |
  !/                  +-----------------------------------+
  !/
  !/    29-Mar-2005 : Origination.                        ( version 3.07 )
  !/    29-May-2009 : Preparing distribution version.     ( version 3.14 )
  !/
  !/    Copyright 2009 National Weather Service (NWS),
  !/       National Oceanic and Atmospheric Administration.  All rights
  !/       reserved.  WAVEWATCH III is a trademark of the NWS.
  !/       No unauthorized use without permission.
  !/
  !  1. Purpose :
  !
  !     Dynamic assignement of unit numbers for the multi-grid wave
  !     model.
  !
  !     Allowed range of unit numbers is set in parameter statements.
  !
  !  2. Variables and types :
  !
  !      Name      Type  Scope    Description
  !     ----------------------------------------------------------------
  !      UNITLW    I.P.  Private  Lowest unit number.
  !      UNITHG    I.P.  Private  Highest unit number.
  !      INPLOW, INPHGH, OUTLOW, OUTHGH, SCRLOW, SCRHGH
  !                I.P.  Private  Low and high for input, output and
  !                               scratch files.
  !      FLINIT    Log.  Private  Flag for intialization.
  !
  !      U_USED    L.A.  Private  Flag for use/assignement.
  !      U_TYPE    C.A.  Private  Type of unit.
  !                                'RES' : Reserved.
  !                                'INP' : Input file.
  !                                'OUT' : Output file.
  !                                'SCR' : Scratch file.
  !      U_NAME    C.A.  Private  File name of unit.
  !      U_DESC    C.A.  Private  Decription of file.
  !     ----------------------------------------------------------------
  !
  !  3. Subroutines and functions :
  !
  !      Name      Type  Scope    Description
  !     ----------------------------------------------------------------
  !      WMUINI    Subr. Public   Initialize data structures.
  !      WMUDMP    Subr. Public   Dump contents of data structures.
  !      WMUSET    Subr. Public   Put data directly in structure.
  !      WMUGET    Subr. Public   Get a unit number.
  !      WMUINQ    Subr. Public   Update ansilary info automatically.
  !     ----------------------------------------------------------------
  !
  !  4. Subroutines and functions used :
  !
  !      Name      Type  Module   Description
  !     ----------------------------------------------------------------
  !      STRACE    Subr. W3SERVMD Subroutine tracing.
  !      EXTCDE    Subr.   Id.    Program abort.
  !     ----------------------------------------------------------------
  !
  !  5. Remarks :
  !
  !     - All parameters are private. Dump data using WMUDMP routine.
  !
  !  6. Switches :
  !
  !     !/S    Enable subroutine tracing.
  !     !/T    Enable test output
  !
  !  7. Source code :
  !
  !/ ------------------------------------------------------------------- /
  PUBLIC
  !/
  !/ Define acceptable ranges of unit numbers
  !/
  INTEGER, PARAMETER, PRIVATE   :: UNITLW =   1
  INTEGER, PARAMETER, PRIVATE   :: UNITHG = 120
  INTEGER, PARAMETER, PRIVATE   :: INPLOW =  10
  INTEGER, PARAMETER, PRIVATE   :: INPHGH =  49
  INTEGER, PARAMETER, PRIVATE   :: OUTLOW =  50
  INTEGER, PARAMETER, PRIVATE   :: OUTHGH =  98
  INTEGER, PARAMETER, PRIVATE   :: SCRLOW =  99
  INTEGER, PARAMETER, PRIVATE   :: SCRHGH = 100
  !
  LOGICAL,            PRIVATE   :: FLINIT = .false.      
 
  LOGICAL,            PRIVATE, ALLOCATABLE :: U_USED(:)
  CHARACTER(LEN= 3),  PRIVATE, ALLOCATABLE :: U_TYPE(:)
  CHARACTER(LEN=30),  PRIVATE, ALLOCATABLE :: U_NAME(:)
  CHARACTER(LEN=30),  PRIVATE, ALLOCATABLE :: U_DESC(:)
  !/
CONTAINS
  !/ ------------------------------------------------------------------- /
  SUBROUTINE wmuini ( NDSE, NDST )
    !/
    !/                  +-----------------------------------+
    !/                  | WAVEWATCH III           NOAA/NCEP |
    !/                  |           H. L. Tolman            |
    !/                  |                        FORTRAN 90 |
    !/                  | Last update :         25-Mar-2005 !
    !/                  +-----------------------------------+
    !/
    !/    25-Mar-2005 : Origination.                        ( version 3.07 )
    !/
    !  1. Purpose :
    !
    !     Allocate and initialize arrays of module.
    !
    !  2. Method :
    !
    !     Allocate and test parameter setting.
    !
    !  3. Parameters :
    !
    !     Parameter list
    !     ----------------------------------------------------------------
    !       NDSE    Int.   I   Unit number for error output.
    !       NDST    Int.   I   Unit number for test output.
    !     ----------------------------------------------------------------
    !
    !  4. Subroutines used :
    !
    !      Name      Type  Module   Description
    !     ----------------------------------------------------------------
    !      STRACE    Subr. W3SERVMD Subroutine tracing.
    !      EXTCDE    Subr.   Id.    Program abort.
    !     ----------------------------------------------------------------
    !
    !  5. Called by :
    !
    !  6. Error messages :
    !
    !     See source code.
    !
    !  7. Remarks :
    !
    !  8. Structure :
    !
    !     See source code.
    !
    !  9. Switches :
    !
    !     !/S    Enable subroutine tracing.
    !     !/T    Enable test output
    !
    ! 10. Source code :
    !
    !/ ------------------------------------------------------------------- /
    USE w3servmd, ONLY: extcde
#ifdef W3_S
    USE w3servmd, ONLY: strace
#endif
    !
    IMPLICIT NONE
    !/
    !/ ------------------------------------------------------------------- /
    !/ Parameter list
    !/
    INTEGER, INTENT(IN)     :: NDSE, NDST
    !/
    !/ ------------------------------------------------------------------- /
    !/ Local parameters
    !/
    INTEGER                 :: J, I1, IN, I
#ifdef W3_S
    INTEGER, SAVE           :: IENT = 0
#endif
    CHARACTER(LEN=3)        :: STRING
    !/
#ifdef W3_S
    CALL strace (ient, 'WMUINI')
#endif
    !
    ! -------------------------------------------------------------------- /
    ! 1.  Test parameter settings
    !
#ifdef W3_T
    WRITE (ndst,9000)
#endif
    !
    IF ( unitlw .GE. unithg ) THEN
      WRITE (ndse,1000) unitlw, unithg
      CALL extcde ( 1000 )
    END IF
    !
    IF ( unitlw .GT. inplow .OR.                                    &
         unitlw .GT. outlow .OR.                                    &
         unitlw .GT. scrlow ) THEN
      WRITE (ndse,1001) unitlw, inplow, outlow, scrlow
      CALL extcde ( 1001 )
    END IF
    !
    IF ( unithg .LT. inphgh .OR.                                    &
         unithg .LT. outhgh .OR.                                    &
         unithg .LT. scrhgh ) THEN
      WRITE (ndse,1002) unithg, inphgh, outhgh, scrhgh
      CALL extcde ( 1002 )
    END IF
    !
    IF ( flinit ) THEN
      WRITE (ndse,1003)
      CALL extcde ( 1003 )
    END IF
    !
    ! -------------------------------------------------------------------- /
    ! 1.  Allocate and initialize arrays
    !
#ifdef W3_T
    WRITE (ndst,9010) unitlw, unithg
#endif
    !
    ALLOCATE ( u_used(unitlw:unithg) , u_type(unitlw:unithg) ,      &
         u_name(unitlw:unithg) , u_desc(unitlw:unithg) )
    !
    u_used = .false.
    u_type = 'RES'
    u_name = 'unknown'
    u_desc = 'unknown'
    !
    ! -------------------------------------------------------------------- /
    ! 2.  Designate file types
    !
#ifdef W3_T
    WRITE (ndst,9020)
#endif
    !
    DO j=1, 3
      !
      SELECT CASE(j)
      CASE(1)
        string = 'INP'
        i1     = inplow
        in     = inphgh
      CASE(2)
        string = 'OUT'
        i1     = outlow
        in     = outhgh
      CASE DEFAULT
        string = 'SCR'
        i1     = scrlow
        in     = scrhgh
      END SELECT
      !
      DO i=i1, in
        IF ( u_type(i) .NE. 'RES' ) THEN
          WRITE (ndse,1020) i, u_type(i)
        END IF
        u_type(i) = string
      END DO
    END DO
    !
    ! -------------------------------------------------------------------- /
    ! 3.  Set flags
    !
#ifdef W3_T
    WRITE (ndst,9030)
#endif
    !
    flinit = .true.
    !
    ! -------------------------------------------------------------------- /
    ! 4.  Test output
    !
#ifdef W3_T
    WRITE (ndst,9040)
    DO i=unitlw, unithg
      WRITE (ndst,9041) i,u_used(i),u_type(i),u_name(i),u_desc(i)
    END DO
#endif
    !
    RETURN
    !
    ! Formats
    !
1000 FORMAT (/' *** ERROR WMUINI: ILLEGAL UNIT RANGE ***'/           &
         '                   LOW - HIGH : ',2i10/)
1001 FORMAT (/' *** ERROR WMUINI: ILLEGAL LOWER LIMITS ***'/         &
         '                   ',4i10/)
1002 FORMAT (/' *** ERROR WMUINI: ILLEGAL HIGHER LIMITS ***'/        &
         '                   ',4i10/)
1003 FORMAT (/' *** ERROR WMUINI: DATA ALREADY INITIALIZED ***'/)
1020 FORMAT (/' *** WARNING WMUINI: UNIT',i4,' ALREADY ASSIGNED [',  &
         a,'] ***')
    !
#ifdef W3_T
9000 FORMAT ( ' TEST WMUNINI: STARTING ROUTINE')
9010 FORMAT ( ' TEST WMUNINI: ALLOCATING ARRAYS ',2i6)
9020 FORMAT ( ' TEST WMUNINI: INITALIZING ARRAYS')
9030 FORMAT ( ' TEST WMUNINI: SETTING FLAGS')
9040 FORMAT ( ' TEST WMUNINI: DATA STRUCTURE AFTER INITIALIZATION')
9041 FORMAT ( 5x,i4,l4,3(2x,a))
#endif
    !/
    !/ End of WMUINI ----------------------------------------------------- /
    !/
  END SUBROUTINE wmuini
  !/ ------------------------------------------------------------------- /
 
  SUBROUTINE wmudmp ( NDS, IREQ )
    !/
    !/                  +-----------------------------------+
    !/                  | WAVEWATCH III           NOAA/NCEP |
    !/                  |           H. L. Tolman            |
    !/                  |                        FORTRAN 90 |
    !/                  | Last update :         25-Mar-2005 !
    !/                  +-----------------------------------+
    !/
    !/    25-Mar-2005 : Origination.                        ( version 3.07 )
    !/
    !  1. Purpose :
    !
    !     Display assigned unit number information from private data base.
    !
    !  2. Method :
    !
    !  3. Parameters :
    !
    !     Parameter list
    !     ----------------------------------------------------------------
    !       NDS     Int.   I   Unit number for output.
    !       IREQ    Int.   I   Request identifier.
    !                           < 0 : Dump all data.
    !                            0  : Dump assigned units only.
    !                           > 0 : Dump this unit only.
    !     ----------------------------------------------------------------
    !
    !  4. Subroutines used :
    !
    !      Name      Type  Module   Description
    !     ----------------------------------------------------------------
    !      STRACE    Subr. W3SERVMD Subroutine tracing.
    !      EXTCDE    Subr.   Id.    Program abort.
    !     ----------------------------------------------------------------
    !
    !  5. Called by :
    !
    !  6. Error messages :
    !
    !  7. Remarks :
    !
    !  8. Structure :
    !
    !  9. Switches :
    !
    !     !/S    Enable subroutine tracing.
    !     !/T    Enable test output
    !
    ! 10. Source code :
    !
    !/ ------------------------------------------------------------------- /
    USE w3servmd, ONLY: extcde
#ifdef W3_S
    USE w3servmd, ONLY: strace
#endif
    !
    IMPLICIT NONE
    !/
    !/ ------------------------------------------------------------------- /
    !/ Parameter list
    !/
    INTEGER, INTENT(IN)     :: NDS, IREQ
    !/
    !/ ------------------------------------------------------------------- /
    !/ Local parameters
    !/
    INTEGER                 :: I
#ifdef W3_S
    INTEGER, SAVE           :: IENT = 0
#endif
    !/
#ifdef W3_S
    CALL strace (ient, 'WMUDMP')
#endif
    !
    ! -------------------------------------------------------------------- /
    ! 1.  Test request and intialization
    !
    IF ( .NOT. flinit ) THEN
      WRITE (nds,1000)
      CALL extcde ( 1000 )
    END IF
    !
    IF ( ireq.GT.0 .AND. ( ireq.LT.unitlw .OR. ireq.GT.unithg) ) THEN
      WRITE (nds,1001) ireq, unitlw, unithg
      CALL extcde ( 1001 )
    END IF
    !
    ! -------------------------------------------------------------------- /
    ! 2.  Single unit request
    !
    IF ( ireq .GT. 0 ) THEN
      WRITE (nds,920) ireq, u_used(ireq), u_type(ireq),           &
           u_name(ireq), u_desc(ireq)
      !
      ! -------------------------------------------------------------------- /
      ! 3.  Multiple unit request
      !
    ELSE
      !
      IF ( ireq .LT. 0 ) THEN
        WRITE (nds,930)
      ELSE
        WRITE (nds,931)
      END IF
      !
      DO i=unitlw, unithg
        IF ( ireq.LT.0 .OR. u_used(i) )                           &
             WRITE (nds,932) i, u_used(i), u_type(i),         &
             u_name(i), u_desc(i)
      END DO
      WRITE (nds,*)
      !
    END IF
    !
    RETURN
    !
    ! Formats
    !
920 FORMAT (/' WMUDMP: Unit number : ',i6/                          &
         '         Assigned    : ',l6/                          &
         '         Type        : ',a/                           &
         '         Name        : ',a/                           &
         '         Description : ',a/)
    !
930 FORMAT (/' WMUDMP: Unit information '//                         &
         '    Nr Flg Type  Name                  Description '/ &
         '  -------------------------------------------------', &
         '---------------------')
931 FORMAT (/' WMUDMP: Unit information (assigned only)'//          &
         '    Nr Flg Type  Name                  Description '/ &
         '  -------------------------------------------------', &
         '---------------------')
932 FORMAT ( 2x,i4,l4,2x,a3,2x,a20,2x,a)
    !
1000 FORMAT (/' *** ERROR WMUDMP: DATA STRUCTURE READY ***'/         &
         /'                   RUN WMUINI FIRST '/)
1001 FORMAT (/' *** ERROR WMUDMP: UNIT NUMBER OUT OF RANGE ***'      &
         /'                   REQ/RANG :',3i6/)
    !/
    !/ End of WMUDMP ----------------------------------------------------- /
    !/
  END SUBROUTINE wmudmp
  !/ ------------------------------------------------------------------- /
  SUBROUTINE wmuset ( NDSE, NDST, NDS, FLAG, TYPE, NAME, DESC )
    !/
    !/                  +-----------------------------------+
    !/                  | WAVEWATCH III           NOAA/NCEP |
    !/                  |           H. L. Tolman            |
    !/                  |                        FORTRAN 90 |
    !/                  | Last update :         25-Mar-2005 !
    !/                  +-----------------------------------+
    !/
    !/    25-Mar-2005 : Origination.                        ( version 3.07 )
    !/
    !  1. Purpose :
    !
    !     Directly set information for a unit number in the data structure.
    !
    !  2. Method :
    !
    !  3. Parameters :
    !
    !     Parameter list
    !     ----------------------------------------------------------------
    !       NDSE    Int.   I   Unit number for error output.
    !       NDST    Int.   I   Unit number for test output.
    !       NDS     Int.   I   Unit number to be assigned.
    !       FLAG    Log.   I   Flag for assigning unit.
    !       TYPE    C*3    I   Type identifier to be used.
    !       NAME    C*     I   Name of file.
    !       DESC    C*     I   Description of file.
    !     ----------------------------------------------------------------
    !
    !  4. Subroutines used :
    !
    !      Name      Type  Module   Description
    !     ----------------------------------------------------------------
    !      STRACE    Sur.  W3SERVMD Subroutine tracing.
    !      EXCTDE    Sur.    Id.    Program abort.
    !     ----------------------------------------------------------------
    !
    !  5. Called by :
    !
    !  6. Error messages :
    !
    !  7. Remarks :
    !
    !  8. Structure :
    !
    !  9. Switches :
    !
    !     !/S    Enable subroutine tracing.
    !     !/T    Enable test output
    !
    ! 10. Source code :
    !
    !/ ------------------------------------------------------------------- /
    USE w3servmd, ONLY: extcde
#ifdef W3_S
    USE w3servmd, ONLY: strace
#endif
    !
    IMPLICIT NONE
    !/
    !/ ------------------------------------------------------------------- /
    !/ Parameter list
    !/
    INTEGER, INTENT(IN)     :: NDSE, NDST, NDS
    LOGICAL, INTENT(IN)     :: FLAG
    CHARACTER(LEN=3), INTENT(IN), OPTIONAL ::                       &
         TYPE
    CHARACTER*(*), INTENT(IN), OPTIONAL ::                          &
         NAME, DESC
    !/
    !/ ------------------------------------------------------------------- /
    !/ Local parameters
    !/
#ifdef W3_S
    INTEGER, SAVE           :: IENT = 0
#endif
    !/
#ifdef W3_S
    CALL strace (ient, 'WMUSET')
#endif
    !
    ! -------------------------------------------------------------------- /
    ! 1.  Test input
    !
    IF ( .NOT. flinit ) THEN
      WRITE (ndse,1000)
      CALL extcde ( 1000 )
    END IF
    !
    IF ( nds.LT.unitlw .OR. nds.GT.unithg ) THEN
      WRITE (ndse,1001) nds, unitlw, unithg
      CALL extcde ( 1001 )
    END IF
    !
#ifdef W3_T
    WRITE (ndst,9000) nds, u_used(nds), u_type(nds),             &
         u_name(nds), u_desc(nds)
#endif
    !
    ! -------------------------------------------------------------------- /
    ! 2.  Set data
    ! 2.a Flag
    !
    u_used(nds) = flag
    !
    ! 2.b Type
    !
    IF ( PRESENT(type) ) u_type(nds) = TYPE
    !
    ! 2.c Name
    !
    IF ( PRESENT(name) ) THEN
      u_name(nds) = name
    ELSE IF ( .NOT. flag ) THEN
      u_name(nds) = 'unknown'
    END IF
    !
    ! 2.d Description
    !
    IF ( PRESENT(desc) ) THEN
      u_desc(nds) = desc
    ELSE IF ( .NOT. flag ) THEN
      u_desc(nds) = 'unknown'
    END IF
    !
#ifdef W3_T
    WRITE (ndst,9001) nds, u_used(nds), u_type(nds),             &
         u_name(nds), u_desc(nds)
#endif
    !
    RETURN
    !
    ! Formats
    !
1000 FORMAT (/' *** ERROR WMUSET: INITIALIZE FIRST !!! ***')
1001 FORMAT (/' *** ERROR WMUSET: UNIT NUMBER OUT OF RANGE ***'      &
         /'                   REQ/RANG :',3i6/)
    !
#ifdef W3_T
9000 FORMAT ( ' TEST WMUSET: UNIT ',i4', ON SUBROUTINE ENTRY :'/  &
         '              FLAG : ',l4/                         &
         '              TYPE : ',a/                          &
         '              NAME : ',a/                          &
         '              DESC : ' a)
9001 FORMAT ( ' TEST WMUSET: UNIT ',i4', ON SUBROUTINE EXIT :'/   &
         '              FLAG : ',l4/                         &
         '              TYPE : ',a/                          &
         '              NAME : ',a/                          &
         '              DESC : ' a)
#endif
    !/
    !/ End of WMUSET ----------------------------------------------------- /
    !/
  END SUBROUTINE wmuset
  !/ ------------------------------------------------------------------- /
  SUBROUTINE wmuget ( NDSE, NDST, NDS, TYPE, NR )
    !/
    !/                  +-----------------------------------+
    !/                  | WAVEWATCH III           NOAA/NCEP |
    !/                  |           H. L. Tolman            |
    !/                  |                        FORTRAN 90 |
    !/                  | Last update :         20-Jan-2017 !
    !/                  +-----------------------------------+
    !/
    !/    28-Mar-2005 : Origination.                        ( version 3.07 )
    !/    20-Jan-2017 : Add INQUIRE OPENED check.           ( version 6.02 )
    !/                  (T. J. Campbell, NRL)
    !/
    !  1. Purpose :
    !
    !     Find a free unit number for a given file type.
    !
    !  2. Method :
    !
    !     Search the data base.
    !
    !  3. Parameters :
    !
    !     Parameter list
    !     ----------------------------------------------------------------
    !       NDSE    Int.   I   Unit number for error output.
    !       NDST    Int.   I   Unit number for test output.
    !       NDS     Int.   O   Unit number to be assigned.
    !       TYPE    C*3    I   Type identifier to be used.
    !       NR      Int.   I   Number of consecutive units needed.
    !                          Needed for output bounday data files.
    !     ----------------------------------------------------------------
    !
    !  4. Subroutines used :
    !
    !      Name      Type  Module   Description
    !     ----------------------------------------------------------------
    !      STRACE    Sur.  W3SERVMD Subroutine tracing.
    !      EXCTDE    Sur.    Id.    Program abort.
    !     ----------------------------------------------------------------
    !
    !  5. Called by :
    !
    !  6. Error messages :
    !
    !  7. Remarks :
    !
    !  8. Structure :
    !
    !  9. Switches :
    !
    !     !/S    Enable subroutine tracing.
    !     !/T    Enable test output
    !
    ! 10. Source code :
    !
    !/ ------------------------------------------------------------------- /
    USE w3servmd, ONLY: extcde
#ifdef W3_S
    USE w3servmd, ONLY: strace
#endif
    !
    IMPLICIT NONE
    !/
    !/ ------------------------------------------------------------------- /
    !/ Parameter list
    !/
    INTEGER, INTENT(IN)           :: NDSE, NDST
    INTEGER, INTENT(OUT)          :: NDS
    CHARACTER(LEN=3), INTENT(IN)  :: TYPE
    INTEGER, INTENT(IN), OPTIONAL :: NR
    !/
    !/ ------------------------------------------------------------------- /
    !/ Local parameters
    !/
    INTEGER                 :: NRC, I, J
#ifdef W3_S
    INTEGER, SAVE           :: IENT = 0
#endif
    LOGICAL                 :: OK
    LOGICAL                 :: OPND
    !/
#ifdef W3_S
    CALL strace (ient, 'WMUGET')
#endif
    !
    ! -------------------------------------------------------------------- /
    ! 1.  Test input / output
    !
    IF ( .NOT. flinit ) THEN
      WRITE (ndse,1010)
      CALL extcde ( 1010 )
    END IF
    !
    IF ( PRESENT(nr) ) THEN
      nrc    = max( 1 , nr )
    ELSE
      nrc    = 1
    END IF
    !
#ifdef W3_T
    WRITE (ndst,9010) TYPE, nrc
#endif
    !
    ! -------------------------------------------------------------------- /
    ! 2.  Find first free unit number and reset flag
    !
    nds    = -1
    !
    DO i=unitlw, unithg - nrc + 1
      ! new: We do not allow I=NDST (unit number for test output).
      !      NDST (aka MDST or IDST) is set to 10 in call to WMINIT
      !      (4th argument)
      ok     = .NOT.u_used(i) .AND. u_type(i).EQ.TYPE  &
           .AND. i.NE.ndst
      INQUIRE ( i, opened=opnd )
      ok     = ok .AND. .NOT.opnd
      IF ( ok ) THEN
        DO j=1, nrc-1
          ok     = ok .AND. (.NOT.u_used(i+j) .AND.               &
               u_type(i+j).EQ.TYPE )
          INQUIRE ( i+j, opened=opnd )
          ok     = ok .AND. .NOT.opnd
        END DO
      END IF
      IF ( ok ) THEN
        nds       = i
        DO j=0, nrc-1
          u_used(i+j) = .true.
        END DO
        EXIT
      END IF
    END DO
    !
    IF ( nds .EQ. -1 ) THEN
      WRITE (ndse,1020) TYPE
      CALL extcde ( 1020 )
    END IF
    !
#ifdef W3_T
    WRITE (ndst,9020) nds
#endif
    !
    RETURN
    !
    ! Formats
    !
1010 FORMAT (/' *** ERROR WMUGET: INITIALIZE FIRST !!! ***')
1020 FORMAT (/' *** ERROR WMUGET: CANNOT FIND FREE UNIT FOR TYPE ',  &
         a,' ***'/)
    !
#ifdef W3_T
9010 FORMAT ( ' TEST WMUGET: LOOKING FOR UNIT FOR TYPE ',a,' [',  &
         i2,']')
9020 FORMAT ( ' TEST WMUGET: UNIT NUMBER SET TO',i4)
#endif
    !/
    !/ End of WMUGET ----------------------------------------------------- /
    !/
  END SUBROUTINE wmuget
  !/ ------------------------------------------------------------------- /
  SUBROUTINE wmuinq ( NDSE, NDST, NDS )
    !/
    !/                  +-----------------------------------+
    !/                  | WAVEWATCH III           NOAA/NCEP |
    !/                  |           H. L. Tolman            |
    !/                  |                        FORTRAN 90 |
    !/                  | Last update :         29-Mar-2005 !
    !/                  +-----------------------------------+
    !/
    !/    29-Mar-2005 : Origination.                        ( version 3.07 )
    !/
    !  1. Purpose :
    !
    !     Update data base information for a given unit number.
    !
    !  2. Method :
    !
    !     FORTRAN INQUIRE statement.
    !
    !  3. Parameters :
    !
    !     Parameter list
    !     ----------------------------------------------------------------
    !       NDSE    Int.   I   Unit number for error output.
    !       NDST    Int.   I   Unit number for test output.
    !       NDS     Int.   I   Unit number to be assigned.
    !     ----------------------------------------------------------------
    !
    !  4. Subroutines used :
    !
    !      Name      Type  Module   Description
    !     ----------------------------------------------------------------
    !      STRACE    Sur.  W3SERVMD Subroutine tracing.
    !      EXCTDE    Sur.    Id.    Program abort.
    !     ----------------------------------------------------------------
    !
    !  5. Called by :
    !
    !  6. Error messages :
    !
    !  7. Remarks :
    !
    !  8. Structure :
    !
    !  9. Switches :
    !
    !     !/S    Enable subroutine tracing.
    !     !/T    Enable test output
    !
    ! 10. Source code :
    !
    !/ ------------------------------------------------------------------- /
    USE w3servmd, ONLY: extcde
#ifdef W3_S
    USE w3servmd, ONLY: strace
#endif
    !
    IMPLICIT NONE
    !/
    !/ ------------------------------------------------------------------- /
    !/ Parameter list
    !/
    INTEGER, INTENT(IN)           :: ndse, ndst, nds
    !/
    !/ ------------------------------------------------------------------- /
    !/ Local parameters
    !/
#ifdef W3_S
    INTEGER, SAVE           :: ient = 0
#endif
    LOGICAL                 :: check
    !/
#ifdef W3_S
    CALL strace (ient, 'WMUINQ')
#endif
    !
    ! -------------------------------------------------------------------- /
    ! 1.  Test input / output
    !
    IF ( .NOT. flinit ) THEN
      WRITE (ndse,1010)
      CALL extcde ( 1010 )
    END IF
    !
    IF ( nds.LT.unitlw .OR. nds.GT.unithg ) THEN
      WRITE (ndse,1011) nds, unitlw, unithg
      CALL extcde ( 1011 )
    END IF
    !
#ifdef W3_T
    WRITE (ndst,9010) nds
#endif
    !
    ! -------------------------------------------------------------------- /
    ! 2.  Check out file
    ! 2.a Check if opened :
    !
    INQUIRE (nds,opened=check)
    !
#ifdef W3_T
    WRITE (ndst,9020) check
#endif
    !
    ! 2.b File not opened, release to pool
    !
    IF ( .NOT. check ) THEN
      CALL wmuset ( ndse, ndst, nds, .false. )
    ELSE
      !
      ! 2.c File is opened, get the name
      !
      INQUIRE (nds,name=u_name(nds))
      !
#ifdef W3_T
      WRITE (ndst,9021) u_name(nds)
#endif
      !
    END IF
    !
    RETURN
    !
    ! Escape locations read errors --------------------------------------- *
    !
    !
    ! Formats
    !
1010 FORMAT (/' *** ERROR WMUINQ: INITIALIZE FIRST !!! ***')
1011 FORMAT (/' *** ERROR WMUINQ: UNIT NUMBER OUT OF RANGE ***'      &
         /'                   REQ/RANG :',3i6/)
    !
#ifdef W3_T
9010 FORMAT ( ' TEST WMUINQ: TESTING UNIT NUMBER',i4)
9020 FORMAT ( '              INQUIRE ON OPENED : ',l2)
9021 FORMAT ( '              NAME OF FILE      : ',a)
#endif
    !/
    !/ End of WMUINQ ----------------------------------------------------- /
    !/
  END SUBROUTINE wmuinq
  !/
  !/ End of module WMUNITMD -------------------------------------------- /
  !/
END MODULE wmunitmd