ww3_multi.F90

Go to the documentation of this file.

 
 
#include "w3macros.h"
!/ ------------------------------------------------------------------- /
!
!
PROGRAM w3mlti
  !/
  !/                  +-----------------------------------+
  !/                  | WAVEWATCH III           NOAA/NCEP |
  !/                  |           H. L. Tolman            |
  !/                  |                        FORTRAN 90 |
  !/                  | Last update :         29-May-2009 |
  !/                  +-----------------------------------+
  !/
  !/    04-May-2005 : Origination.                        ( version 3.07 )
  !/    29-May-2009 : Preparing distribution version.     ( version 3.14 )
  !/    17-Feb-2016 : New version from namelist use       ( version 5.11 )
  !/
  !/    Copyright 2009 National Weather Service (NWS),
  !/       National Oceanic and Atmospheric Administration.  All rights
  !/       reserved.  WAVEWATCH III is a trademark of the NWS.
  !/       No unauthorized use without permission.
  !/
  !  1. Purpose :
  !
  !     Program shell or driver to run the multi-grid wave model
  !     (uncoupled).
  !
  !  2. Method :
  !
  !  3. Parameters :
  !
  !     Local parameters.
  !     ----------------------------------------------------------------
  !     ----------------------------------------------------------------
  !
  !  4. Subroutines used :
  !
  !      Name      Type  Module   Description
  !     ----------------------------------------------------------------
  !      WMINIT    Subr. WMINITMD Multi-grid model initialization.
  !      WMFINL    Subr. WMFINLMD Multi-grid model finalization.
  !
  !      MPI_INIT, MPI_COMM_SIZE, MPI_COMM_RANK, MPI_BARRIER,
  !         MPI_FINALIZE
  !                Subr.          Standard MPI routines.
  !     ----------------------------------------------------------------
  !
  !  5. Called by :
  !
  !     None, stand-alone program.
  !
  !  6. Error messages :
  !
  !  7. Remarks :
  !
  !     - This is he third version, version 1 and 2 were use for proof
  !       of concept only, and were not retained.
  !
  !  8. Structure :
  !
  !     ----------------------------------------------------------------
  !      0.  Initialization necessary for driver
  !        a General I/O: (implicit in wmmdatmd)
  !        b MPI environment
  !        c Identifying output to "screen" unit
  !      1.  Initialization of all wave models / grids       ( WMINIT )
  !      2.  Run the multi-grid models                       ( WMWAVE )
  !      3.  Finalization of wave model                      ( WMFINL )
  !      4.  Finalization of driver
  !     ----------------------------------------------------------------
  !
  !  9. Switches :
  !
  !       !/MPI   Including MPI routines / environment.
  !
  ! 10. Source code :
  !
  !/ ------------------------------------------------------------------- /
  USE wminitmd, ONLY: wminit, wminitnml
  USE wmwavemd, ONLY: wmwave
  USE wmfinlmd, ONLY: wmfinl
  !/
  USE wmmdatmd, ONLY: mdsi, mdso, mdss, mdst, mdse, &
       nmproc, improc, nmpscr, nrgrd, etime
#ifdef W3_OMPG
  USE omp_lib
#endif
  !/
  IMPLICIT NONE
  !
#ifdef W3_MPI
  include "mpif.h"
#endif
  !/
  !/ ------------------------------------------------------------------- /
  !/ Local parameters
  !/
  INTEGER              :: i, mpi_comm = -99
  INTEGER, ALLOCATABLE :: tend(:,:)
  LOGICAL              :: flgnml
#ifdef W3_MPI
  INTEGER              :: ierr_mpi
  LOGICAL              :: flhybr = .false.
#endif
#ifdef W3_OMPH
  INTEGER              :: thrlev
#endif
  !/
  !/ ------------------------------------------------------------------- /
  ! 0.  Initialization necessary for driver
  ! 0.a General I/O: all can start with initialization in wmmdatmd
  !
  ! 0.b MPI environment: Here, we use MPI_COMM_WORLD
  !
