adn30.f

Go to the documentation of this file.

C> @file
C> @brief Convert a WMO bit-wise representation of an FXY value
C> to a character string of length 5 or 6.
C>
C> @author J. Woollen @date 1994-01-06
 
C> Convert a WMO bit-wise representation of an FXY value
C> to a character string of length 5 or 6.
C>      
C> For an description of the WMO bit-wise representation of the FXY
C> value, see ifxy().
C>
C> This function is the logical inverse of function idn30().
C>
C> @param[in] IDN - integer: WMO bit-wise representation of FXY value.
C> @param[in] L30 - integer: Length of string to be returned; can be
C> either 5 or 6 characters.
C> @returns adn30 - character*(*): FXY character string.
C>
C> @author J. Woollen @date 1994-01-06
 
      FUNCTION adn30(IDN,L30)
 
      COMMON /hrdwrd/ nbytw,nbitw,iord(8)
 
      CHARACTER*(*) adn30
      CHARACTER*128 bort_str
 
C----------------------------------------------------------------------
C----------------------------------------------------------------------
      IF(len(adn30).LT.l30         ) GOTO 900
      IF(idn.LT.0 .OR. idn.GT.65535) GOTO 901
      IF(l30.EQ.5) THEN
         WRITE(adn30,'(I5)') idn
      ELSEIF(l30.EQ.6) THEN
         idf = ishft(idn,-14)
         idx = ishft(ishft(idn,nbitw-14),-(nbitw-6))
         idy = ishft(ishft(idn,nbitw- 8),-(nbitw-8))
         WRITE(adn30,'(I1,I2,I3)') idf,idx,idy
      ELSE
         GOTO 902
      ENDIF
 
      DO i=1,l30
      IF(adn30(i:i).EQ.' ') adn30(i:i) = '0'
      ENDDO
 
C  EXITS
C  -----
 
      RETURN
900   CALL bort('BUFRLIB: ADN30 - FUNCTION RETURN STRING TOO SHORT')
901   CALL bort('BUFRLIB: ADN30 - INTEGER REPRESENTATION OF '//
     . 'DESCRIPTOR OUT OF 16-BIT RANGE')
902   WRITE(bort_str,'("BUFRLIB: ADN30 - CHARACTER LENGTH (",I4,") '//
     . 'MUST BE EITHER 5 OR 6")') l30
      CALL bort(bort_str)
      END