copybf.f

Go to the documentation of this file.

C> @file
C> @brief Copy an entire BUFR file.
C>
C> @author J. Woollen @date 1994-01-06
 
C> This subroutine copies an entire BUFR file from one Fortran
C> logical unit to another.
C>
C> @param[in] LUNIN   -- integer: Fortran logical unit number for
C>                       source BUFR file
C> @param[in] LUNOT   -- integer: Fortran logical unit number for
C>                       target BUFR file
C>
C> The logical unit numbers LUNIN and LUNOT must already be
C> associated with actual filenames on the local system, typically
C> via a Fortran "OPEN" statement.
C>
C> @remarks
C> - This subroutine uses subroutine msgwrt() to copy each BUFR
C> message from LUNIN to LUNOT; therefore, this subroutine can be
C> used to create a copy of LUNIN where each corresponding message
C> in LUNOT contains any or all of the updates described in the
C> documentation for subroutine msgwrt().
C>
C> @author J. Woollen @date 1994-01-06
      RECURSIVE SUBROUTINE copybf(LUNIN,LUNOT)
 
      USE moda_mgwa
      USE modv_im8b
 
C-----------------------------------------------------------------------
C-----------------------------------------------------------------------
 
C  CHECK FOR I8 INTEGERS
C  ---------------------
      IF(im8b) THEN
         im8b=.false.
 
         CALL x84(lunin,my_lunin,1)
         CALL x84(lunot,my_lunot,1)
         CALL copybf(my_lunin,my_lunot)
 
         im8b=.true.
         RETURN
      ENDIF
 
C  CALL SUBROUTINE WRDLEN TO INITIALIZE SOME IMPORTANT INFORMATION
C  ABOUT THE LOCAL MACHINE (IN CASE IT HAS NOT YET BEEN CALLED)
C  ---------------------------------------------------------------
 
      CALL wrdlen
 
C  CHECK BUFR FILE STATUSES
C  ------------------------
 
      CALL status(lunin,lun,il,im)
      IF(il.NE.0) GOTO 900
      CALL status(lunot,lun,il,im)
      IF(il.NE.0) GOTO 901
 
C  CONNECT THE FILES FOR READING/WRITING TO THE C-I-O INTERFACE
C  ------------------------------------------------------------
 
      CALL openbf(lunin,'INX',lunin)
      CALL openbf(lunot,'OUX',lunin)
 
C  READ AND COPY A BUFR FILE ON UNIT LUNIN TO UNIT LUNOT
C  -----------------------------------------------------
 
1     CALL rdmsgw(lunin,mgwa,ier)
      IF(ier.EQ.0) THEN
         CALL msgwrt(lunot,mgwa,iupbs01(mgwa,'LENM'))
         GOTO 1
      ENDIF
 
C  FREE UP THE FILE CONNECTIONS FOR THE TWO FILES
C  ----------------------------------------------
 
      CALL closbf(lunin)
      CALL closbf(lunot)
 
C  EXITS
C  -----
 
      RETURN
900   CALL bort
     . ('BUFRLIB: COPYBF - INPUT BUFR FILE IS OPEN, IT MUST BE CLOSED')
901   CALL bort
     . ('BUFRLIB: COPYBF - OUTPUT BUFR FILE IS OPEN, IT MUST BE CLOSED')
      END