drfini.f

Go to the documentation of this file.

C> @file
C> @brief Initialize replication factors for delayed replication
C> sequences.
C>
C> @author J. Woollen @date 2002-05-14
 
C> Initialize replication factors for delayed replication sequences.
C>
C> This subroutine explicitly initializes delayed replication factors
C> and allocates a corresponding amount of space within internal arrays,
C> thereby allowing the subsequent use of subroutine ufbseq() to write
C> data into delayed replication sequences.
C>
C> @param[in] LUNIT - integer: Fortran logical unit number for BUFR file.
C> @param[in] MDRF - integer(*): Array of delayed replication factors,
C> in one-to-one correspondence with the number of occurrences of DRFTAG
C> within the overall subset definition, and explicitly defining how much
C> space (i.e. how many replications) to allocate within each successive
C> occurrence.
C> @param[in] NDRF - integer: Number of delayed replication factors
C> within MDRF.
C> @param[in] DRFTAG - character*(*): Table D sequence mnemonic, bracketed
C> by appropriate delayed replication notation (e.g. {}, () OR <>)
C>
C> Logical unit LUNIT should have already been opened for output
C> operations (i.e. writing/encoding BUFR) via a previous call to
C> subroutine openbf(), and a message for output should have already
C> been opened via a previous call to one of the
C> [message-writing subroutines].
C>
C> The use of this subroutine is only required when writing data
C> into delayed replication sequences using ufbseq(), or for cases
C> where ufbint() or ufbrep() are being used to write data into
C> delayed replication sequences which occur more than once within
C> an overall subset definition.  In such cases, the use of this
C> subroutine allows the application code to explicitly specify how
C> many replications of the sequence are to be allocated to each
C> occurrence of the delayed replication sequence within the overall
C> subset definition, prior to storing all of the actual data values
C> themselves via a single subsequent call to ufbint() or ufbrep().
C> In contrast, the use of this subroutine is not required when
C> ufbint() or ufbrep() are to be called to store data values
C> for a delayed replication sequence which only occurs one time
C> within an overall subset definition, because in that case the
C> same type of initialization and space allocation functionality
C> will be automatically handled internally within subroutine
C> ufbint() or ufbrep().
C>
C> @author J. Woollen @date 2002-05-14
      RECURSIVE SUBROUTINE drfini(LUNIT,MDRF,NDRF,DRFTAG)
 
      USE moda_usrint
      USE moda_tables
      USE modv_im8b
 
      parameter( mxdrf = 2000 )
 
      CHARACTER*(*) drftag
      CHARACTER*128 bort_str
      dimension     mdrf(*),lunit(*),ndrf(*)
      dimension     my_mdrf(mxdrf),my_lunit(1),my_ndrf(1)
 
C-----------------------------------------------------------------------
C-----------------------------------------------------------------------
 
C  CHECK FOR I8 INTEGERS
C  ---------------------
 
      IF(im8b) THEN
         im8b=.false.
 
         CALL x84(lunit,my_lunit,1)
         CALL x84(ndrf,my_ndrf,1)
         CALL x84(mdrf,my_mdrf,my_ndrf(1))
         CALL drfini(my_lunit,my_mdrf,my_ndrf,drftag)
 
         im8b=.true.
         RETURN
      ENDIF
 
      IF(ndrf(1).GT.mxdrf) GOTO 900
 
      CALL status(lunit,lun,il,im)
 
C  COMFORM THE TEMPLATES TO THE DELAYED REPLICATION FACTORS
C  --------------------------------------------------------
 
      m = 0
      n = 0
 
10    DO n=n+1,nval(lun)
      node = inv(n,lun)
      IF(itp(node).EQ.1 .AND. tag(node).EQ.drftag) THEN
         m = m+1
         CALL usrtpl(lun,n,mdrf(m))
         GOTO 10
      ENDIF
      ENDDO
 
C  EXITS
C  -----
 
      RETURN
 900  WRITE(bort_str,'("BUFRLIB: DRFINI - THE NUMBER OF DELAYED '//
     . 'REPLICATION FACTORS (",I5,") EXCEEDS THE LIMIT (",I5,")")')
     .  ndrf(1),mxdrf
      CALL bort(bort_str)
      END