#ifdef W3_OMPH
  flhybr = .true.
  ! For hybrid MPI-OpenMP specify required thread level:
  IF( flhybr ) THEN
    CALL mpi_init_thread(mpi_thread_funneled, thrlev, ierr_mpi)
  ELSE
#endif
#ifdef W3_MPI
    CALL mpi_init      ( ierr_mpi )
#endif
#ifdef W3_OMPH
  ENDIF
#endif
#ifdef W3_MPI
  mpi_comm = mpi_comm_world
  CALL mpi_comm_size ( mpi_comm, nmproc, ierr_mpi )
  CALL mpi_comm_rank ( mpi_comm, improc, ierr_mpi )
  improc = improc + 1
#endif
  !
  ! 0.c Identifying output to "screen" unit
  !
  IF ( improc .EQ. nmpscr ) WRITE (*,900)
#ifdef W3_OMPH
  IF ( improc .EQ. nmpscr ) WRITE (*,905) &
       mpi_thread_funneled, thrlev
#endif
  !
#ifdef W3_OMPG
  IF( improc .EQ. nmpscr ) THEN
      WRITE(*,906) omp_get_max_threads()
    ENDIF
#endif
  !
  !/ ------------------------------------------------------------------- /
  ! 1.  Initialization of all wave models / grids
  !     Use only one of the calls ....
  !
  ! ... Log and screen output, no separate test output file
  !
  !     CALL WMINIT ( MDSI, MDSO, MDSS, MDST, MDSE, 'ww3_multi.inp', MPI_COMM )
  !
  ! ... Screen output disabled
  !
  !     CALL WMINIT ( MDSI, MDSO, MDSO, MDST, MDSE, 'ww3_multi.inp', MPI_COMM )
  !
  ! ... Separate test output file and file preamble defined
  !
  !     CALL WMINIT ( MDSI, MDSO, MDSS, 10, MDSE, 'ww3_multi.inp', MPI_COMM,        &
  !                   './data/' )
  !
  ! ... Separate test output file
  !
  INQUIRE(file="ww3_multi.nml", exist=flgnml)
  IF (flgnml) THEN
    CALL wminitnml ( mdsi, mdso, mdss, 10, mdse, 'ww3_multi.nml', mpi_comm )
  ELSE
    CALL wminit ( mdsi, mdso, mdss, 10, mdse, 'ww3_multi.inp', mpi_comm )
  END IF
  !
 
  !
  !/ ------------------------------------------------------------------- /
  ! 2.  Run the wave model
  !
  ALLOCATE ( tend(2,nrgrd) )
  !
  DO i=1, nrgrd
    tend(:,i) = etime(:)
  END DO
  !
  CALL wmwave ( tend )
  !
  DEALLOCATE ( tend )
  !
  !/ ------------------------------------------------------------------- /
  ! 3.  Finalize the wave model
  !
  CALL wmfinl
  !
  !/ ------------------------------------------------------------------- /
  ! 4   Finalize the driver
  !
  IF ( improc .EQ. nmpscr ) WRITE (*,999)
  !
#ifdef W3_MPI
  CALL mpi_barrier ( mpi_comm, ierr_mpi )
  CALL mpi_finalize  ( ierr_mpi )
#endif
  !
  ! Formats
  !
900 FORMAT (/15x,'     *** WAVEWATCH III Multi-grid shell ***    '/ &
       15x,'================================================='/)
#ifdef W3_OMPH
905 FORMAT ( '  Hybrid MPI/OMP thread support level:'/        &
       '     Requested: ', i2/                          &
       '      Provided: ', i2/ )
#endif
  !
#ifdef W3_OMPG
906 FORMAT ( '  OMP threading enabled. Number of threads: ', i3 / )
#endif
  !
999 FORMAT(//'  End of program '/                                   &
       ' ========================================'/           &
       '          WAVEWATCH III Multi-grid shell '/)
  !/
  !/ End of W3MLTI ----------------------------------------------------- /
  !/
END PROGRAM w3mlti