rdmtbd.f

Go to the documentation of this file.

C> @file
C> @author ATOR @date 2007-01-19
    
C> THIS SUBROUTINE READS MASTER TABLE D INFORMATION FROM TWO
C>   SEPARATE (I.E. ONE STANDARD AND ONE LOCAL) ASCII FILES AND THEN
C>   MERGES IT INTO A UNIFIED SET OF MASTER TABLE D ARRAYS FOR OUTPUT.
C>   EACH OF THE TWO INPUT FILES MUST ALREADY BE INDIVIDUALLY SORTED IN
C>   ASCENDING ORDER WITH RESPECT TO THE FXY NUMBERS.
C>
C> PROGRAM HISTORY LOG:
C> 2007-01-19  J. ATOR    -- ORIGINAL AUTHOR
C> 2021-01-08  J. ATOR    -- MODIFIED MSTABS ARRAY DECLARATIONS
C>                           FOR GNUv10 PORTABILITY
C>
C> USAGE:    CALL RDMTBD ( LUNSTD, LUNLTD, MXMTBD, MXELEM,
C>                         IMT, IMTV, IOGCE, ILTV,
C>                         NMTBD, IMFXYN, CMMNEM, CMDSC, CMSEQ,
C>                         NMELEM, IEFXYN, CEELEM )
C>   INPUT ARGUMENT LIST:
C>     LUNSTD   - INTEGER: FORTRAN LOGICAL UNIT NUMBER OF ASCII FILE
C>                CONTAINING STANDARD TABLE D INFORMATION
C>     LUNLTD   - INTEGER: FORTRAN LOGICAL UNIT NUMBER OF ASCII FILE
C>                CONTAINING LOCAL TABLE D INFORMATION
C>     MXMTBD   - INTEGER: MAXIMUM NUMBER OF ENTRIES TO BE STORED IN
C>                MERGED MASTER TABLE D ARRAYS; THIS SHOULD BE THE SAME
C>                NUMBER AS WAS USED TO DIMENSION THE OUTPUT ARRAYS IN
C>                THE CALLING PROGRAM, AND IT IS USED BY THIS SUBROUTINE
C>                TO ENSURE THAT IT DOESN'T OVERFLOW THESE ARRAYS
C>     MXELEM   - INTEGER: MAXIMUM NUMBER OF ELEMENTS TO BE STORED PER
C>                ENTRY WITHIN THE MERGED MASTER TABLE D ARRAYS; THIS
C>                SHOULD BE THE SAME NUMBER AS WAS USED TO DIMENSION THE
C>                OUTPUT ARRAYS IN THE CALLING PROGRAM, AND IT IS USED
C>                BY THIS SUBROUTINE TO ENSURE THAT IT DOESN'T OVERFLOW
C>                THESE ARRAYS
C>
C>   OUTPUT ARGUMENT LIST:
C>     IMT      - INTEGER: MASTER TABLE, READ FROM EACH ASCII FILE
C>                (NOTE: THESE VALUES MUST BE THE SAME IN EACH FILE!)
C>     IMTV     - INTEGER: VERSION NUMBER OF MASTER TABLE, READ FROM
C>                STANDARD ASCII FILE
C>     IOGCE    - INTEGER: ORIGINATING CENTER, READ FROM LOCAL ASCII FILE
C>     ILTV     - INTEGER: VERSION NUMBER OF LOCAL TABLE, READ FROM
C>                LOCAL ASCII FILE
C>     NMTBD    - INTEGER: NUMBER OF ENTRIES IN MERGED MASTER TABLE D
C>                ARRAYS
C>     IMFXYN(*)- INTEGER: MERGED ARRAY CONTAINING BIT-WISE
C>                REPRESENTATIONS OF FXY NUMBERS (I.E. SEQUENCE
C>                DESCRIPTORS)
C>     CMMNEM(*)- CHARACTER*8: MERGED ARRAY CONTAINING MNEMONICS
C>     CMDSC(*) - CHARACTER*4: MERGED ARRAY CONTAINING DESCRIPTOR CODES
C>     CMSEQ(*) - CHARACTER*120: MERGED ARRAY CONTAINING SEQUENCE NAMES
C>     NMELEM(*)- INTEGER: MERGED ARRAY CONTAINING NUMBER OF ELEMENTS
C>                STORED FOR EACH ENTRY
C>   IEFXYN(*,*)- INTEGER: MERGED ARRAY CONTAINING BIT-WISE
C>                REPRESENTATIONS OF ELEMENT FXY NUMBERS
C>   CEELEM(*,*)- CHARACTER*120: MERGED ARRAY CONTAINING ELEMENT NAMES
C>
C> REMARKS:
C>    THIS ROUTINE CALLS:        ADN30    BORT     GETNTBE  GETTBH
C>                               SNTBDE   WRDLEN
C>    THIS ROUTINE IS CALLED BY: IREADMT
C>                               Not normally called by any application
C>                               programs but it could be.
C>
    SUBROUTINE rdmtbd ( LUNSTD, LUNLTD, MXMTBD, MXELEM,
     .              imt, imtv, iogce, iltv,
     .              nmtbd, imfxyn, cmmnem, cmdsc, cmseq,
     .              nmelem, iefxyn, ceelem )



    character*200   stline, ltline
    character*128   bort_str
    character*120   ceelem(mxmtbd,mxelem)
    character*6 cmatch, adn30
    character*4 cmdsc(*)
    character   cmseq(120,*)
    character   cmmnem(8,*)

    integer     imfxyn(*), nmelem(*),
     .          iefxyn(mxmtbd,mxelem)

C-----------------------------------------------------------------------
C-----------------------------------------------------------------------

C   Call WRDLEN to initialize some important information about the
C   local machine, just in case it hasn't already been called.

    CALL wrdlen

C   Read and parse the header lines of both files.

    CALL gettbh( lunstd, lunltd, 'D', imt, imtv, iogce, iltv )

C   Read through the remainder of both files, merging the
C   contents into a unified set of master Table D arrays.

    nmtbd = 0
    CALL getntbe( lunstd, isfxyn, stline, iers )
    CALL getntbe( lunltd, ilfxyn, ltline, ierl )
    DO WHILE ( ( iers .EQ. 0 ) .OR. ( ierl .EQ. 0 ) )
      IF ( ( iers .EQ. 0 ) .AND. ( ierl .EQ. 0 ) ) THEN
        IF ( isfxyn .EQ. ilfxyn ) THEN
          cmatch = adn30( isfxyn, 6 )
          goto 900
        ELSE IF ( isfxyn .LT. ilfxyn ) THEN
          CALL sntbde( lunstd, isfxyn, stline, mxmtbd, mxelem,
     .              nmtbd, imfxyn, cmmnem, cmdsc, cmseq,
     .              nmelem, iefxyn, ceelem )
          CALL getntbe( lunstd, isfxyn, stline, iers )
        ELSE
          CALL sntbde( lunltd, ilfxyn, ltline, mxmtbd, mxelem,
     .              nmtbd, imfxyn, cmmnem, cmdsc, cmseq,
     .              nmelem, iefxyn, ceelem )
          CALL getntbe( lunltd, ilfxyn, ltline, ierl )
        ENDIF
      ELSE IF ( iers .EQ. 0 ) THEN
        CALL sntbde( lunstd, isfxyn, stline, mxmtbd, mxelem,
     .            nmtbd, imfxyn, cmmnem, cmdsc, cmseq,
     .            nmelem, iefxyn, ceelem )
        CALL getntbe( lunstd, isfxyn, stline, iers )
      ELSE IF ( ierl .EQ. 0 ) THEN
        CALL sntbde( lunltd, ilfxyn, ltline, mxmtbd, mxelem,
     .            nmtbd, imfxyn, cmmnem, cmdsc, cmseq,
     .            nmelem, iefxyn, ceelem )
        CALL getntbe( lunltd, ilfxyn, ltline, ierl )
      ENDIF
    ENDDO

    RETURN
 900    WRITE(bort_str,'("BUFRLIB: RDMTBD - STANDARD AND LOCAL'//
     . ' TABLE D FILES BOTH CONTAIN SAME FXY NUMBER: ",5A)')
     .   cmatch(1:1), '-', cmatch(2:3), '-', cmatch(4:6)    
    CALL bort(bort_str)
    END